实施数据和计数检索

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 通过访问远程服务开发 UI 服务 › 使用远程 OData 服务 › 实施服务使用查询 › 实施数据和计数检索

要启用从远程服务检索数据,必须建立与配置租户的连接,并实例化将 OData 请求传递到远程服务的客户端代理。然后,远程服务中的数据集将导入到使用租户,并且可以与附加数据合并。

预览

在 SAP Fiori UI 上选择执行按钮会触发数据和计数检索的 OData 请求。UI 自动包含一个分页查询选项,每页通常有 20 条数据记录。

远程服务和本地数据库表中的数据

实施步骤

1. 实例化客户端代理

要将请求发送到配置系统,您需要远程客户端代理。

  • 在查询实施类中,调用 get_client_proxy 方法中辅助类 /DMO/CL_TRAVEL_CP_AUX 的方法 select。

METHOD if_rap_query_provider~select.

  " Instantiate Client Proxy
  DATA(lo_client_proxy) = /dmo/cl_travel_cp_aux=>get_client_proxy( ).

  ENDMETHOD.

2. 创建读取请求

要在远程服务上执行查询请求,必须创建相关实体集的读取请求。然后,将使用查询选项增强此读取请求。

  • 在客户端代理对象上,使用 TRAVEL 实体集名称作为导入参数调用方法 create_resource_for_entity_set。

    备注

    OData 实体集名称可以在生成的代理类的相应常量结构中找到:

    此方法返回实体集资源的 对象。

  • 通过在实体集资源上调用方法 create_request_for_read 创建读取请求。

  • 将方法调用与 TRY-CATCH 块包围,并包括带有适当错误消息的错误处理。

TRY.
  " Create Read Request
  DATA(lo_read_request) = lo_client_proxy->create_resource_for_entity_set( 'TRAVEL' )->create_request_for_read( ).

  CATCH /iwbep/cx_gateway INTO DATA(lx_gateway).
    RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
          EXPORTING
            textid   = /dmo/cx_travel_serv_cons=>query_failed
            previous = lx_gateway.
ENDTRY.

3.请求远程服务的内联计数

由于 Fiori UI 始终请求服务的内联计数,因此必须将此请求委托给远程服务才能从中获取记录总数。

  • 在 try-catch 块中,通过调用接口 is_total_numb_of_rec_requested 的 方法来检查 UI 是否请求了记录总数 IF_RAP_QUERY_REQUEST.

    有关 is_total_numb_of_rec_requested 的详细信息,请参阅方法 is_total_numb_of_rec_requested。

    。

    备注

    与之前定义的相同例外可用于读取请求上调用的所有方法。

  • 在读取请求中调用方法 request_count。

" Request Count
IF io_request->is_total_numb_of_rec_requested( ).
   lo_read_request->request_count( ).
ENDIF.

4.如果请求数据,则实施分页

每当 UI 请求分页时,查询框架都会检查查询返回的数据记录数量是否不超过请求的数据记录。因此,您需要为客户端代理发送到远程服务的读取请求设置分页信息。

  • 在 try-catch 块中,检查是否请求了数据。如果必须使用方法 set_data 返回数据,则必须应用请求的分页。如果不必返回数据,如果 is_data_requested 返回 abap_false,则分页不相关。

  • 通过调用接口 ls_paging 的方法 get_paging,将 UI 请求的分页信息获取到局部变量 (IF_RAP_QUERY_REQUEST) 中。

    有关 get_paging 的详细信息,请参阅方法 get_paging。

  • 如果偏移 >= 0,则将其传递到读取请求。

  • 如果页大小不受限制,则将其传递到读取请求。

    备注

    如果请求了所有数据记录,则方法返回值为 page_size_unlimited 的常量 -1。如果返回此常量,则查询选项 $skip 不得传递到读取请求。

" Request Data
IF io_request->is_data_requested( ).

 " Request Paging
 DATA(ls_paging) = io_request->get_paging( ).
 IF ls_paging->get_offset( ) >= 0.
  lo_read_request->set_skip( ls_paging->get_offset( ) ).
  ENDIF.
   IF ls_paging->get_page_size( ) <> if_rap_query_paging=>page_size_unlimited.
     lo_read_request->set_top( ls_paging->get_page_size( ) ).
  ENDIF.
 ENDIF.

5. 执行请求

远程 OData 服务的读取请求现在配备了用于计数 $count=true(如果请求记录总数)以及分页 $skip 和 $top(如果请求数据)的查询选项。至少,如果使用服务是 UI 服务,则应在查询实施类中实施这两个查询选项。

记住

缺省情况下,UI 发送用于计数和分页的查询选项。

现在,可以发送请求。换句话说,它在远程服务上执行。

  • 执行请求并将其写入局部变量 lo_response。

" Execute the Request
DATA(lo_response) = lo_read_request->execute( ).

6.提供非托管查询响应的计数结果。

必须使用对远程服务的计数请求返回的记录总数填充 IF_RAP_QUERY_PROVIDER~select 的响应参数 io_response。

  • 检查是否请求了记录总数。

  • 通过调用远程服务响应对象上的方法 get_count,从远程服务的响应中获取计数。

  • 通过在非托管查询的响应对象上调用方法 set_total_number_of_records,设置非托管查询响应的返回编号。

" Set Count
IF io_request->is_total_numb_of_rec_requested( ).
 io_response->set_total_number_of_records( lo_response->get_count( ) ).
ENDIF.

7.提供非托管查询响应的结果数据。

IF_RAP_QUERY_PROVIDER~select 的响应参数 io_response 必须使用请求的数据填充,这些数据由远程服务返回并使用本地折扣数据增强。

  • 检查是否请求了数据。

  • 使用在生成的代理类 lt_travel 中定义的结构类型 tys_travel_type 表类型声明 /DMO/CL_TRAVEL_SCM。此类型还用于 服务使用模型 部件生成的代码示例中的示例变量声明。远程服务中的数据将写入声明的内部表 lt_travel。

  • 使用自定义实体的类型声明 lt_travel_ce。此表用于填充 select 方法的输出参数。

  • 声明具有本地数据库表类型的 lt_traveladd。数据库表 /DMO/TRVL_SCM_DC 中的数据读取到此表中。

  • 通过调用 get_business_data 方法从远程服务请求的响应对象获取数据,并将其写入 lt_travel。

  • 如果 lt_travel 返回条目,则为自定义实体中与抽象实体元素名称不同的元素提供映射。在我们的场景中,这涉及元素 Description。

  • 根据从远程服务检索的实体集选择本地数据(折扣)。

  • 对于在本地数据库表中具有匹配键的已检索实例,请在内部表 lt_travel_ce 中设置以下数据:

    • 从本地数据库表设置百分比折扣

    • 计算字段的金额 TotalPriceWithDiscount

    • 从本地数据库表中接管时戳。

    • 根据本地时戳计算 etag

  • 对于本地数据库表中没有匹配密钥的已检索实例,将检索的总价用于字段 TotalPriceWithDiscount,并为字段 lastchangedat 设置静态值 '20000101120000'

  • 通过在非托管查询的响应对象上调用方法 set_data,为对非托管查询的响应设置返回的数据。

" Set Data
  IF io_request->is_data_requested( ).
    DATA: lt_travel    TYPE STANDARD TABLE OF /DMO/CL_TRAVEL_SCM=>tys_travel_type,
          lt_travel_ce TYPE STANDARD TABLE OF /DMO/R_TRAVEL_SCM_TP,
          lt_traveladd TYPE STANDARD TABLE OF /DMO/TRVL_SCM_DC.

    lo_response->get_business_data( IMPORTING et_business_data = lt_travel ).
    IF lt_travel IS NOT INITIAL.
       lt_travel_ce = CORRESPONDING #( lt_travel MAPPING description = memo ).
       SELECT * FROM /DMO/TRVL_SCM_DC FOR ALL ENTRIES IN @lt_travel_ce WHERE travel_id = @lt_travel_ce-travel_id INTO TABLE @lt_traveladd.

        LOOP AT lt_travel_ce ASSIGNING FIELD-SYMBOL(<fs_travel_ce>).
              IF line_exists( lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ] ).
                <fs_travel_ce>-discountpct        = lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-discount_pct.
                <fs_travel_ce>-totalpricewithdiscount = <fs_travel_ce>-total_price * ( 1 - <fs_travel_ce>-discountpct / 100 ).
                <fs_travel_ce>-last_changed_at      = lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-lastchangedat.
                <fs_travel_ce>-calculatedetag     = <fs_travel_ce>-calculatedetag && '-' && lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-lastchangedat.
              ELSE.
                <fs_travel_ce>-totalpricewithdiscount = <fs_travel_ce>-total_price.
                <fs_travel_ce>-last_changed_at          = '20000101120000' .  "initial value Jan 1, 2000, 12:00:00 AM
              ENDIF.
            ENDLOOP.
          ENDIF.

          io_response->set_data( lt_travel_ce ).
    ENDIF.

结果

展开以下列表以查看用于数据检索和计数的查询实施的源代码:

查询实施类

CLASS /dmo/cl_r_traveltp_scm_query DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.

    INTERFACES if_rap_query_provider .
  PROTECTED SECTION.
  PRIVATE SECTION.
ENDCLASS.

CLASS /dmo/cl_r_traveltp_scm_query IMPLEMENTATION.

  METHOD if_rap_query_provider~select.

  " Instantiate Client Proxy
  DATA(lo_client_proxy) = /dmo/cl_travel_cp_aux=>get_client_proxy( ).

  TRY.

  " Create Read Request
  DATA(lo_read_request) = lo_client_proxy->create_resource_for_entity_set( 'TRAVEL' )->create_request_for_read( ).

  " Request Count
  IF io_request->is_total_numb_of_rec_requested( ).
   lo_read_request->request_count( ).
  ENDIF.

  " Request Data
  IF io_request->is_data_requested( ).

    " Request Paging
    DATA(ls_paging) = io_request->get_paging( ).
    IF ls_paging->get_offset( ) >= 0.
      lo_read_request->set_skip( ls_paging->get_offset( ) ).
    ENDIF.
    IF ls_paging->get_page_size( ) <> if_rap_query_paging=>page_size_unlimited.
      lo_read_request->set_top( ls_paging->get_page_size( ) ).
    ENDIF.

  ENDIF.

  " Execute the Request
  DATA(lo_response) = lo_read_request->execute( ).

  " Set Count
  IF io_request->is_total_numb_of_rec_requested( ).
   io_response->set_total_number_of_records( lo_response->get_count( ) ).
  ENDIF.

  " Set Data
  IF io_request->is_data_requested( ).
    DATA: lt_travel    TYPE STANDARD TABLE OF /DMO/CL_TRAVEL_SCM=>tys_travel_type,
          lt_travel_ce TYPE STANDARD TABLE OF /DMO/R_TRAVEL_SCM_TP,
          lt_traveladd TYPE STANDARD TABLE OF /DMO/TRVL_SCM_DC.

    lo_response->get_business_data( IMPORTING et_business_data = lt_travel ).
    IF lt_travel IS NOT INITIAL.
       lt_travel_ce = CORRESPONDING #( lt_travel MAPPING description = memo ).
       SELECT * FROM /DMO/TRVL_SCM_DC FOR ALL ENTRIES IN @lt_travel_ce WHERE travel_id = @lt_travel_ce-travel_id INTO TABLE @lt_traveladd.

        LOOP AT lt_travel_ce ASSIGNING FIELD-SYMBOL(<fs_travel_ce>).
              IF line_exists( lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ] ).
                <fs_travel_ce>-discountpct        = lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-discount_pct.
                <fs_travel_ce>-totalpricewithdiscount = <fs_travel_ce>-total_price * ( 1 - <fs_travel_ce>-discountpct / 100 ).
                <fs_travel_ce>-last_changed_at      = lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-lastchangedat.
                <fs_travel_ce>-calculatedetag     = <fs_travel_ce>-calculatedetag && '-' && lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-lastchangedat.
              ELSE.
                <fs_travel_ce>-totalpricewithdiscount = <fs_travel_ce>-total_price.
                <fs_travel_ce>-last_changed_at          = '20000101120000' .  "initial value Jan 1, 2000, 12:00:00 AM
              ENDIF.
            ENDLOOP.
          ENDIF.

          io_response->set_data( lt_travel_ce ).
    ENDIF.

    CATCH /iwbep/cx_gateway INTO DATA(lx_gateway).
     RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
          EXPORTING
            textid   = /dmo/cx_travel_serv_cons=>query_failed
            previous = lx_gateway.

  ENDTRY.
  ENDMETHOD.

ENDCLASS.

如果已为自定义实体定义 UI 服务(请参阅定义 OData 服务),则可以使用 SAP Fiori 元素预览测试实施。打开应用并选择执行按钮时,您将从远程服务接收数据和计数以及匹配的折扣数据。