在 CDS 视图中定义数据模型
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 提供含业务对象结构的 CDS 数据模型 › 在 CDS 视图中定义数据模型
差旅根视图 /DMO/I_Travel_U
列表 1(如下)为您提供用于管理航班的 CDS 数据模型的实施,其中数据库表 /dmo/travel 用作相应 CDS 视图 /DMO/I_Travel_U 的数据源(请注意驼峰命名法)。
此 CDS 视图定义数据模型的根实体,并表示要创建的差旅业务对象的构成层次结构的根。
从结构角度来看,业务对象由节点树组成,这些节点通过称为构成的特殊关联链接。要定义从根实体到子实体的构成关系,使用关键字 COMPOSITION。在我们的示例中,指定 /DMO/I_Booking_U 作为组合 _Booking 的子实体。因此,预订节点被定义为业务对象根的直接子节点。使用基数 [0 .. *] 表示可以为每个差旅实例分配任意数量的预订实例。
为了能够从语义相关的实体访问业务数据,请在 CDS 源代码中定义一组关联。这些关联是指属于演示应用程序场景一部分的 CDS 视图。其中一些视图主要用作检索文本信息的文本视图,并用作特定 UI 字段的值帮助提供者视图,请参阅在 CDS 映射视图中投影数据模型。
除管理字段 createdby、lastchangedby 和 createdat 外,数据源表 /dmo/travel 的所有字段均已添加到 CDS 视图中的元素清单。数据库表提供了多个用于管理数据的管理字段,这些字段通常包括创建或最后更改实例的用户以及相应的时戳。但是,在此示例中,元素 LastChangedAt 扮演特殊部分,因为它用于 ETag 检查以确定实体的两种表示是否相同。如果实体的表示发生更改,则会分配新的和不同的 ETag 值。在处理业务对象时,ETag 在锁定生命周期中起着重要作用。
对于所有元素,我们可以提供别名以为元素提供可读名称。
价格元素和元素 CurrencyCode 具有语义关系。此关系通过 @semantics 注释在业务对象视图中显示。在 Fiori UI 中,金额和货币值可以一起显示。
展开以下代码示例以查看 CDS 根视图 /DMO/I_Travel_U 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Travel view - CDS data model'
define root view entity /DMO/I_Travel_U
as select from /dmo/travel as Travel -- the travel table is the data source for this view
composition [0..*] of /DMO/I_Booking_U as _Booking
association [0..1] to /DMO/I_Agency as _Agency on $projection.AgencyID = _Agency.AgencyID
association [0..1] to /DMO/I_Customer as _Customer on $projection.CustomerID = _Customer.CustomerID
association [0..1] to I_Currency as _Currency on $projection.CurrencyCode = _Currency.Currency
association [1..1] to /DMO/I_Travel_Status_VH as _TravelStatus on $projection.Status = _TravelStatus.TravelStatus
{
key Travel.travel_id as TravelID,
Travel.agency_id as AgencyID,
Travel.customer_id as CustomerID,
Travel.begin_date as BeginDate,
Travel.end_date as EndDate,
@Semantics.amount.currencyCode: 'CurrencyCode'
Travel.booking_fee as BookingFee,
@Semantics.amount.currencyCode: 'CurrencyCode'
Travel.total_price as TotalPrice,
Travel.currency_code as CurrencyCode,
Travel.description as Memo,
Travel.status as Status,
Travel.lastchangedat as LastChangedAt,
/* Associations */
_Booking,
_Agency,
_Customer,
_Currency,
_TravelStatus
}
预订视图 /DMO/I_Booking_U
清单 2(如下)为您提供登记实体的数据模型实施。在根实体 /DMO/I_Travel_U 的数据定义中,将登记实体 /DMO/I_Booking_U 指定为子实体。此构成关系需要与其组成父实体的关联,以便在数据模型实施中指定预订子实体。此关系由关键字 ASSOCIATION TO PARENT 表示。使用此语法,将 CDS 实体/DMO/I_Booking_U 定义为差旅业务对象结构构成层次结构中的直接子节点。
SELECT 列表包括与构建业务对象结构相关的登记实体的所有元素。这些元素随别名一起提供。与在 Travel CDS 视图中一样,使用 CurrencyCode 注释建立 Price 和 @Semantics 之间的语义关系。
为了能够访问其他实体中的数据,在 CDS 源代码中定义了一组附加关联(_Customer、_Carrier 和 _Connection)。这些视图主要用作检索文本信息的文本视图,并用作 UI 上特定预订字段的值帮助提供者视图,在 CDS 映射视图中投影数据模型。
展开以下代码示例以查看 CDS 视图 /DMO/I_Booking_U 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Booking view'
define view entity /DMO/I_Booking_U
as select from /dmo/booking as Booking
association to parent /DMO/I_Travel_U as _Travel on $projection.TravelID = _Travel.TravelID
association [1..1] to /DMO/I_Customer as _Customer on $projection.CustomerID = _Customer.CustomerID
association [1..1] to /DMO/I_Carrier as _Carrier on $projection.AirlineID = _Carrier.AirlineID
association [1..1] to /DMO/I_Connection as _Connection on $projection.AirlineID = _Connection.AirlineID
and $projection.ConnectionID = _Connection.ConnectionID
{
key Booking.travel_id as TravelID,
key Booking.booking_id as BookingID,
Booking.booking_date as BookingDate,
Booking.customer_id as CustomerID,
Booking.carrier_id as AirlineID,
Booking.connection_id as ConnectionID,
Booking.flight_date as FlightDate,
@Semantics.amount.currencyCode: 'CurrencyCode'
Booking.flight_price as FlightPrice,
Booking.currency_code as CurrencyCode,
/* Associations */
_Travel,
_Customer,
_Carrier,
_Connection
}
差旅状态视图 /DMO/I_Travel_Status_VH
清单 3(下方)提供处理差旅状态数据的数据定义。CDS 视图 /DMO/I_Travel_Status_VH 用作提供可能的差旅状态值的值帮助视图。
数据库表 /dmo/trvl_stat 是 CDS 视图的数据源。表 /dmo/trvl_stat 中的差旅状态字段已添加到 CDS 视图 中的元素列表。
要通过下拉菜单启用值选择,请使用注释 @ObjectModel.resultSet.sizeCategory: #XS。
关联的 CDS 视图 /DMO/I_Travel_Status_VH_Text 用作本地化文本的提供者视图。因此,CDS 视图 /DMO/I_Travel_Status_VH 包含关联以及指向 CDS 视图 @ObjectModel.text.association: '_Text' 的注释 /DMO/I_Travel_Status_VH_Text。
为确保值帮助中仅显示关联 CDS 视图 /DMO/I_Travel_Status_VH_Text 提供的文本,使用注释 @UI.textArrangement: #TEXT_ONLY。
注释 @UI.lineItem: [{importance: #HIGH}] 可确保即使显示空间较少也显示差旅状态数据。
@Objectmodel.usageType 注释定义值帮助视图的预期性能参数和包含的数据类。有关详细信息,请参阅 CDS 注释。
展开以下代码示例以查看差旅状态视图的源代码 /DMO/I_Travel_Status_VH。
示例代码
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Travel Status Value Help'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
serviceQuality: #A,
sizeCategory: #S,
dataClass: #MASTER
}
@ObjectModel.resultSet.sizeCategory: #XS
define view entity /DMO/I_Travel_Status_VH
as select from /dmo/trvl_stat
association [0..*] to /DMO/I_Travel_Status_VH_Text as _Text on $projection.TravelStatus = _Text.TravelStatus
{
@UI.textArrangement: #TEXT_ONLY
@UI.lineItem: [{importance: #HIGH}]
@ObjectModel.text.association: '_Text'
key travel_status as TravelStatus,
_Text
}
差旅状态文本视图 /DMO/I_Travel_Status_VH_Text
清单 4(下方)提供处理差旅状态文本数据的数据定义。此 CDS 实体在清单报表页面和值帮助中提供差旅状态文本。
数据库表 /dmo/trvl_stat_t 是相应 CDS 视图 /DMO/I_Travel_Status_VH_Text 的数据源。所有字段均已添加到 CDS 视图中的元素清单。
要通过下拉菜单启用值选择,请使用注释 @ObjectModel.resultSet.sizeCategory: #XS。
注释 @ObjectModel.text.element: ['Text'] 在注释元素及其描述性元素之间建立链接 Text。通过将注释 @Semantics.text: true 用于元素 Text,在运行时从数据库中读取此字段,并由 OData 使用者的登录语言自动过滤。注释 @Semantics.language: true 指定用于此语言过滤器的字段。
@Objectmodel.usageType 注释定义值帮助视图的预期性能参数和包含的数据类。有关详细信息,请参阅 CDS 注释。
展开以下代码示例以查看差旅状态文本视图 /DMO/I_Travel_Status_VH_Text 的源代码。
示例代码
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Travel Status Value Help'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
serviceQuality: #A,
sizeCategory: #S,
dataClass: #MASTER
}
@ObjectModel.resultSet.sizeCategory: #XS
define view entity /DMO/I_Travel_Status_VH_Text
as select from /dmo/trvl_stat_t
association [1..1] to /DMO/I_Travel_Status_VH as _TravelStatus on $projection.TravelStatus = _TravelStatus.TravelStatus
{
@ObjectModel.text.element: ['Text']
key travel_status as TravelStatus,
@Semantics.language: true
key language as Language,
@Semantics.text: true
text as Text,
_TravelStatus
}
旅行社 查看 /DMO/I_Agency
清单 5(如下)提供处理旅行社数据的数据定义。数据库表 /dmo/agency 是相应 CDS 视图 /DMO/I_Agency 的数据源。
由于旅行社的数据可能因国家/地区而异,因此数据模型参考使用关联 _Country 的 I_Country 视图。
此 CDS 实体还用作文本提供者视图。为此,注释 @Semantics.text: true 用于将 Name 元素标识为文本元素,在这种情况下,该元素指向代理名称的文本描述。在差旅和预订映射视图中,相关文本元素作为字段添加到参考实体。在运行时,从数据库读取此字段,并按 OData 使用者的登录语言自动过滤。
此外,数据模型在 Name 元素上启用搜索功能:注释 @Search.searchable: true 将 CDS 视图标记为可搜索,而 @Search.defaultSearchElement: true 指定在全文本搜索中考虑注释的 Name 元素。有关详细信息,请参阅:在 SAP Fiori 应用中启用文本和模糊搜索
展开以下代码示例以查看代理 CDS 视图 /DMO/I_Agency 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Agency view - CDS data model'
@Search.searchable: true
define view entity /DMO/I_Agency
as select from /dmo/agency as Agency -- the agency table serves as the data source for this view
association [0..1] to I_Country as _Country on $projection.CountryCode = _Country.Country
{
key Agency.agency_id as AgencyID,
@Semantics.text: true
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
Agency.name as Name,
Agency.street as Street,
Agency.postal_code as PostalCode,
Agency.city as City,
Agency.country_code as CountryCode,
Agency.phone_number as PhoneNumber,
Agency.email_address as EMailAddress,
Agency.web_address as WebAddress,
/* Associations */
_Country
}
客户视图 /DMO/I_Customer
清单 6(如下)用作管理乘客数据的数据模型实施。数据库表 /dmo/customer 用作相应 CDS 视图 /DMO/I_Customer 的数据源。
除管理字段(createdby、createdat、lastchangedat 和 lastchangedby)外,表 /dmo/customer 的所有字段均已添加到 CDS 视图的元素清单中。
由于乘客的数据可能因国家/地区而异,因此数据模型使用相应的关联 _Country 引用 I_Country 视图。
注释 @Semantics.text: true 将添加到 LastName 元素。此元素用作文本元素,在此情况下指向具有客户名称的文本。此文本注释允许您使用此客户视图作为目标视图 /DMO/I_Travel_U 和 /DMO/I_Booking_U 中相关元素的文本提供者。
展开以下代码示例以查看 CDS 视图 /DMO/I_Customer 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Customer view - CDS data model'
@Search.searchable: true
define view entity /DMO/I_Customer
as select from /dmo/customer as Customer -- the customer table serves as the data source
association [0..1] to I_Country as _Country on $projection.CountryCode = _Country.Country
{
key Customer.customer_id as CustomerID,
Customer.first_name as FirstName,
@Semantics.text: true
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
Customer.last_name as LastName,
Customer.title as Title,
Customer.street as Street,
Customer.postal_code as PostalCode,
Customer.city as City,
Customer.country_code as CountryCode,
Customer.phone_number as PhoneNumber,
Customer.email_address as EMailAddress,
/* Associations */
_Country
}
航班视图 /DMO/I_Flight
清单 7(下方)为您提供航班的数据定义。特定航班的数据存储在数据库表 /dmo/flight 中,该表用作相应 CDS 视图 /DMO/I_Flight 的数据源。
如清单 2(上文)所示,您可以使用附加绑定实施值帮助。要为基于相同值帮助提供者的值帮助定义过滤条件,航班视图 /DMO/I_Flight 用于过滤注释元素的值帮助结果清单。
展开以下代码示例以查看 CDS 视图 /DMO/I_Flight 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Flight view'
define view entity /DMO/I_Flight as select from /dmo/flight as Flight
{
key Flight.carrier_id as AirlineID,
key Flight.connection_id as ConnectionID,
key Flight.flight_date as FlightDate,
@Semantics.amount.currencyCode: 'CurrencyCode'
Flight.price as Price,
Flight.currency_code as CurrencyCode,
Flight.plane_type_id as PlaneType,
Flight.seats_max as MaximumSeats,
Flight.seats_occupied as OccupiedSeats
}
航班航线 查看 /DMO/I_Connection
清单 8(如下)用作转机的数据定义。转机存储在数据库表 /dmo/connection 中,该表用作相应 CDS 视图 /DMO/I_Connection 的数据源。
除管理字段外,表 /dmo/connection 中的所有字段均已添加到 CDS 视图的元素清单中。
使用注释 @Semantics.quantity.unitOfMeasure,将 DistanceUnit 元素引用为包含存储在元素 Distance 中的值的计量单位的元素。
展开以下代码示例以查看 CDS 视图 /DMO/I_Connection 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Connection view'
define view entity /DMO/I_Connection
as select from /dmo/connection as Connection
{
key Connection.carrier_id as AirlineID,
key Connection.connection_id as ConnectionID,
Connection.airport_from_id as DepartureAirport,
Connection.airport_to_id as DestinationAirport,
Connection.departure_time as DepartureTime,
Connection.arrival_time as ArrivalTime,
@Semantics.quantity.unitOfMeasure: 'DistanceUnit'
Connection.distance as Distance,
Connection.distance_unit as DistanceUnit
}
承运商视图 /DMO/I_Carrier
承运商 CDS 实体的以下数据定义为您提供存储在数据库表 /DMO/CARRIER 中的航空公司的标识和名称。
此 CDS 实体主要用作文本提供者视图。它通过差旅和预订视图中定义的文本关联提供文本数据(清单 1 和清单 2)。
为此,需要在元素级别进行文本注释,以对视图元素列表中的文本元素进行注释:在此示例中,将 Name 元素标识为文本元素。
展开以下代码示例以查看 CDS 视图 /DMO/I_Carrier 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Carrier view'
define view entity /DMO/I_Carrier as select from /dmo/carrier as Airline
{
key Airline.carrier_id as AirlineID,
@Semantics.text: true
Airline.name as Name,
Airline.currency_code as CurrencyCode
}
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译