实施差旅实例的 CREATE 操作

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施差旅实例的 CREATE 操作

在本主题中,将指导您完成创建新差旅实例所需的所有实施步骤。我们将从 UI 开始激励实施步骤。

预览

如果基于 SAP Fiori 元素 Fiori 快速启动板运行 UI 服务,生成的 UI 会为您提供现有差旅项目的清单,包括针对 UI 消耗公开的所有字段。

要创建差旅项目,最终用户必须单击创建按钮并填写相关对象页面中的所有必填字段,以指定新差旅实例的所需信息。

用于编辑单个值的对象页面

用户单击对象页面上的保存按钮后,数据将保留在相应的数据库表中,并创建具有新差旅标识的差旅实例。

已保存数据显示在 Fiori UI 上

实施步骤

定义差旅实例创建的处理器类

与根节点行为实施的模板相对应,定义了本地处理器类 lhc_travel 以在一个单独的 FOR MODIFY 方法中实施每个更改操作。在这种情况下,create FOR MODIFY 方法应仅用于实施根实例的创建操作。因此,此方法的签名仅包含一个导入参数 it_travel_create 用于参考要创建的差旅(根)实例。要标识根实体,根据行为定义中指定的别名使用别名 travel。请注意,导入参数 entities 在设计时没有固定数据类型。在运行时,数据类型由编译器分配,其类型派生自行为定义。

备注

本地处理器类 lhc_travel 继承自类 cl_abap_behavior_handler 并由框架自动实例化。

详细信息:<方法> FOR MODIFY

实施用于创建新差旅实例的 <method> FOR MODIFY

如下列表所示,<method> FOR MODIFY 实施的基本结构包括:

  • 要为根节点创建的所有新差旅实例的循环。

  • 通过使用运算符 MAPPING FROM ENTITY USING CONTROL 将 CDS 视图字段名称映射到数据库表字段名称。此运算符仅映射在导入参数的控制结构中标记的字段。

  • 调用业务逻辑功能模块 /DMO/FLIGHT_TRAVEL_CREATE 以创建新的差旅实例。

  • 调用 ADJUST_NUMBERS 以分配 TRAVEL_ID 和 BOOKING_ID

  • 失败时用于处理消息的消息处理。请参阅消息处理。

每个创建操作调用都可以生成失败键值 (<travel_create>-%cid) 和消息 (messages)。任何失败的键都存储在表 FAILED 中,而 REPORTED 表包含所有消息。有关 FAILED 和 REPORTED 的详细信息,请参阅 ABAP EML - 响应参数(ABAP 关键字文档)。在某些用例中,使用者使用尚未持久保存且可能还没有主键的数据。主键可以在 <method> FOR MODIFY 调用中创建,也可以在保存顺序(延迟编号)中创建。在此场景中使用的延迟编号用例中,只要未通过 RAP BO 运行时创建主键,就会使用实例的内容标识 (%CID and %PID) 进行处理。因此,内容标识也用作外键。

如果成功 (messages IS INITIAL),会将内容标识为 %CID 的两个值和 ADJUST NUMBERS 方法中分配的新键值 travelid 写入到 mapped-travel 表中。

展开以下代码示例以查看方法 create 的源代码。

示例代码

CLASS lhc_travel IMPLEMENTATION.

  METHOD create.
    DATA: messages   TYPE /dmo/t_message,
          travel_in  TYPE /dmo/travel,
          travel_out TYPE /dmo/travel.

    LOOP AT entities ASSIGNING FIELD-SYMBOL(<travel_create>).

      travel_in = CORRESPONDING #( <travel_create> MAPPING FROM ENTITY USING CONTROL ).

      CALL FUNCTION '/DMO/FLIGHT_TRAVEL_CREATE'
        EXPORTING
          iv_numbering_mode = /dmo/if_flight_legacy=>numbering_mode-late
        IMPORTING
          es_travel   = travel_out
          et_messages = messages.

      map_messages(
          EXPORTING
            cid       = <travel_create>-%cid
            messages  = messages
          IMPORTING
            failed_added = DATA(failed_added)
          CHANGING
            failed    = failed-travel
            reported  = reported-travel
        ).

      IF failed_added = abap_false.
        INSERT VALUE #(
            %cid     = <travel_create>-%cid
            travelid = travel_out-travel_id )
          INTO TABLE mapped-travel.
      ENDIF.

    ENDLOOP.
  ENDMETHOD.

  ...

ENDCLASS.

消息处理

展开以下代码示例以查看方法 get_cause_from_message 的源代码。

示例代码

CLASS /dmo/cl_travel_auxiliary DEFINITION
  INHERITING FROM cl_abap_behv
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.

    CLASS-METHODS get_cause_from_message
      IMPORTING
        msgid             TYPE symsgid
        msgno             TYPE symsgno
        is_dependend      TYPE abap_bool DEFAULT abap_false
      RETURNING
        VALUE(fail_cause) TYPE if_abap_behv=>t_fail_cause.

ENDCLASS.

CLASS /dmo/cl_travel_auxiliary IMPLEMENTATION.

  METHOD get_cause_from_message.
    fail_cause = if_abap_behv=>cause-unspecific.

    IF msgid = '/DMO/CM_FLIGHT_LEGAC'.
      CASE msgno.
        WHEN '009'  "Travel Key initial
          OR '016'  "Travel does not exist
          OR '017'  "Booking does not exist
          OR '021'. "BookingSupplement does not exist
          IF is_dependend = abap_true.
            fail_cause = if_abap_behv=>cause-unspecific.
          ELSE.
            fail_cause = if_abap_behv=>cause-not_found.
          ENDIF.
        WHEN '032'. "Travel is locked by
          fail_cause = if_abap_behv=>cause-locked.
        WHEN '046'. "You are not authorized
          fail_cause = if_abap_behv=>cause-unauthorized.
      ENDCASE.
    ENDIF.
  ENDMETHOD.

ENDCLASS.

执行最终提交并释放缓存

调整数量

在不返回点后的 save 期间调用 ADJUST_NUMBERS 方法时,将执行功能模块 /DMO/FLIGHT_TRAVEL_ADJ_NUMBERS 并生成键值。然后将初步键值从 %tmp 映射到最终键值。在此用例中,使用就地编号,这意味着在 RAP 交互阶段将临时键值分配到 %key。有关详细信息 %tmp,请参阅 ABAP EML -%tmp(ABAP 关键字文档)。有关 ADJUST_NUMBERS 的详细信息,请参阅 ADJUST_NUMBERS。

展开以下代码示例以查看方法 adjust_numbers 的源代码。

示例代码

CLASS lsc_saver IMPLEMENTATION.
  ...
  METHOD adjust_numbers.

    DATA: travel_mapping       TYPE /dmo/if_flight_legacy=>tt_ln_travel_mapping,
          booking_mapping      TYPE /dmo/if_flight_legacy=>tt_ln_booking_mapping,
          bookingsuppl_mapping TYPE /dmo/if_flight_legacy=>tt_ln_bookingsuppl_mapping.

    CALL FUNCTION '/DMO/FLIGHT_TRAVEL_ADJ_NUMBERS'
      IMPORTING
        et_travel_mapping       = travel_mapping
        et_booking_mapping      = booking_mapping
        et_bookingsuppl_mapping = bookingsuppl_mapping.

    mapped-travel            = VALUE #( FOR travel IN travel_mapping             ( %tmp                = VALUE #( TravelID = travel-preliminary-travel_id )
                                                                                   TravelID            = travel-final-travel_id ) ).

    mapped-booking           = VALUE #( FOR booking IN booking_mapping           ( %tmp                = VALUE #( TravelID  = booking-preliminary-travel_id
                                                                                                                  BookingID = booking-preliminary-booking_id )
                                                                                   TravelID            = booking-final-travel_id
                                                                                   BookingID           = booking-final-booking_id ) ).

    mapped-bookingsupplement = VALUE #( FOR bookingsuppl IN bookingsuppl_mapping ( %tmp                = VALUE #( TravelID            = bookingsuppl-preliminary-travel_id
                                                                                                                  BookingID           = bookingsuppl-preliminary-booking_id
                                                                                                                  BookingSupplementID = bookingsuppl-preliminary-booking_supplement_id )
                                                                                   TravelID            = bookingsuppl-final-travel_id
                                                                                   BookingID           = bookingsuppl-final-booking_id
                                                                                   BookingSupplementID = bookingsuppl-final-booking_supplement_id ) ).

  ENDMETHOD.

SAVE 序列

调用 save 方法时,将在数据库上执行最终提交,并将用户输入的数据保存到新的差旅实例中。如下方列表所示,保存方法仅执行历史业务逻辑中功能模块 /DMO/FLIGHT_TRAVEL_SAVE 的调用。

更多信息:SAVE

要在上次保存后放弃所有更改,请使用 cleanup 方法。此方法将调用从历史代码委托给功能模块 /DMO/FLIGHT_TRAVEL_INITIALIZE。

将清理方法的定义添加到 lsc_saver 并在实施中调用函数模块。

展开以下代码示例以查看 save sequence 的源代码。

示例代码

CLASS lsc_saver IMPLEMENTATION.
  ...
  METHOD save.
      CALL FUNCTION '/DMO/FLIGHT_TRAVEL_SAVE'.
  ENDMETHOD.
  METHOD cleanup.
    CALL FUNCTION '/DMO/FLIGHT_TRAVEL_INITIALIZE'.
  ENDMETHOD.

ENDCLASS.

检查结果

此时,您可以查看生成的应用如何工作,尤其是 CREATE 操作的新实施。但是,为此,必须首先定义和发布合适的 UI 使用业务服务。

有关详细信息,请参阅: 为 Fiori UI 定义业务服务