实施预订实例的 UPDATE、DELETE 和 READ 操作
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 定义并实施业务对象行为 › 实施业务对象的行为 › 为预订子实体创建行为池 › 实施预订实例的 UPDATE、DELETE 和 READ 操作
本主题将指导您完成数据更新和删除预订数据集所需的所有实施步骤。
演示应用程序场景中的行为定义需要预订子实体的标准操作 update 和 delete。请注意,read 操作未在行为定义中显式声明,而是隐式预期。create 由 create_by_association 在差旅行为中处理。此外,由于我们使用的 CDS 视图字段名称与数据库表中的不同,因此需要从 CDS 名称到数据库字段名称的映射规范。
define behavior for /DMO/I_Booking_U alias Booking
implementation in class /DMO/BP_BOOKING_U unique
etag dependent by _Travel
lock dependent by _Travel
authorization dependent by _Travel
{
field ( readonly ) TravelID, BookingID;
field ( mandatory ) BookingDate, CustomerID, AirlineID, ConnectionID, FlightDate;
update;
delete;
association _BookSupplement { create; }
association _Travel;
mapping for /dmo/booking control /dmo/s_booking_intx
{
AirlineID = carrier_id;
BookingDate = booking_date;
BookingID = booking_id;
ConnectionID = connection_id;
CurrencyCode = currency_code;
CustomerID = customer_id;
FlightDate = flight_date;
FlightPrice = flight_price;
TravelID = travel_id;
}
}
create 操作已使用 travel 根实体和 booking 子实体之间的关联关系实施。详细信息:实施相关预订的创建操作
预览(更新预订数据集)
例如,在我们的应用程序场景中,当用户单击 Fiori UI 对象页面上的编辑按钮时,应为预订实例的所有必填字段修改相应的预订数据集。

在更改模式下,最终用户可以更改相关差旅字段,如下图所示。用户选择对象页面上的保存按钮后,更改的预订数据将保留在数据库中,并创建相关预订实例的新版本。

实施步骤
为预订数据定义和实施 UPDATE
与预订子实体的行为实施模板相对应,定义一个本地处理器类 lhc_booking 以在单个 <method> FOR MODIFY 中实施每个更改操作,一个用于更新预订数据集,另一个用于删除预订。
处理器 update_booking FOR MODIFY 的 lhc_booking 方法实施预订的更新操作。此方法的签名仅包含一个导入表参数 entities 用于参考要更新的预订实例。
要更新登记数据,请调用功能模块 /DMO/FLIGHT_TRAVEL_UPDATE。除输入参数 is_travel 和 it_booking 外,还使用相应的标志结构 is_travelx 以及标志表类型 it_bookingx。
更新登记数据集时,必须首先检查最终用户更改了哪些个人数据。通过在可传递到更新功能模块的本地结构上映射导入参数的控制结构完成此检查。
用于在出现故障时处理实例特定消息的消息处理由 handle_booking_messages 方法实施。失败键值通过预订内容标识 (<booking>-%cid_ref) 和差旅标识 <booking>-travelid) 和预订标识 <booking>-bookingid 的值进行处理。如果失败,失败键将保存在 failed-booking 表中,而 reported-booking 表包含特定于实例的所有消息。
展开以下代码示例以查看方法 update 的源代码。
示例代码
**********************************************************************
*
* Handler class for managing bookings
*
**********************************************************************
CLASS lhc_booking DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
update FOR MODIFY
IMPORTING entities FOR UPDATE booking,
...
ENDCLASS.
CLASS lhc_booking IMPLEMENTATION.
**********************************************************************
*
* Implements the UPDATE operation for a set of booking instances
*
**********************************************************************
METHOD update.
DATA messages TYPE /dmo/t_message.
DATA booking TYPE /dmo/booking.
DATA bookingx TYPE /dmo/s_booking_inx.
LOOP AT entities ASSIGNING FIELD-SYMBOL(<booking>).
booking = CORRESPONDING #( <booking> MAPPING FROM ENTITY ).
bookingx-booking_id = <booking>-BookingID.
bookingx-_intx = CORRESPONDING #( <booking> MAPPING FROM ENTITY ).
bookingx-action_code = /dmo/if_flight_legacy=>action_code-update.
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_UPDATE'
EXPORTING
is_travel = VALUE /dmo/s_travel_in( travel_id = <booking>-travelid )
is_travelx = VALUE /dmo/s_travel_inx( travel_id = <booking>-travelid )
it_booking = VALUE /dmo/t_booking_in( ( CORRESPONDING #( booking ) ) )
it_bookingx = VALUE /dmo/t_booking_inx( ( bookingx ) )
IMPORTING
et_messages = messages.
/dmo/cl_travel_auxiliary=>handle_booking_messages(
EXPORTING
cid = <booking>-%cid_ref
travel_id = <booking>-travelid
booking_id = <booking>-bookingid
messages = messages
CHANGING
failed = failed-booking
reported = reported-booking ).
ENDLOOP.
ENDMETHOD.
在辅助类 中为预订实体添加数据类型声明
要使用用于处理预订操作的方法签名中所需的导入、导出或更改参数(稍后,在预订行为池的 FOR MODIFY 方法中),必须首先将相应的类型声明添加到辅助类定义部分的 PUBLIC 部分。
展开以下代码示例以查看辅助类 /dmo/cl_travel_auxiliary 的源代码。
示例代码
CLASS /dmo/cl_travel_auxiliary DEFINITION
INHERITING FROM cl_abap_behv
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
* Type definition for import parameters --------------------------
TYPES tt_booking_failed TYPE TABLE FOR FAILED /dmo/i_booking_u.
TYPES tt_booking_reported TYPE TABLE FOR REPORTED /dmo/i_booking_u.
...
ENDCLASS.
实施消息处理
处理预订实例的更改操作时,可能会发生故障事件。在这种情况下,对于实例特定消息的处理,使用方法 handle_booking_messages。
要参考出现错误 (msgty = 'E') 或中止 (msgty = 'A') 的单个数据集,请使用 FAILED 表,而实例特定的消息存储在 REPORTED 表中。
但是,源自历史代码的消息必须映射到基于类的业务对象框架的消息。要在不同的行为池中重用,请在帮助程序类 /dmo/cl_travel_auxiliary 中定义和实施相应的消息处理器方法。
展开以下代码示例以查看方法 handle_booking_messages 的源代码。
示例代码
CLASS /dmo/cl_travel_auxiliary DEFINITION
INHERITING FROM cl_abap_behv
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
...
CLASS-METHODS handle_booking_messages
IMPORTING
cid TYPE string OPTIONAL
travel_id TYPE /dmo/travel_id OPTIONAL
booking_id TYPE /dmo/booking_id OPTIONAL
messages TYPE /dmo/t_message
CHANGING
failed TYPE tt_booking_failed
reported TYPE tt_booking_reported.
ENDCLASS.
CLASS /dmo/cl_travel_auxiliary IMPLEMENTATION.
...
METHOD handle_booking_messages.
LOOP AT messages INTO DATA(message) WHERE msgty = 'E' OR msgty = 'A'.
APPEND VALUE #( %cid = cid
travelid = travel_id
bookingid = booking_id
%fail-cause = get_cause_from_message(
iv_msgid = message-msgid
iv_msgno = message-msgno
) ) TO failed.
APPEND VALUE #( %msg = get_message_object( )->new_message(
id = message-msgid
number = message-msgno
severity = if_abap_behv_message=>severity-error
v1 = message-msgv1
v2 = message-msgv2
v3 = message-msgv3
v4 = message-msgv4 )
%key-TravelID = travel_id
%cid = cid
TravelID = travel_id
BookingID = booking_id ) TO reported.
ENDLOOP.
ENDMETHOD.
...
ENDCLASS.
为预订实例定义和实施 DELETE 操作
在这种情况下,FOR MODIFY 方法用于实施预订数据集的删除操作。因此,<method> FOR MODIFY 的签名仅包含一个导入参数 keys 用于参考要删除的预订实例。要标识预订的子实体,根据行为定义中指定的别名使用别名 booking。
方法实施中的基本步骤类似于我们在先前方法 update 中所知道的步骤。还针对删除操作调用功能模块 /DMO/FLIGHT_TRAVEL_UPDATE。与之前的情况一样,此处使用相同的传入参数,包括标志结构 is_travelx 以及标志表 it_bookingx)。用于删除预订的相应操作代码由语句 action_code = /dmo/if_flight_legacy=>action_code-delete 定义。
展开以下代码示例以查看方法 delete 的源代码。
示例代码
**********************************************************************
*
* Handler class for managing bookings
*
**********************************************************************
CLASS lhc_booking DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
...
delete FOR MODIFY
IMPORTING keys FOR DELETE booking,
...
ENDCLASS.
CLASS lhc_booking IMPLEMENTATION.
**********************************************************************
*
* Implements the DELETE operation for a set of booking instances
*
**********************************************************************
METHOD delete.
DATA messages TYPE /dmo/t_message.
LOOP AT keys ASSIGNING FIELD-SYMBOL(<booking>).
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_UPDATE'
EXPORTING
is_travel = VALUE /dmo/s_travel_in( travel_id = <booking>-travelid )
is_travelx = VALUE /dmo/s_travel_inx( travel_id = <booking>-travelid )
it_booking = VALUE /dmo/t_booking_in( ( booking_id = <booking>-bookingid ) )
it_bookingx = VALUE /dmo/t_booking_inx( ( booking_id = <booking>-bookingid
action_code = /dmo/if_flight_legacy=>action_code-delete ) )
IMPORTING
et_messages = messages.
map_messages(
EXPORTING
cid = <booking>-%cid_ref
travel_id = <booking>-travelid
booking_id = <booking>-bookingid
messages = messages
CHANGING
failed = failed-booking
reported = reported-booking ).
ENDLOOP.
ENDMETHOD.
为预订实例定义和实施 READ 操作
READ 操作未在行为定义中指定。要完成业务对象,预期所有实体的 READ 都可以通过 EML 使用业务对象。
在登记实体的处理器类 中,使用导入参数 read_booking FOR READ 和结果参数 keys 添加方法 result 的声明。
有关详细信息,请参阅 <方法> FOR READ。
读取预订实体的实施步骤与读取差旅实体的实施步骤类似,请参阅实施差旅数据的 READ 操作。使用相同的功能模块。它根据传递到功能模块的差旅标识读取预订实例。出于性能原因,我们仅针对具有相同差旅标识的所有预订调用一次功能模块。这就是为什么,导入参数 的循环按差旅 ID 分组。由于功能模块 检索差旅标识 的所有可用预订,因此必须为与导入参数 keys 匹配的预订读取输出表。然后,对于使用者请求的字段,读取结果将传递到结果参数 result。键值始终传递到结果。
对于未找到相应差旅标识的预订标识、功能模块未找到的差旅标识以及其他无法指定的失败原因,将错误处理分开。
展开以下代码示例以查看方法 read 的源代码。
示例代码
**********************************************************************
*
* Handler class for managing bookings
*
**********************************************************************
CLASS lhc_booking DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS read FOR READ
IMPORTING keys FOR READ booking RESULT result.
ENDCLASS.
**********************************************************************
* Implements the READ operation for a set of booking instances
**********************************************************************
CLASS lhc_booking IMPLEMENTATION.
METHOD read.
DATA: travel_out TYPE /dmo/travel,
bookings_out TYPE /dmo/t_booking,
messages TYPE /dmo/t_message.
"Only one function call for each requested travelid
LOOP AT keys ASSIGNING FIELD-SYMBOL(<booking_by_travel>)
GROUP BY <booking_by_travel>-travelid .
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_READ'
EXPORTING
iv_travel_id = <booking_by_travel>-travelid
IMPORTING
es_travel = travel_out
et_booking = bookings_out
et_messages = messages.
map_messages(
EXPORTING
travel_id = <booking_by_travel>-travelid
booking_id = <booking_by_travel>-bookingid
messages = messages
IMPORTING
failed_added = DATA(failed_added)
CHANGING
failed = failed-booking
reported = reported-booking ).
IF failed_added = abap_false.
"For each travelID find the requested bookings
LOOP AT GROUP <booking_by_travel> ASSIGNING FIELD-SYMBOL(<booking>)
GROUP BY <booking>-%tky.
READ TABLE bookings_out INTO DATA(booking_out) WITH KEY travel_id = <booking>-%key-TravelID
booking_id = <booking>-%key-BookingID .
"if read was successful
IF sy-subrc = 0.
INSERT CORRESPONDING #( booking_out MAPPING TO ENTITY ) INTO TABLE result.
ELSE.
"BookingID not found
INSERT VALUE #( travelid = <booking>-TravelID
bookingid = <booking>-BookingID
%fail-cause = if_abap_behv=>cause-not_found )
INTO TABLE failed-booking.
ENDIF.
ENDLOOP.
ENDIF.
ENDLOOP.
ENDMETHOD.
为相关差旅实例定义和实施 READ 操作
从预订实例到其父差旅实例的逐项关联用于读取预订实例的 ETag 主数据。因此,支持差旅业务对象的完整 ETag 处理至关重要。此外,必须实施逐个读取关联以完成业务对象的事务处理,以便可通过 EML 使用。
为了以事务方式使用关联,在这种情况下,必须通过事务读取在预订实例的行为定义中指定关联:
define behavior for /DMO/I_Booking_U alias booking
{
...
association _Travel;
...
}
在预订实体的处理器类中,使用导入参数 rba_travel FOR READ booking\_travel 添加方法 keys_rba 的声明,为完整使用添加 result_requested 并声明 RESULT result 和 LINK association_links 作为更改参数。
有关详细信息,请参阅 <方法> FOR READ By Association。
在通过从预订实体关联读取差旅实例的实施中,在传入预订处循环并由传入 TravelID 分组。此分组优化了性能,因为功能调用仅针对每个差旅标识执行一次。如果读取相关差旅实例的函数调用成功,则在 <travel> 组中进行分组以为每个请求的预订填充链接表。如果请求差旅实例的所有字段,则使用功能模块读取的值填充结果参数 result。为确保仅填充已请求的字段(由导入参数的 %control 结构指示),使用具有附加项 MAPPING TO ENTITY 的相应运算符。
为避免重复的结果键,请从 link 表和 result 中删除重复项。
如果功能模块返回消息,请在 failed 表中填写相应的条目。对于未找到相应差旅标识的预订标识、功能模块未找到的差旅标识以及其他无法指定的失败原因,将错误处理分开。
展开以下代码示例以查看方法 rba_travel 的源代码。
示例代码
**********************************************************************
*
* Handler class for managing bookings
*
**********************************************************************
CLASS lhc_booking DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS rba_Travel FOR READ
IMPORTING keys_rba FOR READ booking\_Travel FULL result_requested RESULT result LINK association_links.
ENDCLASS.
CLASS lhc_booking IMPLEMENTATION.
...
**********************************************************************
*
* Read travel by association
*
**********************************************************************
METHOD rba_Travel.
DATA: travel TYPE /dmo/travel,
messages TYPE /dmo/t_message.
"Only one function call for each requested travelid
LOOP AT keys_rba ASSIGNING FIELD-SYMBOL(<booking_by_travel>)
GROUP BY <booking_by_travel>-travelid .
CALL FUNCTION '/DMO/FLIGHT_TRAVEL_READ'
EXPORTING
iv_travel_id = <booking_by_travel>-travelid
IMPORTING
es_travel = travel
et_messages = messages.
map_messages(
EXPORTING
travel_id = <booking_by_travel>-travelid
booking_id = <booking_by_travel>-bookingid
messages = messages
IMPORTING
failed_added = DATA(failed_added)
CHANGING
failed = failed-booking
reported = reported-booking ).
IF failed_added = abap_false.
LOOP AT keys_rba ASSIGNING FIELD-SYMBOL(<travel>) USING KEY entity WHERE TravelID = <booking_by_travel>-TravelID.
INSERT VALUE #(
source-%tky = <travel>-%tky
target-travelid = <travel>-TravelID
) INTO TABLE association_links.
IF result_requested = abap_true.
APPEND CORRESPONDING #( travel MAPPING TO ENTITY ) TO result.
ENDIF.
ENDLOOP.
ENDIF.
ENDLOOP.
SORT association_links BY source ASCENDING.
DELETE ADJACENT DUPLICATES FROM association_links COMPARING ALL FIELDS.
SORT result BY %tky ASCENDING.
DELETE ADJACENT DUPLICATES FROM result COMPARING ALL FIELDS.
ENDMETHOD.
检查结果
此时,您可以查看生成的应用如何用于 CREATE 和 UPDATE。但是,为此,必须首先定义和发布合适的 UI 使用业务服务。
有关详细信息,请参阅: 为 Fiori UI 定义业务服务
无法使用 Fiori UI 轻松测试 READ,因为不存在用于从应用程序缓冲区读取数据的直接执行触发器。但是,您可以使用 EML 测试 READ 实施。
示例
READ ENTITY /dmo/i_booking_U
FIELDS ( TravelID
BookingID
CustomerID
BookingDate )
WITH VALUE #( ( %key = VALUE #( TravelID = travelid
BookingID = bookingid ) ) )
RESULT DATA(read_result_travels)
FAILED DATA(failed_rba).
要检索相应差旅标识的完整实体实例,必须显式设置每个元素。有关 EML 的详细信息,请参阅使用 EML 访问业务对象的示例。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 为预订子实体创建行为池 · 投影行为 →