验证预订实体的值
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发验证 › 验证预订实体的值
对于具有草稿的被管理场景,针对值一致性检查定义并实施登记实体的验证。
验证 validateCustomer
在行为定义中定义验证,并在预订的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 CustomerID 定义保存时验证。由于必须始终有客户分配到特定差旅,因此将字段 CustomerID 定义为 mandatory。
示例代码
define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
field ( mandatory ) CustomerID;
validation validateCustomer on save { create; field CustomerID; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
客户 ID 字段的验证与差旅实体中客户 ID 的验证类似。请参阅验证 validateCustomer。
要在子实体中检索正确的验证消息并在 UI 上显示,必须定义根实体的路径表达式。要使用正确的键值填充路径表达式,必须先读取父实体的键值。此操作通过关联读取完成。您不需要按关联读取的完整结果,而只需要包含源和目标实体的键值映射的链接表。
展开以下代码示例以查看验证 validateCustomer** 的源代码**。
示例代码
METHOD validateCurrencyCode.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY booking
FIELDS ( currencycode )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
DATA: currencies TYPE SORTED TABLE OF I_Currency WITH UNIQUE KEY currency.
currencies = CORRESPONDING #( bookings DISCARDING DUPLICATES MAPPING currency = currencycode EXCEPT * ).
DELETE currencies WHERE currency IS INITIAL.
IF currencies IS NOT INITIAL.
SELECT FROM I_Currency FIELDS currency
FOR ALL ENTRIES IN @currencies
WHERE currency = @currencies-currency
INTO TABLE @DATA(currency_db).
ENDIF.
LOOP AT bookings INTO DATA(booking).
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
) TO reported-booking.
IF booking-currencycode IS INITIAL.
" Raise message for empty Currency
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_required
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
%element-currencycode = if_abap_behv=>mk-on
) TO reported-booking.
ELSEIF NOT line_exists( currency_db[ currency = booking-currencycode ] ).
" Raise message for not existing Currency
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_not_existing
severity = if_abap_behv_message=>severity-error
currency_code = booking-currencycode )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
%element-currencycode = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateConnection
在行为定义中定义验证,并在预订的行为实施类中实施验证。
定义
使用触发器操作 create 和触发器字段 AirlineID、ConnectionID 和 FlightDate 定义保存验证。由于预订实例必须始终包含该航班信息,因此将这些字段定义为 mandatory。
示例代码
define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
field ( mandatory ) CustomerID, AirlineID, ConnectionID, FlightDate;
validation validateConnection on save { create; field AirlineID, ConnectionID, FlightDate; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查提供的值是否与 master 数据库表 /DMO/FLIGHT 中的条目匹配来验证航班相关字段。如果值为初始值或无效,则为使用者发出充足的消息。以下步骤将指导您完成实施。
读取导入
keys到内部表bookings的所有实例。此表是检查是否必须发出消息的基础。通过通过关联读取来读取相应的差旅实例。报告的表中的路径表达式
%path需要父键。它代表根实体路径的路径,在 UI 上正确显示消息非常重要。内部表
bookings上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果航空公司标识为初始值,则将交易代码写入失败的表并将相应消息附加到州范围
VALIDATE_CONNECTION。使用
/dmo/cm_flight_messages消息异常类创建消息,您可以使用该类从消息类中轻松检索消息并提供相应的参数。报告的表包含组件
%path,您必须在其中维护所有父实例的键值,包括根实体。使用链接表中的键值映射填充路径表达式。仅当维护所有父键值时,才在 UI 上正确显示消息。报告的表包括组件
%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。对
ConnectionID和FlightDate中的值重复此步骤。与AirlineID一样,它们不得为初始值。如果所有相关字段不为空,您可以检查这些值是否与航班主数据表中的条目匹配。如果 select 找到相应的行(=
sy-subrc <> 0),则将事务键写入失败的表并将相应的消息附加到状态区域VALIDATE_CONNECTION。
展开以下代码示例以查看验证 validateConnection** 的源代码**。
示例代码
METHOD validateConnection.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking
FIELDS ( BookingID AirlineID ConnectionID FlightDate )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
LOOP AT bookings ASSIGNING FIELD-SYMBOL(<booking>).
"overwrite state area with empty message to avoid duplicate messages
APPEND VALUE #( %tky = <booking>-%tky
%state_area = 'VALIDATE_CONNECTION' ) TO reported-booking.
" Raise message for non existing airline ID
IF <booking>-AirlineID IS INITIAL.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%state_area = 'VALIDATE_CONNECTION'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>ENTER_AIRLINE_ID
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-AirlineID = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
" Raise message for non existing connection ID
IF <booking>-ConnectionID IS INITIAL.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%state_area = 'VALIDATE_CONNECTION'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>ENTER_CONNECTION_ID
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-ConnectionID = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
" Raise message for non existing flight date
IF <booking>-FlightDate IS INITIAL.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%state_area = 'VALIDATE_CONNECTION'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>ENTER_FLIGHT_DATE
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-FlightDate = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
" check if flight connection exists
IF <booking>-AirlineID IS NOT INITIAL AND
<booking>-ConnectionID IS NOT INITIAL AND
<booking>-FlightDate IS NOT INITIAL.
SELECT SINGLE Carrier_ID, Connection_ID, Flight_Date FROM /DMO/FLIGHT WHERE carrier_id = @<booking>-AirlineID
AND connection_id = @<booking>-ConnectionID
AND flight_date = @<booking>-FlightDate
INTO @DATA(flight).
IF sy-subrc <> 0.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%state_area = 'VALIDATE_CONNECTION'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>NO_FLIGHT_EXISTS
carrier_id = <booking>-AirlineID
flight_date = <booking>-FlightDate
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-FlightDate = if_abap_behv=>mk-on
%element-AirlineID = if_abap_behv=>mk-on
%element-ConnectionID = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateCurrencyCode
在行为定义中定义验证,并在预订的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 CurrencyCode 定义保存时验证。由于必须始终为预订价格分配货币代码,因此将字段 CurrencyCode 定义为 mandatory。
示例代码
define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
field ( mandatory ) CurrencyCode;
validation validateCurrencyCode on save { create; field CurrencyCode; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
对货币代码字段的验证与验证差旅实体中的货币代码类似。请参阅验证 validateCurrencyCode。
要在子实体中检索正确的验证消息并在 UI 上显示,必须定义根实体的路径表达式。要使用正确的键值填充路径表达式,必须先读取父实体的键值。此操作通过关联读取完成。您不需要按关联读取的完整结果,而只需要包含源和目标实体的键值映射的链接表。
展开以下代码示例以查看验证 validateCustomer** 的源代码**。
示例代码
METHOD validateCurrencyCode.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY booking
FIELDS ( currencycode )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
DATA: currencies TYPE SORTED TABLE OFI_Currency WITH UNIQUE KEY currency.
currencies = CORRESPONDING #( bookings DISCARDING DUPLICATES MAPPING currency = currencycode EXCEPT * ).
DELETE currencies WHERE currency IS INITIAL.
IF currencies IS NOT INITIAL.
SELECT FROM I_Currency FIELDS currency
FOR ALL ENTRIES IN @currencies
WHERE currency = @currencies-currency
INTO TABLE @DATA(currency_db).
ENDIF.
LOOP AT bookings INTO DATA(booking).
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
) TO reported-booking.
IF booking-currencycode IS INITIAL.
" Raise message for empty Currency
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_required
severity = if_abap_behv_message=>severity-error )
%element-currencycode = if_abap_behv=>mk-on
) TO reported-booking.
ELSEIF NOT line_exists( currency_db[ currency = booking-currencycode ] ).
" Raise message for not existing Currency
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_CURRENCYCODE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_not_existing
severity = if_abap_behv_message=>severity-error
currency_code = booking-currencycode )
%element-currencycode = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateFlightPrice
在行为定义中定义验证,并在预订的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 FlightPrice 定义保存时验证。
示例代码
define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
validation validateFlightPrice on save { create; field FlightPrice; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查输入的值是否小于 0 来验证航班价格。如果值无效,则向使用者发出足够消息。以下步骤将指导您完成实施。
读取导入
keys到内部表bookings的所有实例。此表是检查是否必须发出消息的基础。使用关联
_Travel读取相应父实例的键值,并将结果存储在link响应中。将预订实例链接到报告响应中的差旅实例时需要此信息。内部表
bookings上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果航班价格小于 0,则将事务键值写入失败表并将相应消息与状态区域
VALIDATE_FLIGHTPRICE一起附加到该实例的报告表中。报告的表包括组件%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。使用上面填充的travel_booking_links表为每个预订实例提供相应差旅实例的键值。
具有草稿的被管理场景的消息存储在消息类 /dmo/cm_flight_messages 中,该消息类是 ABAP 航班参考场景的一部分。
展开以下代码示例以查看验证 validateFlightPrice** 的源代码**。
示例代码
METHOD validateFlightPrice.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY booking
FIELDS ( FlightPrice )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
LOOP AT bookings INTO DATA(booking).
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_FLIGHTPRICE'
) TO reported-booking.
" Raise message for flight price < 0
IF booking-FlightPrice < 0.
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_FLIGHTPRICE'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>flight_price_invalid
severity = if_abap_behv_message=>severity-error )
%element-FlightPrice = if_abap_behv=>mk-on
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
) TO reported-booking.
ENDIF.
ENDLOOP.
ENDMETHOD.
验证 validateStatus
在行为定义中定义验证,并在预订的行为实施类中实施验证。
定义
使用触发操作 create 和触发器字段 BookingStatus 定义保存时验证。
示例代码
define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
validation validateStatus on save { create; field BookingStatus; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
通过检查预订状态是否与其中一个预定义值匹配来验证预订状态。如果值无效,则向使用者发出足够消息。以下步骤将指导您完成实施。
读取导入
keys到内部表bookings的所有实例。此表是检查是否必须发出消息的基础。使用关联
_Travel读取相应父实例的键值,并将结果存储在link响应中。将预订实例链接到报告响应中的差旅实例时需要此信息。内部表
bookings上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果预订状态与预定义状态不同,则将事务键写入失败表,并将相应消息以及状态区域
VALIDATE_STATUS附加到该实例的报告表中。报告的表包括组件%element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。使用上面填充的travel_booking_links表为每个预订实例提供相应差旅实例的键值。
具有草稿的被管理场景的消息存储在消息类 /dmo/cm_flight_messages 中,该消息类是 ABAP 航班参考场景的一部分。
展开以下代码示例以查看验证 validateStatus** 的源代码**。
示例代码
METHOD validateStatus.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY booking
FIELDS ( BookingStatus )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
LOOP AT bookings INTO DATA(booking).
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_STATUS'
) TO reported-booking.
CASE booking-BookingStatus.
WHEN 'N'. " New
WHEN 'X'. " Canceled
WHEN 'B'. " Booked
WHEN OTHERS.
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%state_area = 'VALIDATE_STATUS'
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>status_invalid
status = booking-BookingStatus
severity = if_abap_behv_message=>severity-error )
%element-BookingStatus = if_abap_behv=>mk-on
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
) TO reported-booking.
ENDCASE.
ENDLOOP.
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 验证差旅实体的值 · 验证预订补充实体的值 →