实施缓冲区类

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 通过访问远程服务开发 UI 服务 › 使用远程 OData 服务 › 将事务行为添加到业务对象 › 实施业务对象的行为池 › 实施缓冲区类

本地缓冲区类用作服务使用场景中数据处理的中间存储。它是行为池中的单独局部类。

创建缓冲区类

必须从预定义方法 READ、MODIFY 和 SAVE 访问缓冲区。

  1. 在行为实施池的本地类型中创建本地缓冲区类 lcl_buffer。

  2. 将局部类设置为 PRIVATE。

*清单:*局部缓冲类

CLASS lcl_buffer DEFINITION CREATE PRIVATE.

ENDCLASS.
CLASS lcl_buffer IMPLEMENTATION.
ENDCLASS.

创建缓冲区实例

当使用事务缓冲区存储和处理数据时,必须首先创建缓冲区的实例。单元集模式用于确保应用程序缓冲区只有一个现有缓冲区实例。

  1. 在缓冲区类的公共部分中声明返回缓冲区实例的静态方法 get_instance

  2. 如果不存在实例,则实施 get_instance 以接收缓冲区实例

清单:get_instance 的声明和实施

CLASS lcl_buffer DEFINITION CREATE PRIVATE.
  PUBLIC SECTION.
    CLASS-METHODS get_instance
      RETURNING VALUE(ro_instance) TYPE REF TO lcl_buffer.

  PRIVATE SECTION.
    CLASS-DATA: go_instance TYPE REF TO lcl_buffer.
ENDCLASS.
CLASS lcl_buffer IMPLEMENTATION.
  METHOD get_instance.
    IF go_instance IS NOT BOUND.
      go_instance = NEW #( ).
    ENDIF.
    ro_instance = go_instance.
  ENDMETHOD.
ENDCLASS.

从远程服务检索数据

以下列表表示从远程服务中检索数据的方法 get_data 的签名和实施(如果远程服务尚未在缓冲区中)。方法的实施包括

  1. 检查要更新折扣数据的差旅实例是否已位于缓冲区中,并将其写入导出参数 et_travel(如果缓冲区中可用)。如果不在缓冲区中,则必须收集 travel_id 以从持久性中检索相关数据。

  2. 通过调用辅助类 /DMO/CL_TRAVEL_CP_AUX 的方法 get_client_proxy 来实例化客户端代理,请参阅创建远程客户端代理。

  3. 客户端代理的读取请求,具有仅为特定差旅 ID 请求数据集的筛选器

  4. 选择以从数据库表 /DMO/TRVL_SCM_DC 中获取并计算匹配的折扣数据,并处理 calculatedetag 字段的时戳。

  5. 如果未更改折扣数据,则计算 TotalPriceWithDiscount 并设置初始时戳。

  6. 如果未找到差旅标识,则填写 FAILED 表。

    以及

  7. 对远程系统的访问失败时的错误处理。

备注

如果要显示合适的消息,则需要创建消息类。例如,在此,消息 Accesss to remote system cannot be established 很方便。它从消息类 /DMO/CM_SERV_CONS 中检索。

列表:get_data 的声明和实施 扩展以下代码示例以查看 lcl_buffer (method get_data) 的“声明和实施”的源代码。

示例代码

CLASS lcl_buffer DEFINITION CREATE PRIVATE.
  PUBLIC SECTION.
    CLASS-METHODS get_instance
      RETURNING VALUE(ro_instance) TYPE REF TO lcl_buffer.

    "types used in get_data
    TYPES: BEGIN OF ts_message,
             travelid TYPE /DMO/R_TRAVEL_SCM_TP-travel_id,
             symsg    TYPE symsg,
             fields   TYPE string_table,
           END OF ts_message,
           tt_travel        TYPE STANDARD TABLE OF /DMO/R_TRAVEL_SCM_TP,
           tt_travel_in     TYPE TABLE FOR READ IMPORT /DMO/R_TRAVEL_SCM_TP,
           tt_travel_out    TYPE TABLE FOR READ RESULT /DMO/R_TRAVEL_SCM_TP,
           tt_travel_failed TYPE TABLE FOR FAILED /DMO/R_TRAVEL_SCM_TP,
           tt_message       TYPE STANDARD TABLE OF ts_message.

    METHODS get_data
      IMPORTING it_travel        TYPE tt_travel_in OPTIONAL
      EXPORTING et_travel        TYPE tt_travel_out
                et_travel_failed TYPE tt_travel_failed
                et_message       TYPE tt_message.

  PRIVATE SECTION.
    CLASS-DATA: go_instance TYPE REF TO lcl_buffer.
    DATA: mt_travel       TYPE tt_travel.

ENDCLASS.
CLASS lcl_buffer IMPLEMENTATION.

  METHOD get_data.

    DATA: lt_travel         TYPE STANDARD TABLE OF /DMO/CL_TRAVEL_SCM=>tys_travel_type.
    DATA: ls_result         LIKE LINE OF et_travel.
    DATA: lt_travel_id      TYPE STANDARD TABLE OF /DMO/R_TRAVEL_SCM_TP-travel_id.

    DATA: lt_filter         TYPE RANGE OF /DMO/R_TRAVEL_SCM_TP-travel_id.
    DATA: ls_filter         LIKE LINE OF lt_filter.
    DATA: lt_travel_ce      TYPE STANDARD TABLE OF /DMO/R_TRAVEL_SCM_TP.
    DATA: lt_traveladd      TYPE STANDARD TABLE OF /DMO/TRVL_SCM_DC.
    FIELD-SYMBOLS: <fs_travel_ce> LIKE LINE OF lt_travel_ce.

    IF it_travel IS SUPPLIED.

      LOOP AT it_travel ASSIGNING FIELD-SYMBOL(<fs_travel>).
        IF line_exists( mt_travel[ travel_id = <fs_travel>-travel_id ] ).
          ls_result = CORRESPONDING #( mt_travel[ travel_id = <fs_travel>-travel_id ] ).
          " collect from buffer for result
          APPEND ls_result TO et_travel.
        ELSE.
          " collect to retrieve from persistence
          APPEND <fs_travel>-travel_id TO lt_travel_id.
        ENDIF.
      ENDLOOP.

      IF lt_travel_id IS NOT INITIAL.
        TRY.
            DATA(lo_client_proxy) = /dmo/cl_travel_cp_aux=>get_client_proxy( ).
            DATA(lo_request) = lo_client_proxy->create_resource_for_entity_set( 'TRAVEL' )->create_request_for_read( ).

            lt_filter = VALUE #( FOR travel_id IN lt_travel_id ( sign = 'I' option = 'EQ' low = travel_id ) ).
            DATA(lo_filter) = lo_request->create_filter_factory( )->create_by_range( iv_property_path = 'TRAVEL_ID'
                                                                                     it_range         = lt_filter ).
            lo_request->set_filter( lo_filter ).
            DATA(lo_response) = lo_request->execute( ).
            " get relevant data sets
            lo_response->get_business_data( IMPORTING et_business_data = lt_travel ).

            " add local data
            IF lt_travel IS NOT INITIAL.
              " map OData service to custom entity
              lt_travel_ce = CORRESPONDING #( lt_travel MAPPING description = memo ).
              SELECT * FROM /DMO/TRVL_SCM_DC FOR ALL ENTRIES IN @lt_travel_ce WHERE travel_id = @lt_travel_ce-travel_id INTO TABLE @lt_traveladd.

              LOOP AT lt_travel_id ASSIGNING FIELD-SYMBOL(<fs_travel_id>).
                IF line_exists( lt_travel_ce[ travel_id = <fs_travel_id> ] ).
                  ASSIGN lt_travel_ce[ travel_id = <fs_travel_id> ] TO <fs_travel_ce>.

                  IF line_exists( lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ] ).
                    <fs_travel_ce>-discountpct        = lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-discount_pct.
                    <fs_travel_ce>-totalpricewithdiscount = <fs_travel_ce>-total_price * ( 1 - <fs_travel_ce>-discountpct / 100 ).
                    <fs_travel_ce>-last_changed_at      = lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-lastchangedat.
                    <fs_travel_ce>-calculatedetag         = <fs_travel_ce>-calculatedetag && '-' && lt_traveladd[ travel_id = <fs_travel_ce>-travel_id ]-lastchangedat.
                  ELSE.
                    <fs_travel_ce>-totalpricewithdiscount = <fs_travel_ce>-total_price.
                    <fs_travel_ce>-last_changed_at = '20000101120000' .  "initial value Jan 1, 2000, 12:00:00 AM
                  ENDIF.

                  ls_result = CORRESPONDING #( <fs_travel_ce> ).
                  APPEND <fs_travel_ce> TO mt_travel.
                  APPEND ls_result           TO et_travel.
                ELSE.
                  APPEND VALUE #( travel_id =  <fs_travel_id> ) TO et_travel_failed.
                  APPEND VALUE #( travelid    = <fs_travel_id>
                                  symsg-msgty = 'E'
                                  symsg-msgid = '/DMO/CM_SERV_CONS'
                                  symsg-msgno = '004'
                                  symsg-msgv1 = <fs_travel_id> )
                  TO et_message.
                ENDIF.
              ENDLOOP.
            ENDIF.

          CATCH  /iwbep/cx_gateway /dmo/cx_travel_serv_cons.
            et_travel_failed = CORRESPONDING #( lt_travel_id MAPPING travel_id = table_line ).
            et_message = CORRESPONDING #( lt_travel_id MAPPING travelid = table_line ).
            LOOP AT et_message ASSIGNING FIELD-SYMBOL(<fs_message>).
              <fs_message>-symsg-msgty = 'E'.
              <fs_message>-symsg-msgid = '/DMO/CM_SERV_CONS'.
              <fs_message>-symsg-msgno = '001'.
            ENDLOOP.
        ENDTRY.
      ENDIF.
    ELSE.
      et_travel = CORRESPONDING #( mt_travel ).

    ENDIF.

  ENDMETHOD.

  METHOD get_instance.
    IF go_instance IS NOT BOUND.
      go_instance = NEW #( ).
    ENDIF.
    ro_instance = go_instance.
  ENDMETHOD.

ENDCLASS.

更新折扣数据

使用上述方法,将数据从远程服务检索到缓冲区。但是 UPDATE 操作的本质是通过方法 put_data 完成的。它使用缓冲区中的数据(已使用数据库表 /DMO/TRVL_SCM_DC 中的附加折扣数据进行增强),并将新的折扣数据写入缓冲区。该操作由 完成

  1. 调用方法 get_data 从缓冲区检索数据

  2. 在 it_travel_upd 处循环以识别更改的字段

  3. 使用新折扣数据覆盖更改的字段

  4. 计算 TotalPriceWithDiscount 的数据

  5. 如果折扣计算后含折扣的总价为负,则填写 FAILED 表。

    备注

    如果要显示合适的消息,则需要将消息添加到消息类 /DMO/CM_SERV_CONS。在这种情况下,如果 Total Price with Discount 为负,则需要抛出异常。例如,在此,消息 Total Price with Discount must be greater than 0 很方便。

  6. 将更新的数据集写入缓冲区。

列表:put_data 的声明和实施 扩展以下代码示例以查看 lcl_buffer (method put_data) 的“声明和实施”的源代码。

示例代码

CLASS lcl_buffer DEFINITION CREATE PRIVATE.
  PUBLIC SECTION.

    "types used in put_data
    TYPES:
      tt_travel_upd    TYPE TABLE FOR UPDATE /DMO/R_TRAVEL_SCM_TP,
      tt_travel_mapped TYPE TABLE FOR MAPPED /DMO/R_TRAVEL_SCM_TP.

    METHODS put_data
      IMPORTING it_travel_upd    TYPE tt_travel_upd
      EXPORTING et_travel_failed TYPE tt_travel_failed
                et_message       TYPE tt_message.

...
ENDCLASS.
CLASS lcl_buffer IMPLEMENTATION.

...

 METHOD put_data.

    get_data(
      EXPORTING it_travel        = CORRESPONDING #( it_travel_upd mapping %key = %key except * )
      IMPORTING et_travel        = data(lt_travel)
                et_travel_failed = DATA(lt_travel_failed)
                et_message       = DATA(lt_message)
    ).

    LOOP AT it_travel_upd ASSIGNING FIELD-SYMBOL(<fs_travel_upd>).
      CHECK line_exists( lt_travel[ KEY entity COMPONENTS travel_id = <fs_travel_upd>-travel_id ] ).
      ASSIGN lt_travel[ KEY entity COMPONENTS travel_id = <fs_travel_upd>-travel_id ] TO FIELD-SYMBOL(<fs_travel>).

      IF <fs_travel_upd>-%control-DiscountPct = if_abap_behv=>mk-on.
        <fs_travel>-DiscountPct = <fs_travel_upd>-DiscountPct.
      ENDIF.
    ENDLOOP.

    " Postprocessing
    LOOP AT lt_travel ASSIGNING FIELD-SYMBOL(<fs_traveladdinfo>).
      DATA(lv_totalpricediscount) = <fs_traveladdinfo>-total_price * ( 1 - <fs_traveladdinfo>-discountpct / 100 ).
      IF lv_totalpricediscount >= 0.
        <fs_traveladdinfo>-totalpricewithdiscount = lv_totalpricediscount.
      ELSE.
        APPEND VALUE #( travel_id    =  <fs_traveladdinfo>-travel_id ) TO et_travel_failed.
        APPEND VALUE #( travelid    = <fs_traveladdinfo>-travel_id
                        symsg-msgty = 'E'
                        symsg-msgid = '/DMO/CM_SERV_CONS'
                        symsg-msgno = '009'
                        symsg-msgv1 = <fs_traveladdinfo>-travel_id
                        symsg-msgv2 = |{ lv_totalpricediscount NUMBER = USER }|
                        fields      = VALUE #( ( |discountpct| )
                                             )
                      )
        TO et_message.
      ENDIF.
    ENDLOOP.
    "save data in buffer
    mt_travel = CORRESPONDING #( lt_travel ) .

  ENDMETHOD.
ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 实施业务对象的行为池 · 实施 READ →