开发验证

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用多行编辑功能开发事务应用 › 开发事务行为 › 开发验证

对于多行编辑场景,定义并实施值一致性检查的验证。

上下文

仅当提供每个字段的值时,运输公司实例才完全可用。没有名称或货币代码的航空公司没有任何意义。因此,在创建新实例和编辑时检查这些值是不可或缺的。承运方实例的字段不得为空。通过将关键字段 AirlineID 定义为创建时必填且更新时为只读,RAP 运行时引擎确保在创建新实例时提供该值,并且在修改过程中不会更改该值。其他字段 Name 和 CurrencyCode 是开发人员的责任。这些字段必须通过验证进行检查。在将草稿实例保存到持久表之前,将执行验证并拒绝不含所有值的实例。

验证必须具有触发条件 create 和相应字段。

过程

定义验证以在创建新的承运方实例并在承运方实体上编辑这些字段时检查 Name 和 CurrencyCode。

示例代码

define behavior for /DMO/I_Carrier_S alias Carrier
...
{
  validation validateName on save { create; field Name; }
  validation validateCurrencyCode on save { create; field CurrencyCode; }
... }

仅当在根实体上为草稿确定操作 Prepare 定义了验证时,才会在 UI 上正确显示验证消息。

示例代码

define behavior for /DMO/I_CarrierLockSingleton_S alias Carrier
...
{
  draft determine action Prepare
  {
    validation Carrier ~ validateName;
    validation Carrier ~ validateCurrencyCode;
  }

... }

使用行为定义中的快速修复,在行为池中生成验证处理程序的方法定义。

实施在方法 FOR VALIDATE ON SAVE 中完成。

验证 ValidateName

读取已导入 keys 的所有实例到内部表中。将失败条目传递到验证的 failed 表。

内部表 Carriers 上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果相应字段为初始值,则将实例标识符写入失败的表并将相应消息附加到相应的状态区域。

展开以下代码示例以查看 validateName 的源代码。

示例代码

CLASS lhc_carrier DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.

    METHODS validateName FOR VALIDATE ON SAVE
      IMPORTING keys FOR Carrier~validateName.

ENDCLASS.

CLASS lhc_carrier IMPLEMENTATION.
  METHOD validateName.

    READ ENTITIES OF /DMO/I_CarriersLockSingleton_S IN LOCAL MODE
      ENTITY Carrier
        FIELDS ( CarrierSingletonID Name )
        WITH CORRESPONDING #( keys )
      RESULT DATA(Carrier).

    " Raise message for empty Airline Name
    LOOP AT Carrier ASSIGNING FIELD-SYMBOL(<carrier>).

      APPEND VALUE #( %tky        = <carrier>-%tky
                      %state_area = 'VALIDATE_NAME'
                    ) TO reported-carrier.

      IF <carrier>-name IS INITIAL.
        APPEND VALUE #( %tky                        = <carrier>-%tky ) TO failed-carrier.
        APPEND VALUE #( %tky                        = <carrier>-%tky
                        %msg                        = NEW /dmo/cx_carriers_s(
                                                         textid     = /dmo/cx_carriers_s=>name_required
                                                         severity   = if_abap_behv_message=>severity-error
                                                         airline_id = <carrier>-AirlineID )
                        %element-name               = if_abap_behv=>mk-on
                        %state_area                 = 'VALIDATE_NAME'
                        %path-carrierslocksingleton = CORRESPONDING #( <carrier> )
                      ) TO reported-carrier.
      ENDIF.
    ENDLOOP.

  ENDMETHOD.
ENDCLASS.

验证 ValidateCurrencyCode

除了检查为运输公司实例提供的值是否为初始值外,此处还需要检查提供的货币代码是否确实存在。

读取已导入 keys 的所有实例到内部表中。将失败条目传递到验证的 failed 表。

将条目复制到其他内部表并删除重复项。如果结果表不是初始值,则使用给定货币代码选择 /DMO/I_Currency 的条目。如果没有相应的结果条目,则提供的货币代码无效。

内部表 Carriers 上的循环。为避免使用者出现重复的状态消息,请将空消息附加到报告的表以清除状态区域。如果相应字段为初始值,则将实例标识符写入失败的表并将相应消息附加到相应的状态区域。如果从 /DMO/I_Currency 中选择未返回所提供货币代码的值,则将实例标识符写入失败的表并将相应消息附加到相应的状态区域。

展开以下代码示例以查看 validateCurrencyCode 的源代码。

示例代码

CLASS lhc_carrier DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.

    METHODS validatecurrencycode FOR VALIDATE ON SAVE
      IMPORTING keys FOR carrier~validatecurrencycode.

ENDCLASS.

CLASS lhc_carrier IMPLEMENTATION.
METHOD validateCurrencyCode.

    DATA: currency_codes TYPE SORTED TABLE OF I_Currency WITH UNIQUE KEY Currency.

    READ ENTITIES OF /DMO/I_CarriersLockSingleton_S IN LOCAL MODE
      ENTITY Carrier
        FIELDS ( CarrierSingletonID CurrencyCode )
        WITH CORRESPONDING #( keys )
      RESULT DATA(Carrier).

    currency_codes = CORRESPONDING #( Carrier DISCARDING DUPLICATES MAPPING Currency = CurrencyCode EXCEPT * ).

    IF currency_codes IS NOT INITIAL.
      SELECT FROM I_Currency FIELDS Currency
        FOR ALL ENTRIES IN @currency_codes
        WHERE Currency = @currency_codes-Currency
        INTO TABLE @DATA(currency_codes_db).
    ENDIF.

    " Raise message for not existing Currency Codes
    LOOP AT Carrier ASSIGNING FIELD-SYMBOL(<carrier>).

      APPEND VALUE #( %tky        = <carrier>-%tky
                      %state_area = 'VALIDATE_CURRENCY_CODE'
                    ) TO reported-carrier.

      IF <carrier>-CurrencyCode IS INITIAL.
        APPEND VALUE #( %tky                             = <carrier>-%tky ) TO failed-carrier.
        APPEND VALUE #( %tky                             = <carrier>-%tky
                        %msg                             = NEW /dmo/cx_carriers_s(
                                                               textid     = /dmo/cx_carriers_s=>currency_code_required
                                                               severity   = if_abap_behv_message=>severity-error
                                                               airline_id = <carrier>-AirlineID )
                        %element-currencycode            = if_abap_behv=>mk-on
                        %state_area                      = 'VALIDATE_CURRENCY_CODE'
                        %path-carrierslocksingleton      = CORRESPONDING #( <carrier> )
                      ) TO reported-carrier.

      ELSEIF NOT line_exists( currency_codes_db[ Currency = <carrier>-CurrencyCode ] ).
        APPEND VALUE #( %tky                             = <carrier>-%tky ) TO failed-carrier.
        APPEND VALUE #( %tky                             = <carrier>-%tky
                        %msg                             = NEW /dmo/cx_carriers_s(
                                                               textid        = /dmo/cx_carriers_s=>invalid_currency_code
                                                               severity      = if_abap_behv_message=>severity-error
                                                               currency_code = <carrier>-CurrencyCode )
                        %element-currencycode            = if_abap_behv=>mk-on
                        %state_area                      = 'VALIDATE_CURRENCY_CODE'
                        %path-carrierslocksingleton      = CORRESPONDING #( <carrier> )
                      ) TO reported-carrier.
      ENDIF.
    ENDLOOP.

  ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 开发承运方实体的功能控制 · 预测 UI 敞口的业务对象 →