实施按关联创建的动态操作控制
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施相关预订的创建操作 › 实施按关联创建的动态操作控制
本主题将指导您完成所需的实施步骤,以动态启用和禁用预订关联创建操作。
上下文
根据差旅实例的 Status 字段的值,在相应的差旅实例上启用或禁用通过关联创建操作。
仅当启用操作时,Fiori 元素应用预览才会在对象页面上显示相关预订的创建按钮。
实施步骤
在行为定义中定义动态功能控制
在行为定义中,按关联创建的功能控件定义如下:
...
define behavior for /DMO/I_Travel_U alias travel
implementation in class /DMO/BP_TRAVEL_U unique
...
{
...
association _Booking { create (features: instance); }
...
}
在行为池中实施动态功能控制
必须声明 <method> FOR FEATURES。有关详细信息,请参阅
读取差旅实例,并根据字段 Status 的值启用或禁用通过关联创建。
展开以下代码示例以查看 CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler 的源代码。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
...
METHODS get_instance_features FOR INSTANCE FEATURES
IMPORTING keys REQUEST requested_features FOR travel RESULT result.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
...
METHOD get_instance_features.
READ ENTITIES OF /DMO/I_Travel_U IN LOCAL MODE
ENTITY Travel
FIELDS ( TravelID Status )
WITH CORRESPONDING #( keys )
RESULT DATA(travel_read_results)
FAILED failed.
result = VALUE #(
FOR travel_read_result IN travel_read_results (
%tky = travel_read_result-%tky
%features-%action-set_status_booked = COND #( WHEN travel_read_result-Status = 'B'
THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled )
%assoc-_Booking = COND #( WHEN travel_read_result-Status = 'B' OR travel_read_result-Status = 'X'
THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled )
) ).
ENDMETHOD.
ENDCLASS.