实施过滤
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 通过访问远程服务开发 UI 服务 › 使用远程 OData 服务 › 实施服务使用查询 › 实施过滤
过滤器选项可以委派给远程服务。使用查询选项 $filter 填充传递到 OData 客户端代理的请求。
预览

要检索筛选器的相应条目,您必须实施筛选工厂以从远程服务获取筛选结果。
实施步骤
此场景仅实施按远程服务的字段过滤。服务代理 API 提供筛选器工厂,以将筛选器委托给远程服务。此场景中不支持按本地字段过滤。
备注
要按本地字段过滤,您必须检索远程服务的所有可用数据集并首先将本地字段合并到这些数据集中,以便能够按折扣值进行过滤。在这种情况下,分页也无法委派给远程服务,并且必须在手动检索数据后实施。因此,过滤折扣值可能会导致严重的性能问题,因此在此场景中无法举例说明。
备注
仅当最终用户还在单位字段(在本例中为货币代码)提供过滤器时,才可以对金额字段进行筛选。在我们的场景中,字段
total_price、totalpricewithdiscount和booking_fee是金额字段。如果为这些字段输入过滤器,则货币代码也必须在过滤条件中。因此,在这些情况下,实施还必须包括货币代码。
过滤器信息与数据和计数检索相关。因此,过滤器的实施必须与数据或计数请求的检查无关。过滤器信息必须添加到远程服务的读取请求。因此,必须在执行读取请求之前调用过滤器实施。
非托管查询 API 提供了一种将过滤条件从 UI OData 请求获取到局部变量的方法。使用
io_request->get_filter( )->get_as_ranges( )将过滤条件作为范围获取到局部变量lt_filter。如果过滤器无法转换为范围表,则处理异常。有关非托管查询过滤器 API 的详细信息,请参阅接口 IF_RAP_QUERY_FILTER。
循环
lt_filter。记住
在将某些过滤器请求发送到远程服务之前,需要对其进行特殊处理:
不允许对本地字段进行过滤。
要过滤金额字段,必须在过滤器中提供单位。
如果针对本地字段请求过滤器,则引发包含足够消息的异常,例如
Filtering on &1 is not allowed。在金额字段中查找筛选请求的货币代码。
如果未提供货币代码,则引发异常,例如
Currency code is not supplied for &1.创建要传递到远程服务的过滤器属性。将远程服务的元素
Description映射到Memo以匹配远程服务的数据模型。创建筛选工厂以为客户端代理提供筛选请求。
通过调用筛选器工厂的方法
create_by_range为远程服务创建筛选器范围,并导出筛选器属性、筛选器范围以及货币代码(如有必要)。如果为多个元素定义过滤器,则连接过滤条件。
为请求设置过滤器。
展开以下代码示例以查看 Request Filtering 的源代码。
示例代码
" Request Filtering
TRY.
DATA(lt_filter) = io_request->get_filter( )->get_as_ranges( ).
CATCH cx_rap_query_filter_no_range INTO DATA(lx_no_range).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>no_ranges
previous = lx_no_range.
ENDTRY.
LOOP AT lt_filter ASSIGNING FIELD-SYMBOL(<fs_filter>).
IF <fs_filter>-name = 'DISCOUNTPCT' OR
<fs_filter>-name = 'TOTALPRICEWITHDISCOUNT' OR
<fs_filter>-name = 'CALCULATEDETAG'.
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>filtering_failed
element = <fs_filter>-name.
ENDIF.
"provide currency code, if filtering on amount field
IF <fs_filter>-name = 'TOTAL_PRICE' OR
<fs_filter>-name = 'BOOKING_FEE'.
IF line_exists( lt_filter[ name = 'CURRENCY_CODE' ] ).
DATA(lv_currencycode) = VALUE waers_curc( lt_filter[ name = 'CURRENCY_CODE' ]-range[ option = 'EQ' ]-low OPTIONAL ).
ELSE.
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>no_currencycode
element = <fs_filter>-name.
ENDIF.
ENDIF.
"map element names
DATA(lv_filter_property) = COND /iwbep/if_cp_runtime_types=>ty_property_path( WHEN <fs_filter>-name = 'DESCRIPTION'
THEN 'MEMO'
ELSE <fs_filter>-name ).
"create filter factory for read request
DATA(lo_filter_factory) = lo_read_request->create_filter_factory( ).
"
DATA(lo_filter_for_current_field) = lo_filter_factory->create_by_range( iv_property_path = lv_filter_property
it_range = <fs_filter>-range
iv_currency_code = lv_currencycode ).
"Concatenate filter if more than one filter element
DATA: lo_filter TYPE REF TO /iwbep/if_cp_filter_node.
IF lo_filter IS INITIAL.
lo_filter = lo_filter_for_current_field.
ELSE.
lo_filter = lo_filter->and( lo_filter_for_current_field ).
ENDIF.
ENDLOOP.
"set filter
IF lo_filter IS NOT INITIAL.
lo_read_request->set_filter( lo_filter ).
ENDIF.
结果
如果已为自定义实体定义 UI 服务(请参阅定义 OData 服务),则可以使用 SAP Fiori 元素预览测试实施。您可以定义过滤器并检查 UI 是否仅检索与过滤器请求匹配的数据。