实施差旅数据的 READ 操作

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施差旅数据的 READ 操作

本主题将指导您完成从事务缓冲区读取差旅实例所需的实施步骤。

上下文

与 CREATE、UPDATE 或 DELETE 操作相比,READ 在 Fiori UI 上没有其直接触发器。

记住

UI 上的执行按钮不会在行为池中调用 <method> FOR READ(事务 READ)。相反,执行按钮通过 RAP 运行时引擎执行查询,并直接从数据库中读取数据。

READ 操作提供对应用程序缓冲区的读取访问。用于在交互阶段检索数据以进行进一步处理。这是必要的,例如,在执行 UPDATE 时进行 ETag 比较。检查操作的条件以决定是启用还是禁用操作。在差旅场景中,调用操作 <method> for UPDATE,必须将应用程序缓冲区中的 ETag 值与 UI 上显示的值进行比较。仅当这些值相对应时,才会触发 UPDATE。此检查确保最终用户在 UI 上看到的数据未被其他使用者更改。

动态操作控制 READ 在状态为 set_to_booked 时也需要 booked。因此,必须读取事务缓冲区中的数据才能相应地显示操作按钮。

这两个用例都与我们的差旅场景相关。因此,有必要实施 <method> FOR READ。

还需要使用 READ 完成业务对象并使其可由 EML 访问。在这种情况下,您可以直接从 ABAP 使用业务对象。

实施步骤

无法在行为定义中声明 READ 操作,因为它始终隐式假定已实施 READ。

定义 <method> FOR READ 的签名

在差旅处理器类的定义部分中,使用导入参数和结果参数为 READ 定义方法 read_travel。

<method> for READ 的签名

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.
    METHODS:
          ...
    METHODS read FOR READ
      IMPORTING keys FOR READ travel RESULT result.
         ... .
ENDCLASS.

有关详细信息,请参阅 <方法> FOR READ。

实施 <method> FOR READ

要从应用程序缓冲区返回实际数据,将导入的差旅标识传递到读取功能模块 /DMO/FLIGHT_TRAVEL_READ。功能模块返回与差旅标识对应的实体实例,如果发生错误,则返回消息。然后,使用使用者请求的字段的键值和值填充结果参数 result。在导入参数 keys 的控制结构中标记这些字段。

使用更改参数 failed,指定出错时的失败原因。例如,如果使用的功能模块返回消息编号 16,则未找到差旅标识。在这种情况下,您可以返回失败原因 not_found。对于所有其他错误,返回失败原因 unspecific。

展开以下代码示例以查看方法 read 的源代码。

示例代码

...
METHOD read.
    DATA: travel_out TYPE /dmo/travel,
          messages   TYPE /dmo/t_message.

    LOOP AT keys ASSIGNING FIELD-SYMBOL(<travel_to_read>) GROUP BY <travel_to_read>-%tky.

      CALL FUNCTION '/DMO/FLIGHT_TRAVEL_READ'
        EXPORTING
          iv_travel_id = <travel_to_read>-travelid
        IMPORTING
          es_travel    = travel_out
          et_messages  = messages.

      map_messages(
          EXPORTING
            travel_id        = <travel_to_read>-TravelID
            messages         = messages
            IMPORTING
            failed_added = DATA(failed_added)
          CHANGING
            failed           = failed-travel
            reported         = reported-travel
        ).

      IF failed_added = abap_false.
        INSERT CORRESPONDING #( travel_out MAPPING TO ENTITY ) INTO TABLE result.
      ENDIF.
    ENDLOOP.
  ENDMETHOD.
...

测试 READ

与 CREATE、UPDATE 和 DELETE 操作相比,无法使用 Fiori UI 轻松测试 READ,因为不存在用于从应用程序缓冲区读取数据的直接执行触发器。但是,您可以使用 EML 测试 READ 实施。

示例

    READ ENTITY /DMO/I_Travel_U FIELDS ( TravelID
                                         AgencyID
                                         CustomerID
                                         BeginDate
                                         EndDate
                                         BookingFee
                                         TotalPrice
                                         CurrencyCode
                                         Memo
                                         Status
                                         LastChangedAt )
        WITH VALUE #( ( %key-TravelID = lv_travel_id ) )
      RESULT   DATA(lt_received_travel_data)
      FAILED   DATA(ls_failed).

要检索相应差旅标识的完整实体实例,必须显式标记每个元素。有关 EML 的详细信息,请参阅实体操作语言 (EML) 。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 实施差旅数据的 UPDATE 操作 · 实施差旅实例的 DELETE 操作 →