开发事务行为

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用多行编辑功能开发事务应用 › 开发事务行为

多行编辑场景实施草稿业务对象的一些标准行为以及在 UI 上启用多行编辑所需的其他特定行为。

上下文

单元集业务对象的行为在行为定义中定义。由于承运方业务对象已启用草稿,因此有一些标准草稿行为必须可用于草稿业务对象。其他行为会导致此业务对象中使用的特殊单元集模式。

过程

使用 ADT 中的创建向导创建行为定义。通过使用根视图上的上下文菜单 (/DMO/I_CarriersLockSingleton_S),可以直接为承运商单元集数据模型创建行为定义。在向导中,选择实施类型托管。

模板中的标准行为

managed 实施类型的模板为行为池提供建议,并提供了作为 RAP 业务对象最佳实践的严格添加。对于构成树中的每个实体,都会添加行为定义并指定持久表。由于根实体在其数据源上使用联接,因此找不到持久表。

每个实体都包含标准操作 create、update 和 delete。RAP 场景中不支持对子实体的创建操作。子实体的实例只能通过按关联创建操作创建,该操作也包含在父实体中。

模板还建议包括行为特征 lock、authorization 和 etag。锁定和权限的主项在根实体上定义,与子实体相关。严格模式要求为业务对象定义权限。使用附加项 none,不执行任何权限检查。这是演示应用程序,因此不使用附加项。在实际场景中不建议使用此方法,这会违反最佳实践。有关详细信息,请参阅权限控制。由于此载体业务对象几乎没有必须实施的行为,因此两个实体都可以使用一个实施类。模板建议用于两个实体的行为池的名称。

根实体实例永远无法修改。因此,它不需要 ETag。ETag 主数据在具有 ETag 字段 LocalLastChangedAt 的子实体上定义。建议使用字段特征 readonly 在行为定义中将相应 ETag 字段指定为只读。

子实体在 CDS 视图中使用与数据库表不同的字段名称。为所有字段的承运方子实体添加映射定义。

单字母特定行为

由于根视图实体仅设计为应用的入口点,因此预计始终只有一个实例。不打算在根实体上创建、更新或删除实例。从根实体上的模板中删除此修改行为。

实施类型 managed 需要为每个业务对象实体指定持久表。对于根视图实体,没有持久表,这会导致行为定义中出现语法错误。在此场景中,不允许修改根视图实体。因此,不需要持久表。要解决行为定义中的语法问题,请使用语法 with unmanaged save 为根视图实体定义非托管保存。由于此方案根本不想保存根实体实例的任何修改,因此行为池中的保护程序实施方法仍为空。然后在业务对象的保存序列期间调用,但不会更改单个根视图实体实例的任何内容。

将根实体中的字段 CarrierSingletonID 设置为只读。由于不允许修改根实体,因此该字段不应在 UI 上可编辑。

草稿特定行为

要草稿启用承运方业务对象,请在行为定义抬头中定义 with draft。

启用草稿要求每个实体都有一个草稿数据库表。通过在每个实体上添加草稿表的 draft table 和名称,您可以使用触发草稿表创建的行为定义快速修复。根实体 /dmo/d_carr_lock 的草稿表只是未使用的虚拟表,因为在此场景中无法对根实体实例进行修改。子实体 /dmo/d_carrier 的草稿表用于承运方草稿实例的草稿生命周期管理。

草稿启用还需要定义总计 ETag 字段。字段 LastChangedAtMax 在用作总计 ETag 字段的根视图实体中计算。

将 with draft 添加到关联 association _Airline {create;} 和 association _CarrierSingleton; 以显式定义始终遵循与草稿标识相关的关联。这会自动隐式启用,但出于透明度原因,最佳实践是将其显式添加到行为定义。字段 CarrierSingletonID 用于子实体 中至父关联 _CarrierSingleton 的 on 条件中。必须将其设置为只读,以确保无法更改父项和子项之间的连接元素。

子实体的所有主数据字段均为必填字段,因为不应存在不含 AirlineID、Name 或 CurrencyCode 的实例。此外,关键字段 AirlineID 在更新时必须为只读。

定义根实体的所有草稿操作。

展开以下代码示例以查看行为定义的源代码 /DMO/I_CarriersLockSingleton_S。

示例代码

managed implementation in class /dmo/bp_i_carrierslocksingle_s unique;

strict(2);
with draft;

define behavior for /DMO/I_CarriersLockSingleton_S alias CarriersLockSingleton
with unmanaged save
draft table /dmo/d_carr_lock
lock master
total etag LastChangedAtMax
authorization master ( none )

{
  association _Airline { create; with draft; }

  field ( readonly ) CarrierSingletonID, LastChangedAtMax;

  draft action Edit;
  draft action Activate optimized;
  draft action Discard;
  draft action Resume;
  draft determine action Prepare

}

define behavior for /DMO/I_Carrier_S alias Carrier
persistent table /dmo/carrier
draft table /dmo/d_carrier
lock dependent by _CarrierSingleton
authorization dependent by _CarrierSingleton
etag master LocalLastChangedAt
{
  update;
  delete;

  field ( readonly ) CarrierSingletonID, LocalCreatedBy, LocalCreatedAt, LocalLastChangedBy, LocalLastChangedAt, LastChangedAt;
  field ( mandatory : create, readonly : update ) AirlineID;
  field ( mandatory ) Name, CurrencyCode;

  association _CarrierSingleton { with draft; }

  mapping for /dmo/carrier
  { AirlineID = carrier_id;
    CurrencyCode = currency_code;
    Name = name;
    LocalCreatedBy = local_created_by;
    LocalCreatedAt = local_created_at;
    LocalLastChangedBy = local_last_changed_by;
    LocalLastChangedAt = local_last_changed_at;
    LastChangedAt = last_changed_at;
  }
}

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 创建主数据实体 · 开发承运方实体的功能控制 →