实施相关预订的 READ 操作
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施相关预订的 READ 操作
本主题将指导您完成所需的实施步骤,以从缓冲区中读取与差旅实例相关联的预订实例。
上下文
与差旅数据的 READ 类似,UI 上没有 READ by association 的显式触发器。但是,业务对象必须可完全由 EML 使用,因此有必要实施一种方法,以在差旅场景中读取与特定差旅标识相关联的预订。
READ by association 操作通过读取父实体的子实体实例提供对应用程序缓冲区的读取访问权限。用于在交互阶段检索数据以进行进一步处理。
实施步骤
不必在行为定义中声明 READ by association 操作,因为它始终隐式假定 READ by association 已实现。但是,您可以显式指定:
define behavior for /DMO/I_Travel_U alias travel
{
...
association _Booking;
}
1. 界定 <method> FOR READ by association 的签名
在差旅处理器类的定义部分中,使用实体输入参数 read_booking_ba 和 LINK 以及输出参数 IMPORTING 和 FULL 为 READ travel\_Booking 定义方法 RESULT。
布尔参数 FULL 指示使用者是请求完成实体实例还是仅通过参数 LINK 返回的键值。
参数 RESULT 根据导入参数的控制结构返回完整的关联实体实例集。
参数 LINK 返回源实体和关联目标实体的键值。
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
...
METHODS rba_Booking FOR READ
IMPORTING keys_rba FOR READ travel\_Booking FULL result_requested RESULT result LINK association_links.
... .
ENDCLASS.
实施 <method> FOR READ by association
要从应用程序缓冲区返回实际数据,将导入的行程标识传递到读取功能模块 /DMO/FLIGHT_TRAVEL_READ。功能模块返回与差旅标识相对应的相关预订的实体实例,并在发生错误时返回可能的消息。如果未返回任何消息,则对于每个关联的预订,使用差旅实例的相应源键值和预订实例的目标键值填充输出参数 association_links。
在更改参数 failed 中,指定出错时的失败原因。例如,如果使用的功能模块返回消息编号 16,则未找到差旅标识。在这种情况下,您可以返回失败原因 not_found。对于所有其他错误,返回失败原因 unspecific。
展开以下代码示例以查看方法 rba_Booking 的源代码。
示例代码
METHOD rba_Booking.
DATA: travel_out TYPE /dmo/travel,
booking_out TYPE /dmo/t_booking,
booking LIKE LINE OF result,
messages TYPE /dmo/t_message.
LOOP AT keys_rba ASSIGNING FIELD-SYMBOL(<travel_rba>) GROUP BY <travel_rba>-TravelID.
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_READ'
EXPORTING
iv_travel_id = <travel_rba>-travelid
IMPORTING
es_travel = travel_out
et_booking = booking_out
et_messages = messages.
map_messages(
EXPORTING
travel_id = <travel_rba>-TravelID
messages = messages
IMPORTING
failed_added = DATA(failed_added)
CHANGING
failed = failed-travel
reported = reported-travel
).
IF failed_added = abap_false.
LOOP AT booking_out ASSIGNING FIELD-SYMBOL(<booking>).
"fill link table with key fields
INSERT
VALUE #(
source-%tky = <travel_rba>-%tky
target-%tky = VALUE #(
TravelID = <booking>-travel_id
BookingID = <booking>-booking_id
) )
INTO TABLE association_links.
IF result_requested = abap_true.
booking = CORRESPONDING #( <booking> MAPPING TO ENTITY ).
INSERT booking INTO TABLE result.
ENDIF.
ENDLOOP.
ENDIF.
ENDLOOP.
SORT association_links BY target ASCENDING.
DELETE ADJACENT DUPLICATES FROM association_links COMPARING ALL FIELDS.
SORT result BY %tky ASCENDING.
DELETE ADJACENT DUPLICATES FROM result COMPARING ALL FIELDS.
ENDMETHOD.
测试
就像 READ 操作一样,无法使用 Fiori UI 轻松测试 READ by association,因为不存在用于从应用程序缓冲区读取相关预订的直接执行触发器。但是,您可以使用 EML 测试 READ by association 实施。
示例
READ ENTITY /dmo/i_travel_u
BY \_Booking FIELDS ( AirlineID
BookingDate
BookingID
CustomerID
CurrencyCode
LastChangedAt )
WITH VALUE #( ( %key-TravelID = travelID ) )
RESULT DATA(lt_read_bookings_ba)
LINK DATA(lt_link_table)
FAILED DATA(ls_failed_rba).
如果请求 RESULT 参数,则设置导入参数 FULL 并根据控制标志检索值。参数 LINK 与控制标志无关,始终检索源实体和目标实体的键值。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 实施按关联创建的动态操作控制 · 实施 LOCK 操作 →