在对象页面上动态隐藏字段
ABAP RESTful 应用程序编程模型 › 开发 › 开发 UI 特定 › 定义元数据驱动的 UI 的 CDS 注释 › 对象页面 › 隐藏对象页面上的字段 › 在对象页面上动态隐藏字段
如何使用 hidden 注释动态隐藏应用程序对象页面上的字段。
快捷信息
上下文和使用
您可以将 hidden 注释与虚拟元素结合使用,以根据布尔值在 UI 上动态显示或隐藏字段。如果返回值对应于 true,则会隐藏相应字段,如果值对应于 false 则会在用户界面上显示相应字段。要使用虚拟元素启用动态字段隐藏,需要执行以下步骤:
在行为定义映射中定义虚拟元素。有关如何实施虚拟元素的更多常规信息,请参阅在 CDS 映射视图中使用虚拟元素。
创建 ABAP 类以确定虚拟元素的返回值。
对要在对象页面上动态隐藏相应字段的字段进行注释。
在下文中,您可以查看所有组件的示例片段,并在下面找到特定用例的示例实施。
代码片段
在以下定义中,检查提取字段的数值,如果 FieldToCheck 的值大于 1000,则方法返回 abap_true,并在对象页面上隐藏 Field。如果包含的值小于 1000,则 methord 返回 abap_false,并在用户界面上显示 Field。您可以根据任何条件检查任何值,并动态确定相应字段的可见性。
示例定义:/DMO/Projection_View
define root view entity /DMO/Projection_View
as projection on /DMO/Root_View
{
@UI: {
lineItem: [ { position: 40, importance: #MEDIUM } ],
identification: [ { position: 40, hidden: #(testField)} ] }
Field as Field,
@UI: {
identification:[ { position: 50 } ] }
FieldToCheck as FieldToCheck
@ObjectModel.virtualElementCalculatedBy: 'ABAP:Z_ShowField'
virtual testField :abap_boolean,
}
示例定义:CLASS Z_ShowField
CLASS Z_ShowField DEFINITION
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
INTERFACES IF_SADL_EXIT_CALC_ELEMENT_READ.
ENDCLASS.
CLASS Z_ShowField IMPLEMENTATION.
METHOD IF_SADL_EXIT_CALC_ELEMENT_READ~CALCULATE.
* Check the field for your condition and return either abap_true or abap_false for the
* virtual field.
DATA LT_ORIGINAL_DATA TYPE STANDARD TABLE OF Z_FD_C_Travel_Processor_M WITH DEFAULT KEY.
LT_ORIGINAL_DATA = CORRESPONDING #( IT_ORIGINAL_DATA ).
LOOP AT LT_ORIGINAL_DATA ASSIGNING FIELD-SYMBOL(<FS_ORIGINAL_DATA>).
<FS_ORIGINAL_DATA>-testField = COND ABAP_BOOLEAN( WHEN <FS_ORIGINAL_DATA>-FieldToCheck > 1000 THEN ABAP_TRUE ELSE ABAP_FALSE ).
ENDLOOP.
CT_CALCULATED_DATA = CORRESPONDING #( LT_ORIGINAL_DATA ).
ENDMETHOD.
METHOD IF_SADL_EXIT_CALC_ELEMENT_READ~GET_CALCULATION_INFO.
* Extract the field you want the field visibility to depend on
*
IF IV_ENTITY <> '/DMO/Projection_View'.
RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
EXPORTING
TEXTID = /dmo/cx_virtual_elements=>ENTITY_NOT_KNOWN
ENTITY = IV_ENTITY.
ENDIF.
LOOP AT IT_REQUESTED_CALC_ELEMENTS ASSIGNING FIELD-SYMBOL(<FS_CALC_ELEMENT>).
CASE <FS_CALC_ELEMENT>.
WHEN 'testField'.
APPEND 'FieldToCheck' TO ET_REQUESTED_ORIG_ELEMENTS.
...
ENDCASE.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 隐藏对象页面上的字段 · 使用统计图可视化数据 →