实施差旅数据的 UPDATE 操作

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施差旅数据的 UPDATE 操作

本主题将指导您完成对现有差旅实例的数据更新所需的实施步骤。但是,在这种情况下,除了 <method> FOR MODIFY 之外,还必须实施 <method> FOR READ。它提供应用程序缓冲区的读取访问权限,这是 ETag 比较所必需的。

预览

在我们的差旅应用程序场景中,当用户单击 Fiori UI 上的编辑按钮时,应针对差旅实例的所有所需项目修改相应的业务数据。

已保存差旅数据

在更改模式下,最终用户可以更改相关差旅字段,如下图所示。用户选择对象页面上的保存按钮后,更改的差旅数据将保存在相应的表中,并创建相关差旅实例的新版本。

已保存差旅数据

实施步骤

定义实施差旅数据更新的方法

与根节点行为实施的模板相对应,定义了本地处理器类 lhc_travel 以实施每个更改操作。在这种情况下,update FOR MODIFY 方法应仅用于实施根实例的更新操作。因此,此方法的签名仅包含一个导入参数 entities 用于引用要更新的 travel(根)实例。

<method> FOR MODIFY 签名(摘录自模板)

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.

    METHODS:
      ...
    METHODS update FOR MODIFY
      IMPORTING entities FOR UPDATE travel.

ENDCLASS.

实施差旅数据更新的 <method> FOR MODIFY

FOR MODIFY 方法实施的基本结构与用于创建差旅实例的处理器类的结构非常相似:

  • 要为根节点更新的所有新差旅实例的循环。

  • 使用运算符 MAPPING FROM ENTITY 将 CDS 视图字段名称映射到数据库表字段名称。此运算符映射在行为定义的映射规范中声明的每个字段。

  • 将导入参数的 %control-结构映射到预定义的标志结构 ls_travelx。控制结构标识客户端更改了哪些实体字段。它包含数据字段的键值和标志结构,并在 BAPI 中用于将每个单独的数据字段标记为已更改。

  • 调用业务逻辑功能模块 /DMO/FLIGHT_TRAVEL_UPDATE 以更新差旅实例。

  • 失败时用于处理消息的消息处理。

每个更新调用都可以生成失败的键和消息 (lt_messages)。通过内容标识 (<travel_update>-%cid_ref) 和值 <travel_update>-travelid) 寻址失败的键值。如果失败,失败键将保存在 failed-travel 表中,而 reported-travel 表包含特定于实例的所有消息。

展开以下代码示例以查看方法 update 的源代码。

示例代码

CLASS lhc_travel IMPLEMENTATION.
  ...

 METHOD update.
    DATA: messages TYPE /dmo/t_message,
          travel   TYPE /dmo/travel,
          travelx  TYPE /dmo/s_travel_inx. "refers to x structure (> BAPIs)

    LOOP AT entities ASSIGNING FIELD-SYMBOL(<travel_update>).

      travel = CORRESPONDING #( <travel_update> MAPPING FROM ENTITY ).

      travelx-travel_id = <travel_update>-TravelID.
      travelx-_intx     = CORRESPONDING #( <travel_update> MAPPING FROM ENTITY ).

      CALL FUNCTION '/DMO/FLIGHT_TRAVEL_UPDATE'
        EXPORTING
          is_travel   = CORRESPONDING /dmo/s_travel_in( travel )
          is_travelx  = travelx
        IMPORTING
          et_messages = messages.

      map_messages(
          EXPORTING
            cid       = <travel_update>-%cid_ref
            travel_id = <travel_update>-travelid
            messages  = messages
          CHANGING
            failed    = failed-travel
            reported  = reported-travel
        ).

    ENDLOOP.
  ENDMETHOD.

  ...

ENDCLASS.

更新差旅实例的数据

<fs_travel_update> 的 F2 访问

实施 <method> FOR READ 进行 ETag 处理

在对现有差旅数据集进行数据更新的上下文中,从应用程序缓冲区检索当前数据非常重要。请记住,我们在行为定义中为根实体指定了 ETag:

define behavior for /DMO/I_Travel_U alias travel
etag master LastChangedAt
{
...

}

ETag 确定对请求数据集的更改,以帮助防止数据集的同时更新相互覆盖。这正是 ETag 检查需要缓冲区数据的原因。<method> FOR READ 旨在返回应用程序缓冲区中的数据。

有关如何实施此方法的详细信息,请参阅实施差旅数据的 READ 操作。