创建单例模式根实体

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用多行编辑功能开发事务应用 › 定义数据模型和业务对象结构 › 创建单例模式根实体

对于多行编辑场景,为定义业务对象的单例模式的 CDS 视图实体创建数据定义。

上下文

多行编辑场景需要一个单例模式根实体,其中只有一个实例代表 UI 上承运商数据列表的单个入口点。

单例模式在 RAP BO 中通过一种简单的方法实施:对根实体进行建模,该根实体从始终存在的 CDS 视图中进行选择,并使用 where 子句限制选择结果,以确保始终只有一个结果。此类 CDS 视图可以是已发布的 CDS 视图 I_Language,在 SAP 系统中始终可用。通过将选择结果限制为会话语言,您会收到所需的结果。始终只有一种会话语言,缺省情况下,在 CDS 视图 I_Language 的选择列表中始终可用。在根 CDS 视图实体中建模的实际实例不包含基础 CDS 视图 I_Language 的元素,但定义了具有虚拟值的关键元素以及与草稿处理相关的其他元素。需要注意的是,基础 CDS 视图 I_Language 与场景没有任何相关性。它仅确保 RAP 业务对象的单例模式机制。

过程

  1. 为 CDS 视图实体创建数据定义以建模业务对象的单例模式。

    在 ADT 中,使用向导创建 CDS 数据定义。

    为单元集实体选择模板定义根视图实体,然后输入视图实体的名称和描述。

    CDS 视图实体 /DMO/I_CarriersLockSingleton_S 使用 CDS 视图 I_Language 作为数据源。此 CDS 视图针对每个系统发布,可用于任何 RAP 业务对象。语言数据未在单元集实体中使用。

  2. 将根视图实体建模为单例模式实体以接收 UI 的单一入口点。

    使用 where 子句按系统语言限制选择列表。这可确保始终仅为此实体上的请求检索一个实例。

    将虚拟字段定义为实例的键值。您可以使用任何硬编码值。

  3. 定义总计 ETag 字段以启用业务对象的草稿功能。

    在此场景中,根视图中的总计 ETag 由其所有子实例的最大值确定。子承运商实例使用字段 last_changed_at 作为 ETag 字段。每当更新实例时,字段都会收到新值并更新总计 ETag。

    要访问子实例的数据,请使用子实例的数据库表建模左外部联接 /dmo/carrier。连接必须使用虚拟连接条件,因为左侧没有与连接右侧的任何字段匹配的字段。通过使用虚拟连接条件(如 on 0 = 0),每个实例(只有一个实例)接收从连接数据源中选择的字段。

    将承运商数据库表的最大字段 last_changed_at 添加到根视图实体的选择列表。

  4. 定义载体业务对象的构成结构。

    存在子实体 /DMO/I_Carrier_S 的 CDS 视图实体后,将构成定义为 并使用选择列表中的关联。

展开以下代码示例以查看 CDS 根视图实体 /DMO/I_CarriersLockSingleton_S 的源代码。

示例代码

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Carrier Singleton Root View'

define root view entity /DMO/I_CarriersLockSingleton_S
  as select from    I_Language
    left outer join /dmo/carrier as carr on 0 = 0
  composition [0..*] of /DMO/I_Carrier_S as _Airline

{
  key 1                          as CarrierSingletonID,
      max (carr.last_changed_at) as LastChangedAtMax,

      _Airline
}

where
  I_Language.Language = $session.system_language

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 定义数据模型和业务对象结构 · 创建主数据实体 →