在 CDS 投影视图中投影数据模型

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 提供含业务对象结构的 CDS 数据模型 › 在 CDS 投影视图中投影数据模型

使用 CDS 映射视图公开特定业务服务的常规数据模型。

常规业务对象定义所有可用实体和元素,而业务对象映射定义用于特定服务的实体和元素,在本例中为公开供 UI 使用的服务。这意味着,在映射层中,我们定义差旅场景的 UI 服务用例所需的数据模型及其功能。UI 服务包括:

  • 值帮助

  • 文本元素

  • 搜索

  • UI 布局注释

这些 UI 增强通过 CDS 投影视图中的 CDS 注释建模。最好在元数据扩展中外包与 UI 布局相关的注释,因为这些注释可以轻松使投影视图过载。CDS 元数据扩展始终分配到行业、合作伙伴或客户等层,以便轻松扩展元数据扩展的范围。

创建 CDS 映射视图

对于 Travel UI 服务,为属于业务对象构成层次结构一部分的 CDS 实体创建映射视图。它们是:

 

根层

第一个子层

业务对象结构的 CDS 视图

/DMO/I_TRAVEL_U

/DMO/I_BOOKING_U

业务对象映射的 CDS 视图

/DMO/C_TRAVEL_U

/DMO/C_BOOKING_U

备注

名称根据映射视图的命名规则进行分配:开发对象的命名规则。

有关映射视图中语法的信息,请参阅将视图实体定义为映射(ABAP 关键字文档)。

业务对象映射的数据建模

非托管场景仅提供一个映射用例,该用例重用业务对象视图中定义的所有元素。在投影层中,数据模型使用通过 映射视图中的 CDS 注释或关键字实施并在服务元数据中显示的 UI 功能进行丰富。

根映射视图 /DMO/C_Travel_U

以下代码块为您提供 CDS 视图投影的实施,其中 CDS 视图 /DMO/I_Travel_U 用作相应 CDS 投影视图 /DMO/C_Travel_U 的投影源。它预计基础视图中的每个元素。

差旅预测视图还显示在基础差旅视图 /DMO/I_Travel_U 中定义的所有关联。但是,必须将构成重定向到子项 /DMO/I_Booking_U 以重定向到新创建的投影对应项。在 CDS 映射视图 中描述了定义重定向成分的语法。

要定义元素 AgencyID 、 CustomerID 、 Status 与其相应文本或描述之间的关系,必须在 CDS 投影视图中对文本元素进行非规范化。因此,映射视图的 _TravelStatus._Text.Text 列表中包含相关文本提供程序视图的元素(_Agency.Name、_Customer.LastName 和 select)。其相应的标识元素使用 @ObjectModel.text.element 进行注释。在运行时,从数据库中读取参考的元素并按 OData 使用者的登录语言自动过滤。有关详细信息,请参阅: 使用文本元素

通过将注释 /DMO/C_Travel_U 添加到元素 AgencyID、CustomerID、Status 和 @Consumption.valueHelpDefinition,在 CDS 投影视图 CurrencyCode 的源代码中定义值帮助。值帮助注释 允许您在不实施关联的情况下引用值帮助提供者视图。您只需将 CDS 实体分配为值帮助提供者,并在注释 中为映射指定元素。值帮助提供者的所有字段都显示在 UI 上。当最终用户选择值帮助提供者的其中一个条目时,参考元素的值将传输到 UI 上的相应输入字段。有关详细信息,请参阅:简单值帮助

备注

对于值帮助的缺省实施,请注意,您可以重用包含与 UI 上的输入字段相对应的元素所需值的任何 CDS 实体。无需将 CDS 实体显式定义为值帮助提供者

在投影视图中,对在视图中搜索特定值的能力进行建模。实体注释 @Search.searchable 用于差旅投影以启用常规 HANA 搜索。此注释还会触发 Fiori 元素 UI 中的搜索栏。通过使用此注释,您必须定义主要用作自由文本搜索的搜索目标的元素。这些元素使用 @Search.defaultSearchElement 进行注释。此外,您可以定义模糊性阈值,用于定义搜索值必须如何精确才能找到元素值。有关搜索的详细信息,请参阅在 SAP Fiori 应用中启用文本和模糊搜索。

以下列表不包括定义 UI 布局的注释。它们外包到元数据扩展,请参阅将 UI 元数据添加到数据模型。

展开以下代码示例以查看 CDS 根映射视图 /DMO/C_Travel_U 的源代码。

示例代码

@EndUserText.label: 'Travel Projection View'
@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.allowExtensions: true

@Search.searchable: true
define root view entity /DMO/C_Travel_U
  provider contract transactional_query
  as projection on /DMO/I_Travel_U

{     ///DMO/I_Travel_U

  key TravelID,

      @Consumption.valueHelpDefinition: [{ entity : {name: '/DMO/I_Agency_StdVH', element: 'AgencyID'  }, useForValidation: true }]
      @ObjectModel.text.element: ['AgencyName']
      @Search.defaultSearchElement: true
      AgencyID,
      _Agency.Name       as AgencyName,

      @Consumption.valueHelpDefinition: [{entity: {name: '/DMO/I_Customer_StdVH', element: 'CustomerID' }, useForValidation: true}]
      @ObjectModel.text.element: ['CustomerName']
      @Search.defaultSearchElement: true
      CustomerID,
      _Customer.LastName as CustomerName,

      BeginDate,

      EndDate,

      BookingFee,

      TotalPrice,

      @Consumption.valueHelpDefinition: [{entity: {name: 'I_CurrencyStdVH', element: 'Currency' }, useForValidation: true }]
      CurrencyCode,

      Memo,

      @Consumption.valueHelpDefinition: [{ entity: { name: '/DMO/I_Travel_Status_VH', element: 'TravelStatus' }}]
      @ObjectModel.text.element: ['StatusText']
      Status,

      _TravelStatus._Text.Text as StatusText : localized,

      LastChangedAt,
      /* Associations */
      ///DMO/I_Travel_U
      _Booking : redirected to composition child /DMO/C_Booking_U,
      _Agency,
      _Currency,
      _Customer,
      _TravelStatus

}

子投影视图 /DMO/C_Booking_U

以下代码块为您提供 CDS 视图投影的实施,其中 CDS 视图 /DMO/I_Booking_U 用作相应 CDS 投影视图 /DMO/C_Booking_U 的投影源。它预计基础视图中的每个元素。

预订映射视图还显示在基础预订视图 /DMO/I_Travel_U 中定义的所有关联。但是,必须将构成重定向到父项 /DMO/I_Travel_U 以重定向到新创建的投影对应项。在 CDS 映射视图 中描述了定义重定向成分的语法。

要访问相应的文本或描述,本示例使用元素 AirlineID 和 ConnectionID 与相关文本提供程序视图 /DMO/I_Carrier 和 /DMO/I_Connection 中的文本元素之间的关系。其相应的标识元素使用 @ObjectModel.text.element 进行注释。在运行时,从数据库中读取参考的元素并按 OData 使用者的登录语言自动过滤。有关详细信息,请参阅: 使用文本元素

通过将注释 @Consumption.valueHelpDefinition 添加到相关元素,在预订实体 /DMO/C_Booking_U 的源代码中定义值帮助。您只需将 CDS 实体作为值帮助提供者分配到元素 CustomerID、AirlineID 和 CurrencyCode,并在 注释中为映射指定元素。如果您只想显示输入字段值帮助提供者视图中的值,则此简单值帮助方法非常方便。在这种情况下, 注释定义对提供实体的值帮助的绑定。您只需指定实体名称和元素,为注释元素提供可能的值。有关详细信息,请参阅:简单值帮助

清单 2 还演示了如何使用定义过滤条件的附加绑定实施值帮助。为过滤元素 FlightDate 和 /DMO/I_Flight 的值帮助结果列表定义了针对同一值帮助提供者实体 ConnectionID 值帮助的不同过滤条件。有关详细信息,请参阅:含附加绑定的值帮助

预订映射视图中的元素也可以在 UI 服务中搜索。因此,与搜索相关的注释也在实体级别的预订视图和特定元素中维护,以将其标记为主要搜索元素。有关搜索的详细信息,请参阅在 SAP Fiori 应用中启用文本和模糊搜索。

以下列表不包括定义 UI 布局的注释。它们外包到元数据扩展,请参阅将 UI 元数据添加到数据模型。

展开以下代码示例以查看 CDS 根映射视图 /DMO/C_Booking_U 的源代码。

示例代码

@EndUserText.label: 'Booking Projection View'
@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.allowExtensions: true

@Search.searchable: true
define view entity /DMO/C_Booking_U
  as projection on /DMO/I_Booking_U

{      ///DMO/I_Booking_U
      @Search.defaultSearchElement: true
  key TravelID,

      @Search.defaultSearchElement: true
  key BookingID,

      BookingDate,

      @Consumption.valueHelpDefinition: [{entity: {name: '/DMO/I_Customer_StdVH', element: 'CustomerID' }, useForValidation: true}]
      @Search.defaultSearchElement: true
      @ObjectModel.text.element: ['CustomerName']
      CustomerID,
      _Customer.LastName    as CustomerName,

      @ObjectModel.text.element: ['CarrierName']
      @Consumption.valueHelpDefinition: [
          { entity: {name: '/DMO/I_Flight_StdVH', element: 'AirlineID'},
            additionalBinding: [ { localElement: 'FlightDate',   element: 'FlightDate',   usage: #RESULT},
                                 { localElement: 'ConnectionID', element: 'ConnectionID', usage: #RESULT},
                                 { localElement: 'FlightPrice',  element: 'Price',        usage: #RESULT},
                                 { localElement: 'CurrencyCode', element: 'CurrencyCode', usage: #RESULT } ],
            useForValidation: true }
        ]
      AirlineID,
      _Carrier.Name      as CarrierName,

      @Consumption.valueHelpDefinition: [
          { entity: {name: '/DMO/I_Flight_StdVH', element: 'ConnectionID'},
            additionalBinding: [ { localElement: 'FlightDate',   element: 'FlightDate',   usage: #RESULT},
                                 { localElement: 'AirlineID',    element: 'AirlineID',    usage: #FILTER_AND_RESULT},
                                 { localElement: 'FlightPrice',  element: 'Price',        usage: #RESULT},
                                 { localElement: 'CurrencyCode', element: 'CurrencyCode', usage: #RESULT } ],
            useForValidation: true }
        ]
      ConnectionID,

      @Consumption.valueHelpDefinition: [
          { entity: {name: '/DMO/I_Flight_StdVH', element: 'FlightDate'},
            additionalBinding: [ { localElement: 'AirlineID',    element: 'AirlineID',    usage: #FILTER_AND_RESULT},
                                 { localElement: 'ConnectionID', element: 'ConnectionID', usage: #FILTER_AND_RESULT},
                                 { localElement: 'FlightPrice',  element: 'Price',        usage: #RESULT},
                                 { localElement: 'CurrencyCode', element: 'CurrencyCode', usage: #RESULT } ],
            useForValidation: true }
        ]
      FlightDate,

      @Consumption.valueHelpDefinition: [
          { entity: {name: '/DMO/I_Flight_StdVH', element: 'Price'},
            additionalBinding: [ { localElement: 'FlightDate',   element: 'FlightDate',   usage: #FILTER_AND_RESULT},
                                 { localElement: 'AirlineID',    element: 'AirlineID',    usage: #FILTER_AND_RESULT},
                                 { localElement: 'ConnectionID', element: 'ConnectionID', usage: #FILTER_AND_RESULT},
                                 { localElement: 'CurrencyCode', element: 'CurrencyCode', usage: #RESULT } ],
            useForValidation: true }
        ]
      FlightPrice,

      @Consumption.valueHelpDefinition: [{entity: {name: 'I_CurrencyStdVH', element: 'Currency' }, useForValidation: true }]
      CurrencyCode,

//      LastChangedAt,
      /* Associations */
      ///DMO/I_Booking_U
      _Travel: redirected to parent /DMO/C_Travel_U,
      _BookSupplement: redirected to composition child /DMO/C_BookingSupplement_U,
      _Carrier,
      _Connection,
      _Customer
}

与文本配置和值帮助相关的其他 CDS 视图不必投影数据模型结构,因为它们不是业务对象的一部分。