验证差旅实体的值
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发验证 › 验证差旅实体的值
对于具有草稿的托管场景,定义并实施差旅实体的验证,以进行值一致性检查。
验证 validateCustomer
在行为定义中定义验证,并在“差旅”的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 CustomerID 定义保存时验证。由于必须始终有客户分配到特定差旅,因此将字段 CustomerID 定义为 mandatory。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( mandatory ) CustomerID;
validation validateCustomer on save { create; field CustomerID; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查提供的值是否是客户数据库表中条目的 ID 来验证客户标识。如果值为初始值或无效,则为使用者发出充足的消息。以下步骤将指导您完成实施。
读取导入
keys到内部表travels的所有实例。此表是检查是否必须发出消息的基础。将条目复制到其他内部表,并删除具有初始客户标识的所有实例。如果生成的内部表不是初始值,则选择具有给定客户标识的
/DMO/CUSTOMER条目。如果此数据库表中没有相应的条目,则提供的客户标识无效。内部表
travels上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果客户标识为初始值,则将事务键值写入失败的表并将相应消息附加到状态区域
VALIDATE_CUSTOMER。RAP 运行时框架提供方法new message,您可以使用该方法轻松地从消息类中检索消息,从而提供相应的参数。报告的表包括组件%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。如果客户主数据表中没有条目,则将事务键值写入失败的表并将相应消息附加到状态区域
VALIDATE_CUSTOMER。
具有草稿的被管理场景的消息存储在消息类 /dmo/cm_flight 中,该消息类是 ABAP 航班参考场景的一部分。
展开以下代码示例以查看验证 validateCustomer** 的源代码**。
示例代码
METHOD validateCustomer.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( CustomerID )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DATA customers TYPE SORTED TABLE OF /DMO/CUSTOMER WITH UNIQUE KEY customer_id.
" Optimization of DB select: extract distinct non-initial customer IDs
customers = CORRESPONDING #( travels DISCARDING DUPLICATES MAPPING customer_id = CustomerID EXCEPT * ).
DELETE customers WHERE customer_id IS INITIAL.
IF customers IS NOT INITIAL.
" Check if customer ID exists
SELECT FROM /DMO/CUSTOMER FIELDS customer_id
FOR ALL ENTRIES IN @customers
WHERE customer_id = @customers-customer_id
INTO TABLE @DATA(valid_customers).
ENDIF.
" Raise message for non existing customer id
LOOP AT travels INTO DATA(travel).
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_CUSTOMER'
) TO reported-travel.
IF travel-CustomerID IS INITIAL.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_CUSTOMER'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_customer_id
severity = if_abap_behv_message=>severity-error )
%element-CustomerID = if_abap_behv=>mk-on
) TO reported-travel.
ELSEIF travel-CustomerID IS NOT INITIAL AND NOT line_exists( valid_customers[ customer_id = travel-CustomerID ] ).
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_CUSTOMER'
%msg = NEW /dmo/cm_flight_messages(
customer_id = travel-customerid
textid = /dmo/cm_flight_messages=>customer_unkown
severity = if_abap_behv_message=>severity-error )
%element-CustomerID = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateAgency
在行为定义中定义验证,并在“差旅”的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 AgencyID 定义保存时验证。由于必须始终将旅行社分配给特定差旅,因此将字段 AgencyID 定义为 mandatory。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( mandatory ) CustomerID, AgencyID;
validation validateAgency on save { create; field AgencyID; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查提供的值是否为代理数据库表中条目的标识,验证代理标识。如果值为初始值或无效,则为使用者发出充足的消息。实施步骤与验证 ValidateCustomer 完全相同。
展开以下代码示例以查看验证 validateAgency** 的源代码**。
示例代码
METHOD validateAgency.
DATA: modification_granted TYPE abap_boolean,
agency_country_code TYPE land1.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( AgencyID TravelID )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DATA agencies TYPE SORTED TABLE OF /dmo/agency WITH UNIQUE KEY agency_id.
" Optimization of DB select: extract distinct non-initial agency IDs
agencies = CORRESPONDING #( travels DISCARDING DUPLICATES MAPPING agency_id = AgencyID EXCEPT * ).
DELETE agencies WHERE agency_id IS INITIAL.
IF agencies IS NOT INITIAL.
" Check if Agency ID exists
SELECT FROM /dmo/agency FIELDS agency_id, country_code
FOR ALL ENTRIES IN @agencies
WHERE agency_id = @agencies-agency_id
INTO TABLE @DATA(valid_agencies).
ENDIF.
" Raise message for non existing Agency id
LOOP AT travels INTO DATA(travel).
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_AGENCY'
) TO reported-travel.
IF travel-AgencyID IS INITIAL.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_AGENCY'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_agency_id
severity = if_abap_behv_message=>severity-error )
%element-AgencyID = if_abap_behv=>mk-on
) TO reported-travel.
ELSEIF travel-AgencyID IS NOT INITIAL AND NOT line_exists( valid_agencies[ agency_id = travel-AgencyID ] ).
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_AGENCY'
%msg = NEW /dmo/cm_flight_messages(
agency_id = travel-agencyid
textid = /dmo/cm_flight_messages=>agency_unkown
severity = if_abap_behv_message=>severity-error )
%element-AgencyID = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateDates
在行为定义中定义验证,并在“差旅”的行为实施类中实施验证。
定义
使用触发器操作 create 和触发器字段 BeginDate 和 EndDate 定义保存时验证。由于差旅日期是差旅数据的重要部分,因此将字段 BeginDate 和 EndDate 定义为 mandatory。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( mandatory ) CustomerID, AgencyID, BeginDate, EndDate;
validation validateDates on save { create; field BeginDate, EndDate; }
… }
实施
通过将 BeginDate 的值与 EndDate 进行比较来验证差旅日期。结束日期不得早于开始日期,并且开始日期必须晚于系统日期。如果提供的值无效,则为使用者发出充足的消息。以下步骤将指导您完成实施。具有草稿的被管理场景的消息存储在消息类 /DMO/CM_FLIGHT 中,该消息类是 ABAP 航班参考场景的一部分。
读取导入
keys到内部表travels的所有实例。此表是检查是否必须发出消息的基础。内部表
travels上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。差旅日期必须满足四个条件:
开始日期不得为初始值。
结束日期不得为初始值。
开始日期不得早于系统日期。
结束日期不得早于开始日期。
对于所有情况,请使用
if-loop进行检查,并将事务键值附加到失败表。此外,将相应消息附加到状态区域VALIDATE_DATES。RAP 运行时框架提供方法new message,您可以使用该方法轻松地从消息类中检索消息,从而提供相应的参数。报告的表包括组件%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。
展开以下代码示例以查看验证 validateDates** 的源代码**。
示例代码
METHOD validateDates.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( BeginDate EndDate TravelID )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
LOOP AT travels INTO DATA(travel).
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_DATES' ) TO reported-travel.
IF travel-BeginDate IS INITIAL.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_DATES'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_begin_date
severity = if_abap_behv_message=>severity-error )
%element-BeginDate = if_abap_behv=>mk-on ) TO reported-travel.
ENDIF.
IF travel-EndDate IS INITIAL.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_DATES'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_end_date
severity = if_abap_behv_message=>severity-error )
%element-EndDate = if_abap_behv=>mk-on ) TO reported-travel.
ENDIF.
IF travel-EndDate < travel-BeginDate AND travel-BeginDate IS NOT INITIAL
AND travel-EndDate IS NOT INITIAL.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_DATES'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>begin_date_bef_end_date
begin_date = travel-BeginDate
end_date = travel-EndDate
severity = if_abap_behv_message=>severity-error )
%element-BeginDate = if_abap_behv=>mk-on
%element-EndDate = if_abap_behv=>mk-on ) TO reported-travel.
ENDIF.
IF travel-BeginDate < cl_abap_context_info=>get_system_date( ) AND travel-BeginDate IS NOT INITIAL.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_DATES'
%msg = NEW /dmo/cm_flight_messages(
begin_date = travel-BeginDate
textid = /dmo/cm_flight_messages=>begin_date_on_or_bef_sysdate
severity = if_abap_behv_message=>severity-error )
%element-BeginDate = if_abap_behv=>mk-on ) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateCurrenyCode
在行为定义中定义验证,并在“差旅”的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 CurrencyCode 定义保存时验证。由于必须始终为预订提供货币代码,因此将字段 CurrencyCode 定义为 mandatory。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( mandatory ) CurrencyCode;
validation validateCurrencyCode on save { create; field CurrencyCode; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查提供的值是否为货币数据库表中条目的标识,验证货币代码。如果值为初始值或无效,则为使用者发出充足的消息。以下步骤将指导您完成实施。
读取导入
keys到内部表travels的所有实例。此表是检查是否必须发出消息的基础。将条目复制到其他内部表,并删除具有初始货币代码的所有实例。如果生成的内部表不是初始值,则使用给定货币代码选择
I_Currency的条目。如果此数据库表中没有相应的条目,则提供的货币代码无效。内部表
travels上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果货币代码为初始值,则将交易代码写入失败的表并将相应消息附加到状态区域
VALIDATE_CURRENCYCODE。RAP 运行时框架提供方法new message,您可以使用该方法轻松地从消息类中检索消息,从而提供相应的参数。报告的表包括组件%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。如果货币代码主数据表中没有条目,则将交易代码写入失败的表并将相应消息附加到州范围
VALIDATE_CURRENCYCODE。
具有草稿的被管理场景的消息存储在消息类 /dmo/cm_flight_messages 中,该消息类是 ABAP 航班参考场景的一部分。
展开以下代码示例以查看验证 validateCurrencyCode** 的源代码**。
示例代码
METHOD validateCustomer.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( CustomerID )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DATA: currencies TYPE SORTED TABLE OF I_Currency WITH UNIQUE KEY currency.
currencies = CORRESPONDING #( travels DISCARDING DUPLICATES MAPPING currency = currencycode EXCEPT * ).
DELETE currencies WHERE currency IS INITIAL.
IF currencies IS NOT INITIAL.
SELECT FROM I_Currency FIELDS currency
FOR ALL ENTRIES IN @currencies
WHERE currency = @currencies-currency
INTO TABLE @DATA(currency_db).
ENDIF.
LOOP AT travels INTO DATA(travel).
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
) TO reported-travel.
IF travel-currencycode IS INITIAL.
" Raise message for empty Currency
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_required
severity = if_abap_behv_message=>severity-error )
%element-currencycode = if_abap_behv=>mk-on
) TO reported-travel.
ELSEIF NOT line_exists( currency_db[ currency = travel-currencycode ] ).
" Raise message for not existing Currency
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_not_existing
severity = if_abap_behv_message=>severity-error
currency_code = travel-currencycode )
%element-currencycode = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateBookingFee
在行为定义中定义验证,并在“差旅”的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 BookingFee 定义保存时验证。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
validation validateBookingFee on save { create; field BookingFee; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查输入的值是否小于 0 来验证预订费。如果值无效,则向使用者发出足够消息。以下步骤将指导您完成实施。
读取导入
keys到内部表travels的所有实例。此表是检查是否必须发出消息的基础。内部表
travels上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果预订费小于 0,则将事务键值写入失败表并将相应消息与状态区域
VALIDATE_BOOKINGFEE一起附加到该实例的报告表中。报告的表包括组件%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。
具有草稿的被管理场景的消息存储在消息类 /dmo/cm_flight_messages 中,该消息类是 ABAP 航班参考场景的一部分。
展开以下代码示例以查看验证 validateBookingFee** 的源代码**。
示例代码
METHOD validateBookingFee.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY travel
FIELDS ( BookingFee )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
LOOP AT travels INTO DATA(travel).
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_BOOKINGFEE'
) TO reported-travel.
" Raise message for booking fee < 0
IF travel-BookingFee < 0.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%state_area = 'VALIDATE_BOOKINGFEE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>booking_fee_invalid
severity = if_abap_behv_message=>severity-error )
%element-BookingFee = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译