验证预订补充实体的值

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发验证 › 验证预订补充实体的值

对于具有草稿的被管理场景,针对值一致性检查的登记补充实体定义并实施验证。

验证 validateSupplement

在行为定义中定义验证,并在 BookingSupplement 的行为实施类中实施验证。

定义

使用触发操作 create 和触发器字段 SupplementID 定义保存时验证。由于登记补充实例始终需要补充,因此将字段 SupplementID 定义为 mandatory。

示例代码

define behavior for /DMO/R_BookingSupplement_D alias BookingSupplement
...
{ ...
  field ( mandatory ) SupplementID
  validation validateSupplement on save { create; field SupplementID; }

… }

通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施

通过检查提供的值是否为补充数据库表中的条目,验证补充标识。如果值为初始值或无效,则为使用者发出充足的消息。实施步骤与验证 ValidateCustomer 完全相同。有关详细的逐步描述,请参阅验证 validateCustomer。

要填充报告表中的 %path 组件,必须提供所有父实例的键值。因此,您必须对业务对象结构中的每个实体执行按关联读取。在这种情况下,请参阅预订和预订补充。

展开以下代码示例以查看验证 validateSupplement** 的源代码**。

示例代码

 METHOD validateSupplement.

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement
        FIELDS ( SupplementID )
        WITH CORRESPONDING #(  keys )
      RESULT DATA(bookingsupplements)
      FAILED DATA(read_failed).

    failed = CORRESPONDING #( DEEP read_failed ).

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement BY \_Booking
        FROM CORRESPONDING #( bookingsupplements )
      LINK DATA(booksuppl_booking_links).

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement BY \_Travel
        FROM CORRESPONDING #( bookingsupplements )
      LINK DATA(booksuppl_travel_links).

    DATA supplements TYPE SORTED TABLE OF /DMO/SUPPLEMENT WITH UNIQUE KEY supplement_id.

    " Optimization of DB select: extract distinct non-initial customer IDs
    supplements = CORRESPONDING #( bookingsupplements DISCARDING DUPLICATES MAPPING supplement_id = SupplementID EXCEPT * ).
    DELETE supplements WHERE supplement_id IS INITIAL.

    IF  supplements IS NOT INITIAL.
      " Check if customer ID exists
      SELECT FROM /DMO/SUPPLEMENT FIELDS supplement_id
                                  FOR ALL ENTRIES IN @supplements
                                  WHERE supplement_id = @supplements-supplement_id
      INTO TABLE @DATA(valid_supplements).
    ENDIF.

    LOOP AT bookingsupplements ASSIGNING FIELD-SYMBOL(<bookingsupplement>).

      APPEND VALUE #(  %tky        = <bookingsupplement>-%tky
                       %state_area = 'VALIDATE_SUPPLEMENT'
                    ) TO reported-bookingsupplement.

      IF <bookingsupplement>-SupplementID IS  INITIAL.
        APPEND VALUE #( %tky = <bookingsupplement>-%tky ) TO failed-bookingsupplement.

        APPEND VALUE #( %tky                  = <bookingsupplement>-%tky
                        %state_area           = 'VALIDATE_SUPPLEMENT'
                        %msg                  = NEW /dmo/cm_flight_messages(
                                                                textid = /dmo/cm_flight_messages=>ENTER_SUPPLEMENT_ID
                                                                severity = if_abap_behv_message=>severity-error )
                        %path                 = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id  source-%tky = <bookingsupplement>-%tky ]-target-%tky
                                                         travel-%tky  = booksuppl_travel_links[  KEY id  source-%tky = <bookingsupplement>-%tky ]-target-%tky )
                        %element-SupplementID = if_abap_behv=>mk-on
                       ) TO reported-bookingsupplement.

      ELSEIF <bookingsupplement>-SupplementID IS NOT INITIAL AND NOT line_exists( valid_supplements[ supplement_id = <bookingsupplement>-SupplementID ] ).
        APPEND VALUE #(  %tky = <bookingsupplement>-%tky ) TO failed-bookingsupplement.

        APPEND VALUE #( %tky                  = <bookingsupplement>-%tky
                        %state_area           = 'VALIDATE_SUPPLEMENT'
                        %msg                  = NEW /dmo/cm_flight_messages(
                                                                textid = /dmo/cm_flight_messages=>SUPPLEMENT_UNKNOWN
                                                                severity = if_abap_behv_message=>severity-error )
                        %path                 = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id  source-%tky = <bookingsupplement>-%tky ]-target-%tky
                                                          travel-%tky = booksuppl_travel_links[  KEY id  source-%tky = <bookingsupplement>-%tky ]-target-%tky )
                        %element-SupplementID = if_abap_behv=>mk-on
                       ) TO reported-bookingsupplement.
      ENDIF.

    ENDLOOP.

  ENDMETHOD.

验证 validateCurrencyCode

在行为定义中定义验证,并在 BookingSupplement 的行为实施类中实施验证。

定义

使用触发操作 create 和触发器字段 CurrencyCode 定义保存时验证。由于必须始终存在货币代码,因此将字段 CurrencyCode 定义为 mandatory。

示例代码

define behavior for /DMO/R_BookingSupplement_D alias BookingSupplement
...
{ ...
  field ( mandatory ) SupplementID
  validation validateSupplement on save { create; field SupplementID; }

… }

通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施

通过检查提供的值是否为 I 中的条目来验证货币代码。如果值为初始值或无效,则为使用者发出充足的消息。实施步骤与验证 ValidateCustomer 完全相同。有关详细的逐步描述,请参阅验证 validateCustomer。

要填充报告表中的 %path 组件,必须提供所有父实例的键值。因此,您必须对业务对象结构中的每个实体执行按关联读取。在这种情况下,请参阅预订和预订补充。

展开以下代码示例以查看验证 validateSupplement** 的源代码**。

示例代码

  METHOD validateCurrencyCode.
    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement
        FIELDS ( currencycode )
        WITH CORRESPONDING #( keys )
      RESULT DATA(booking_supplements).

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement BY \_Booking
        FROM CORRESPONDING #( booking_supplements )
      LINK DATA(booksuppl_booking_links).

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement BY \_Travel
        FROM CORRESPONDING #( booking_supplements )
      LINK DATA(booksuppl_travel_links).

    DATA: currencies TYPE SORTED TABLE OF I_Currency WITH UNIQUE KEY currency.

    currencies = CORRESPONDING #( booking_supplements DISCARDING DUPLICATES MAPPING currency = currencycode EXCEPT * ).
    DELETE currencies WHERE currency IS INITIAL.

    IF currencies IS NOT INITIAL.
      SELECT FROM I_Currency FIELDS currency
        FOR ALL ENTRIES IN @currencies
        WHERE currency = @currencies-currency
        INTO TABLE @DATA(currency_db).
    ENDIF.

    LOOP AT booking_supplements INTO DATA(booking_supplement).
      APPEND VALUE #(  %tky               = booking_supplement-%tky
                       %state_area        = 'VALIDATE_CURRENCYCODE'
                    ) TO reported-bookingsupplement.
      IF booking_supplement-currencycode IS INITIAL.
        " Raise message for empty Currency
        APPEND VALUE #( %tky                   = booking_supplement-%tky ) TO failed-bookingsupplement.
        APPEND VALUE #( %tky                   = booking_supplement-%tky
                        %state_area            = 'VALIDATE_CURRENCYCODE'
                        %msg                   = NEW /dmo/cm_flight_messages(
                                                        textid    = /dmo/cm_flight_messages=>currency_required
                                                        severity  = if_abap_behv_message=>severity-error )
                        %path                 = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id  source-%tky = booking_supplement-%tky ]-target-%tky
                                                         travel-%tky  = booksuppl_travel_links[  KEY id  source-%tky = booking_supplement-%tky ]-target-%tky )
                        %element-currencycode = if_abap_behv=>mk-on
                      ) TO reported-bookingsupplement.
      ELSEIF NOT line_exists( currency_db[ currency = booking_supplement-currencycode ] ).
        " Raise message for not existing Currency
        APPEND VALUE #( %tky                   = booking_supplement-%tky ) TO failed-bookingsupplement.
        APPEND VALUE #( %tky                   = booking_supplement-%tky
                        %state_area            = 'VALIDATE_CURRENCYCODE'
                        %msg                   = NEW /dmo/cm_flight_messages(
                                                        textid        = /dmo/cm_flight_messages=>currency_not_existing
                                                        severity      = if_abap_behv_message=>severity-error )
                        %path                 = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id  source-%tky = booking_supplement-%tky ]-target-%tky
                                                         travel-%tky  = booksuppl_travel_links[  KEY id  source-%tky = booking_supplement-%tky ]-target-%tky )
                        %element-currencycode = if_abap_behv=>mk-on
                      ) TO reported-bookingsupplement.
      ENDIF.
    ENDLOOP.
  ENDMETHOD.

验证 validatePrice

在行为定义中定义验证,并在 BookingSupplement 的行为实施类中实施验证。

定义

使用触发操作 create 和触发器字段 BookSupplPrice 定义保存时验证。

示例代码

define behavior for /DMO/R_BookingSupplement_D alias BookingSupplement
            ...
            { ...
              validation validatePrice on save { create; field BookSupplPrice; }

            … }

通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施

通过检查输入的值是否小于 0 来验证价格。如果值无效,则向使用者发出足够消息。以下步骤将指导您完成实施。

  1. 读取导入 keys 到内部表 booking_supplements 的所有实例。此表是检查是否必须发出消息的基础。

  2. 使用关联 _Booking 和 _Travel 分别读取相应父实例和根实例的键值,并将结果分别存储在 link 响应中。在将补充实例链接到报告的响应中的预订和差旅实例时,需要此信息。

  3. 内部表 booking_supplements 上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。

  4. 如果航班价格小于 0,则将事务键值写入失败表并将相应消息与状态区域 VALIDATE_PRICE 一起附加到该实例的报告表中。报告的表包括组件 %element。在此,您可以指定负责状态不一致的 CDS 元素。Fiori 元素 UI 评估此组件并突出显示相应的输入字段。使用上面填充的标签 booksuppl_booking_links 和 booksuppl_travel_links 为每个补充实例提供相应预订和差旅实例的键值。

具有草稿的被管理场景的消息存储在消息类 /dmo/cm_flight_messages 中,该消息类是 ABAP 航班参考场景的一部分。

展开以下代码示例以查看验证 validatePrice** 的源代码**。

示例代码

METHOD validatePrice.

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement
        FIELDS ( BookSupplPrice )
        WITH CORRESPONDING #( keys )
      RESULT DATA(booking_supplements).

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement BY \_Booking
        FROM CORRESPONDING #( booking_supplements )
      LINK DATA(booksuppl_booking_links).

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY BookingSupplement BY \_Travel
        FROM CORRESPONDING #( booking_supplements )
      LINK DATA(booksuppl_travel_links).

    LOOP AT booking_supplements INTO DATA(booking_supplement).
      APPEND VALUE #(  %tky               = booking_supplement-%tky
                       %state_area        = 'VALIDATE_PRICE'
                    ) TO reported-bookingsupplement.
      " Raise message for Supplement Price < 0
      IF booking_supplement-BookSupplPrice < 0.
        APPEND VALUE #( %tky                   = booking_supplement-%tky ) TO failed-bookingsupplement.
        APPEND VALUE #( %tky                   = booking_supplement-%tky
                        %state_area            = 'VALIDATE_PRICE'
                        %msg                   = NEW /dmo/cm_flight_messages(
                                                        textid    = /dmo/cm_flight_messages=>suppl_price_invalid
                                                        severity  = if_abap_behv_message=>severity-error )
                        %path                 = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id  source-%tky = booking_supplement-%tky ]-target-%tky
                                                         travel-%tky  = booksuppl_travel_links[  KEY id  source-%tky = booking_supplement-%tky ]-target-%tky )
                        %element-BookSupplPrice = if_abap_behv=>mk-on
                      ) TO reported-bookingsupplement.
      ENDIF.
    ENDLOOP.

  ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 验证预订实体的值 · 开发 RAP 副作用 →