实施动态操作控制

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 实施交互阶段和保存顺序 › 实施 SET_STATUS_BOOKED 操作 › 实施动态操作控制

本主题将指导您完成所需的实施步骤以动态启用和禁用操作。

预览

下图显示了动态控制对操作按钮设置为已预订的影响:由于所选差旅实例的状态为 B(已预订),因此操作按钮已禁用。

操作的动态功能控制

实施步骤

1.在行为定义中定义动态功能控制

在行为定义中,操作 set_status_booked 的功能控件定义如下:

define behavior for /DMO/I_Travel_U alias travel
implementation in class /DMO/BP_TRAVEL_U unique
...

{
  ...

  action ( features : instance ) set_status_booked result [1] $self;
  ...
}

2.将操作的动态功能控制添加到行为池中的方法 get_features

必须将操作的功能控制添加到行为池中的方法 get_features。您可以在同一方法中对不同的操作或操作实施功能控制。

根据 Status 字段的值,启用或禁用 set_status_booked 操作。

展开以下代码示例以查看**方法 get_features 的源代码。

示例代码

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.

    METHODS:
        ...
        get_features      FOR FEATURES
                                IMPORTING keys REQUEST requested_features FOR travel
                                RESULT result.
ENDCLASS.

CLASS lhc_travel IMPLEMENTATION.
...

********************************************************************************
*
* Implements the dynamic action handling for travel instances
*
********************************************************************************
  METHOD get_features.

    READ ENTITIES OF /DMO/I_Travel_U IN LOCAL MODE
      ENTITY Travel
        FIELDS ( TravelID Status )
        WITH CORRESPONDING #( keys )
    RESULT DATA(lt_travel_result)
    FAILED failed.

    result = VALUE #(
      FOR ls_travel IN lt_travel_result (
        %key                                = ls_travel-%key
        %features-%action-set_status_booked = COND #( WHEN ls_travel-Status = 'B'
                                                      THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled )
        %assoc-_Booking                     = COND #( WHEN ls_travel-Status = 'B' OR ls_travel-Status = 'X'
                                                      THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled )

      ) ).

  ENDMETHOD.

ENDCLASS.