实施相关预订的创建操作
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施相关预订的创建操作
在本主题中,将指导您完成创建新预订所需的所有实施步骤。
在我们的演示应用程序中,我们假设无法单独创建新预订,但只能与给定差旅实例结合使用。
在 _Booking 关联的行为定义中考虑只能为特定差旅实例创建新预订实例这一事实:
define behavior for /DMO/I_Travel_U alias travel
...
{
...
association _Booking { create; }
}
关键字 { create; } 声明此关联已启用创建,确切意味着关联预订的实例由差旅实例创建。
预览
要将新预订添加到所选差旅实例,最终用户必须单击创建按钮并编辑某些字段以指定新预订的所需信息。

用户单击 Fiori 对象页面上的创建按钮后,将立即创建具有新预订编号的预订数据集。

实施步骤
定义创建相关预订的方法
与根实体的模板相对应,定义本地处理器类 lhc_travel 以在单个 <method> FOR MODIFY 中实施每个更改操作。在这种情况下,cba_booking FOR MODIFY 方法应仅用于通过关联实施预订实例的创建操作。cba_Booking FOR MODIFY 的签名仅包含一个导入参数 entities_cba 以参考要创建的相关预订实例。
为了识别关联的预订,根据行为定义中指定的别名使用根实体和子实体的别名。关联以下列形式表示:
… FOR CREATE root\_child_entity。
cba_booking FOR MODIFY 方法的签名(摘录自模板)
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
...
METHODS cba_Booking FOR MODIFY
IMPORTING entities_cba FOR CREATE travel\_Booking.
ENDCLASS.
实施用于创建新预订实例的 FOR MODIFY 方法
如下面的列表所示,FOR MODIFY 方法的实施由 loop 在要创建相关预订的所有选定差旅实例中启动。每个选定的差旅(根)实例都由差旅标识表示为主键 (travelid)。
即使在此类情况下,使用者也可能使用尚未保留且可能还没有主键的数据(例如,如果稍后将在保存序列中创建主键(延迟编号))。在这种情况下,只要业务对象运行时未创建主键,就会使用临时主键、差旅实例的内容标识 (%CID)。然后将内容标识写入 mapped-travel 表。
在创建新的预订数据集之前,我们首先需要检索所选差旅实例已存在的所有预订 (booking_old)。通过调用 /DMO/FLIGHT_TRAVEL_READ 功能模块完成此操作。
如果失败,则通过 map_messages 方法处理消息,正如我们在之前主题中实施 FOR MODIFY 所知道的。
如果成功,则必须确定最大预订编号。对于新预订实例,最后一个给定的预订编号 last_booking_id 将增加 1。
针对给定差旅实例创建新预订将在要创建的预订实例中进一步进行 loop,这些实例由关联 <travel>-%target 寻址。此关联包括用于处理成分目标的预定义组件 %target。
要为预订数据提供传入结构,需要 CDS 视图中 元素和原始表字段之间的映射。此映射由运算符 MAPPING FROM ENTITY USING CONTROL 实施,该运算符根据行为定义和控制结构中的映射规范将 CDS 视图字段映射到数据库表字段。
通过调用功能模块 /DMO/FLIGHT_TRAVEL_UPDATE 创建新登记数据集之前,可通过语句 booking-booking_id += 1. 轻松确定要创建的登记实例的登记标识。
如果成功,内容标识为 %CID、键值为 travelid 和 bookingid 的值将写入 mapped-booking 表。
函数调用可以生成失败键 (<bbooking_create>-%cid) 和消息 (messages)。任何失败的键值都存储在表 failed-booking 中,而 reported-booking 表包含特定于失败预订实例的所有消息
展开以下代码示例以查看方法 cba_Booking 的源代码。
示例代码
CLASS lhc_travel IMPLEMENTATION.
...
METHOD cba_Booking.
DATA: messages TYPE /dmo/t_message,
booking_old TYPE /dmo/t_booking,
booking TYPE /dmo/booking,
last_booking_id TYPE /dmo/booking_id VALUE '0'.
LOOP AT entities_cba ASSIGNING FIELD-SYMBOL(<travel>).
DATA(travelid) = <travel>-travelid.
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_READ'
EXPORTING
iv_travel_id = travelid
IMPORTING
et_booking = booking_old
et_messages = messages.
map_messages(
EXPORTING
cid = <travel>-%cid_ref
travel_id = <travel>-TravelID
messages = messages
IMPORTING
failed_added = DATA(failed_added)
CHANGING
failed = failed-travel
reported = reported-travel
).
IF failed_added = abap_true.
LOOP AT <travel>-%target ASSIGNING FIELD-SYMBOL(<booking>).
map_messages_assoc_to_booking(
EXPORTING
cid = <booking>-%cid
travel_id = <travel>-TravelID
booking_id = <booking>-BookingID
is_dependend = abap_true
messages = messages
CHANGING
failed = failed-booking
reported = reported-booking
).
ENDLOOP.
ELSE.
" Set the last_booking_id to the highest value of booking_old booking_id or initial value if none exist
last_booking_id = VALUE #( booking_old[ lines( booking_old ) ]-booking_id OPTIONAL ).
LOOP AT <travel>-%target ASSIGNING FIELD-SYMBOL(<booking_create>).
booking = CORRESPONDING #( <booking_create> MAPPING FROM ENTITY USING CONTROL ) .
last_booking_id += 1.
booking-booking_id = last_booking_id.
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_UPDATE'
EXPORTING
is_travel = VALUE /dmo/s_travel_in( travel_id = travelid )
is_travelx = VALUE /dmo/s_travel_inx( travel_id = travelid )
it_booking = VALUE /dmo/t_booking_in( ( CORRESPONDING #( booking ) ) )
it_bookingx = VALUE /dmo/t_booking_inx(
(
booking_id = booking-booking_id
action_code = /dmo/if_flight_legacy=>action_code-create
)
)
IMPORTING
et_messages = messages.
map_messages_assoc_to_booking(
EXPORTING
travel_id = <booking_create>-TravelID
booking_id = <booking_create>-bookingID
messages = messages
IMPORTING
failed_added = failed_added
CHANGING
failed = failed-booking
reported = reported-booking
).
IF failed_added = abap_false.
INSERT
VALUE #(
%cid = <booking_create>-%cid
travelid = travelid
bookingid = booking-booking_id
) INTO TABLE mapped-booking.
ENDIF.
ENDLOOP.
ENDIF.
ENDLOOP.
ENDMETHOD.