实施 SET_STATUS_BOOKED 操作
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施 SET_STATUS_BOOKED 操作
本主题介绍与差旅实例相关的操作的实施。使用此操作,最终用户应能够更改差旅处理的状态。
预览
同样,我们使用基于 Fiori 元素运行结果应用的选项检查操作执行。运行应用时,UI 屏幕会为操作提供按钮设置为已预订,如下图所示。


实施步骤
在行为定义中定义操作后,必须在业务对象的行为池中实施。
定义操作方法
如操作实施中所述,方法 FOR ACTION 必须在行为池的私有部分中声明。
以下列表中源代码摘录的开头显示两种表类型的声明,一种用于 ACTION IMPORT(导入参数),另一个用于 ACTION RESULT(导出参数)。
导入参数是自由选择的名称。操作名称 set_status_booked 是指行为定义中定义的操作名称以及分配操作的实体 travel。结果参数也是自由选择的名称。
定义 set_travel_status FOR MODIFY 的签名
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
...
METHODS set_status_booked FOR MODIFY
IMPORTING keys FOR ACTION travel~set_status_booked RESULT result.
...
ENDCLASS.
实施 set_travel_status FOR MODIFY
要执行实际操作,需调用历史业务逻辑的功能模块 /DMO/FLIGHT_TRAVEL_SET_BOOKING。
主要实施步骤与 CUD 操作的实施相同。
要根据操作定义填充操作结果参数,必须执行读取。
展开以下代码示例以查看方法 set_status_booked 的源代码。
示例代码
CLASS lhc_travel IMPLEMENTATION.
...
METHOD set_status_booked.
DATA: messages TYPE /dmo/t_message,
travel_out TYPE /dmo/travel,
travel_set_status_booked LIKE LINE OF result.
CLEAR result.
LOOP AT keys ASSIGNING FIELD-SYMBOL(<travel_set_status_booked>).
DATA(travelid) = <travel_set_status_booked>-travelid.
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_SET_BOOKING'
EXPORTING
iv_travel_id = travelid
IMPORTING
et_messages = messages.
map_messages(
EXPORTING
travel_id = <travel_set_status_booked>-TravelID
messages = messages
IMPORTING
failed_added = DATA(failed_added)
CHANGING
failed = failed-travel
reported = reported-travel
).
IF failed_added = abap_false.
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_READ'
EXPORTING
iv_travel_id = travelid
IMPORTING
es_travel = travel_out.
travel_set_status_booked-travelid = travelid.
travel_set_status_booked-%param = CORRESPONDING #( travel_out MAPPING TO ENTITY ).
travel_set_status_booked-%param-travelid = travelid.
APPEND travel_set_status_booked TO result.
ENDIF.
ENDLOOP.
ENDMETHOD.
实施动态操作控制
要动态控制对单个实体实例执行的操作,必须将选项 (features: instance) 添加到行为定义中的操作 set_status_booked。必须在引用的类池中提供所需的实施。在类池的实施处理器中,可以指定启用或禁用操作的条件。