创建主数据实体

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用多行编辑功能开发事务应用 › 定义数据模型和业务对象结构 › 创建主数据实体

对于多行编辑场景,为选择承运方主数据的 CDS 视图实体创建数据定义。

上下文

多行编辑场景要求将主数据实体建模为根实体的子实体,以启用单例模式机制。

过程

  1. 为 CDS 视图实体创建数据定义以对承运方主数据建模。

    在 ADT 中,使用向导创建 CDS 数据定义。

    为子实体选择模板定义具有对父关联的视图实体,然后输入视图实体的名称和描述。

    CDS 视图实体 /DMO/I_Carrier_S 使用数据库表 /dmo/carrier 作为数据源。已选择所有字段。

  2. 定义与上级视图实体的关联。

    在选择列表中,包括与根视图实体中的关键字段具有相同硬编码值的虚拟字段。此字段用作关联的条件。

  3. 使用自动更新被管理场景中管理字段的 @Semantics 注释。

  4. 通过使用抬头注释 @Metadata.ignorePropagatedAnnotations: true 禁止从基础 CDS 视图继承的搜索和文本注释。

展开以下代码示例以查看 CDS 视图实体 /DMO/I_Carrier_S 的源代码。

示例代码

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Transactional Carrier View'
@Metadata.ignorePropagatedAnnotations: true

define view entity /DMO/I_Carrier_S
  as select from /DMO/I_Carrier as Airline
  association        to parent /DMO/I_CarriersLockSingleton_S as _CarrierSingleton on $projection.CarrierSingletonID = _CarrierSingleton.CarrierSingletonID

{
  key AirlineID,
      1 as CarrierSingletonID,

      Name,

      CurrencyCode,

      @Semantics.user.createdBy: true
      LocalCreatedBy,
      @Semantics.systemDateTime.createdAt: true
      LocalCreatedAt,
      @Semantics.user.lastChangedBy: true
      LocalLastChangedBy,
      //local etag field --> odata etag
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LocalLastChangedAt,

      //total etag field
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangedAt,

      /* Associations */
      _CarrierSingleton
}

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 创建单例模式根实体 · 开发事务行为 →