开发承运方实体的功能控制

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用多行编辑功能开发事务应用 › 开发事务行为 › 开发承运方实体的功能控制

对于多行编辑场景,使用承运商实体上的功能控制启用和禁用功能。

上下文

此场景中用于演示 Fiori UI 上的多行编辑功能的承运方数据也由其他业务对象用作差旅实例的主数据。差旅业务对象中的预订实体与承运商接口视图相关联,并验证在预订实例中使用的承运商是否存在于承运商数据的数据库表中。这可确保仅使用现有航空公司。到目前为止,承运商数据保持稳定,因为数据库表中没有其他业务对象修改数据。对于当前场景,此更改。维护承运方数据时,必须确保无法删除已由其他业务对象使用的承运方实例。这是通过定义删除操作的功能控制来强制执行的。实例功能控制检查航空公司是否用于数据库表 /dmo/connection 中维护的转机。仅当航空公司标识未在连接中使用时,才会启用删除操作。

过程

为承运方实体的删除操作定义功能控制。

示例代码

define behavior for /DMO/I_Carrier_S alias Carrier
...
{
  update;
  delete ( features : instance );
... }

使用行为定义中的快速修复,在行为池中生成实例功能控制处理器的方法定义。

实施在方法 FOR INSTANCE FEATURES 中完成。

将已导入 keys 的所有实例读取到内部表中,并使用 AirlineID 从转机界面视图 /DMO/I_Connection 中选择相应的 AirlineID,以检查运输公司 BO 中的航空公司标识是否用于转机。

如果转机中存在相应的 AirlineID,则在方法的结果表中禁用删除操作。如果不存在,则将权限值设置为 enabled。

使用功能控制方法的响应结构中返回的足够的信息消息填充报告的表。

展开以下代码示例以查看 GET_INSTANCE_FEATURES 的源代码。

示例代码

CLASS lhc_carrier DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.
...
    METHODS get_instance_features FOR INSTANCE FEATURES
      IMPORTING keys REQUEST requested_features FOR Carrier RESULT result.

ENDCLASS.

CLASS lhc_carrier IMPLEMENTATION.
  METHOD get_instance_features.

    DATA: airline_ids TYPE SORTED TABLE OF /dmo/i_carrier WITH UNIQUE KEY AirlineID.

    READ ENTITIES OF /DMO/I_CarriersLockSingleton_S IN LOCAL MODE
      ENTITY Carrier
        FIELDS ( AirlineID )
        WITH CORRESPONDING #( keys )
      RESULT DATA(Carrier)
      FAILED failed.

    airline_ids = CORRESPONDING #( Carrier DISCARDING DUPLICATES MAPPING AirlineID = AirlineID EXCEPT * ).

    IF airline_ids IS NOT INITIAL.
      SELECT DISTINCT AirlineID
      FROM /DMO/I_Connection
        FOR ALL ENTRIES IN @airline_ids
        WHERE AirlineID = @airline_ids-AirlineID
        INTO TABLE @DATA(connections_db).
    ENDIF.

    LOOP AT Carrier ASSIGNING FIELD-SYMBOL(<carrier>).
      " Delete is not allowed if any Connection exists
      IF line_exists( connections_db[ AirlineID = <carrier>-AirlineID ] ).
        APPEND VALUE #( %tky    = <carrier>-%tky
                        %delete = if_abap_behv=>fc-o-disabled ) TO result.
        APPEND VALUE #( %tky                        = <carrier>-%tky
                        %msg                        = NEW /dmo/cx_carriers_s(
                                                       textid        = /dmo/cx_carriers_s=>airline_still_used
                                                       severity      = if_abap_behv_message=>severity-information
                                                       airline_id    = <carrier>-AirlineID )
                        %delete                     = if_abap_behv=>mk-on
                        %path-carrierslocksingleton = CORRESPONDING #( <carrier> )
                      ) TO reported-carrier.
      ELSE.
        APPEND VALUE #( %tky    = <carrier>-%tky
                        %delete = if_abap_behv=>fc-o-enabled ) TO result.
      ENDIF.
    ENDLOOP.

  ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 开发事务行为 · 开发验证 →