实施 LOCK 操作

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施 LOCK 操作

本主题将指导您完成锁定数据库上的实例所需的实施步骤。

上下文

锁定可防止同时对数据库进行更改。

锁定操作在修改操作之前执行。它在修改操作期间锁定实体实例,并禁用其他客户端修改特定实例及其所有锁定相关实例。修改操作完成后,将释放锁。

有关详细信息,请参阅悲观并发控制(锁定)。

在非托管场景中,差旅实体定义为锁定主数据,预订实体定义为锁定相关。这意味着,锁定机制始终锁定锁主实例及其所有从属实例。例如,如果由于预订实例更新而执行锁定操作,则也会锁定父差旅实例及其所有预订实例。

要启用锁定,必须实现 method FOR LOCK。非托管场景的历史代码包括锁对象,必须在 method FOR LOCK 中调用该对象以锁定相关实体实例。

预览

在我们的场景中,应该无法在数据库中保存更改,而同一锁主实体实例的其他实体实例正在同时更改。在这种情况下,UI 上的最终用户会收到错误消息:

相同锁主实例的实体实例并发更改。

实施步骤

非托管场景的历史代码包括锁对象,必须在 method FOR LOCK 中调用该对象以锁定相关实体实例。

定义用于锁定差旅实例的处理器类

与根节点行为实施的模板相对应,定义本地处理器类以实施每个操作。在这种情况下,方法 lock FOR LOCK 用于实施差旅业务对象的锁定操作。如以下列表所示,<method> FOR LOCK 的签名仅包含一个导入参数 keys 用于引用锁主密钥。

lock FOR LOCK 签名(摘录自模板)

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.
    METHODS:
          ...
    METHODS lock FOR LOCK
      IMPORTING keys FOR LOCK travel.
      ... .
ENDCLASS.

实施差旅实例的锁定

要锁定差旅实例及其锁定相关性,请实例化历史业务逻辑的锁对象 /DMO/ETRAVEL。这是通过调用 cl_abap_lock_object_factory 的工厂方法 get_instance 来完成的。除技术错误外,此实例化不得失败。如果发生这种情况,可以引发短转储。

调用锁对象的 enqueue 方法并传递导入的行程标识以执行锁定。如果实例已锁定,您将收到异常。此异常可由辅助类的 handle_travel_messages 处理,以填充 failed 和 reported 表。如果由于技术原因锁定失败,请引发短转储。

展开以下代码示例以查看方法 lock 的源代码。

示例代码

CLASS lhc_travel IMPLEMENTATION.

  ...

   METHOD lock.
    TRY.
        "Instantiate lock object
        DATA(lock) = cl_abap_lock_object_factory=>get_instance( iv_name = '/DMO/ETRAVEL' ).
      CATCH cx_abap_lock_failure INTO DATA(exception).
        RAISE SHORTDUMP exception.
    ENDTRY.

    LOOP AT keys ASSIGNING FIELD-SYMBOL(<travel>).
      TRY.
          "enqueue travel instance
          lock->enqueue(
              it_parameter  = VALUE #( (  name = 'TRAVEL_ID' value = REF #( <travel>-travelid ) ) )
          ).
          "if foreign lock exists
        CATCH cx_abap_foreign_lock INTO DATA(foreign_lock).
          map_messages(
           EXPORTING
                travel_id = <travel>-TravelID
                messages  =  VALUE #( (
                                           msgid = '/DMO/CM_FLIGHT_LEGAC'
                                           msgty = 'E'
                                           msgno = '032'
                                           msgv1 = <travel>-travelid
                                           msgv2 = foreign_lock->user_name )
                          )
              CHANGING
                failed    = failed-travel
                reported  = reported-travel
            ).

        CATCH cx_abap_lock_failure INTO exception.
          RAISE SHORTDUMP exception.
      ENDTRY.
    ENDLOOP.
  ENDMETHOD.

  ...

ENDCLASS.

测试

要测试锁定机制是否正常工作,请打开两次预览并在方法 enqueue 之后设置断点。

在第一个预览应用程序中,删除或更新任何实体实例。ADT 调试器在断点处停止。此时,已在所选实体实例的锁主数据及其相关项上设置入队锁。尝试对同一实体实例或其锁主数据的相关项执行其他预览应用程序的修改操作。此时不要在断点处停止。您将看到修改操作被拒绝,因为实体实例由第一个预览应用程序的客户端锁定。