实施虚拟元素的计算

ABAP RESTful 应用程序编程模型 › 开发 › 开发通用功能 › 在 CDS 映射视图中使用虚拟元素 › 建模虚拟元素 › 实施虚拟元素的计算

虚拟元素的值在参考的 ABAP 类中计算。本主题说明如何通过示例实施计算这些值。

上下文

通过在 CDS 投影视图中使用虚拟元素,为 OData 服务定义附加字段。由于此附加字段未保存在数据库层中,因此必须在运行时计算其值。计算在 CDS 投影视图中虚拟元素的注释中引用的 ABAP 类中实施。

计算类必须实施接口 IF_SADL_EXIT_CALC_ELEMENT_READ。此接口为计算实施提供了两种方法:

  • get_calculation_info:此方法在实际数据检索之前调用。确保已选择计算虚拟元素所需的所有相关元素。

  • calculate:在数据检索后调用此方法。它使用相关元素的值来计算虚拟元素的值。

前提条件

  • 虚拟元素在 CDS 投影视图中建模,如建模虚拟元素中所述。

  • 虚拟元素使用引用现有 ABAP 类的注释 @ObjectModel.virtualElementCalculatedBy。

过程

  1. 将接口 IF_SADL_EXIT_CALC_ELEMENT_READ 添加到计算类的公共部分,并添加两种方法实施。

    示例

    CLASS /dmo/cl_days_to_flight DEFINITION
      PUBLIC
      FINAL
      CREATE PUBLIC .
    
      PUBLIC SECTION.
        INTERFACES if_sadl_exit_calc_element_read.
      PROTECTED SECTION.
      PRIVATE SECTION.
    ENDCLASS.
    
    CLASS /dmo/cl_days_to_flight IMPLEMENTATION.
      METHOD if_sadl_exit_calc_element_read~get_calculation_info.
      ENDMETHOD.
    
      METHOD if_sadl_exit_calc_element_read~calculate.
      ENDMETHOD.
    
    ENDCLASS.
    
  2. 实施方法 get_calculation_info。

    使用此方法,可以检查是否仅在请求相关元素时才执行虚拟元素的计算。此外,您必须提供计算所需的元素列表。只能添加请求的 CDS 实体的元素。

    有关详细信息,请参阅 get_calculation_info 的方法描述。

    如果请求实体或虚拟元素(非预期),则引发足够的异常。

    示例

    首先,我们检查请求的实体是否为包含要进行计算的虚拟元素的实体。要计算与航班日期相比的剩余时间或经过时间,我们需要元素 FlightDate。此元素将添加到请求的元素列表中,以确保值可用于计算虚拟元素。

    可以为同一 ABAP 类中的多个虚拟元素计算值。根据虚拟元素,您可能需要将不同的元素插入到请求的元素列表中。

    展开以下代码示例以查看方法 get_calculation_info 的源代码。

    示例代码

    CLASS /dmo/cl_days_to_flight IMPLEMENTATION.
      METHOD if_sadl_exit_calc_element_read~get_calculation_info.
        IF iv_entity <> '/DMO/C_BOOKING_VE'.
          RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
            EXPORTING
              textid = /dmo/cx_virtual_elements=>entity_not_known
              entity = iv_entity.
        ENDIF.
    
        LOOP AT it_requested_calc_elements ASSIGNING FIELD-SYMBOL(<fs_calc_element>).
          CASE <fs_calc_element>.
            WHEN 'DAYSTOFLIGHT'.
            	INSERT `FLIGHTDATE` INTO TABLE et_requested_orig_elements.
    
    *        WHEN 'ANOTHERELEMENT'.
    *          INSERT `` ...
    
            WHEN OTHERS.
              RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
                EXPORTING
                  textid  = /dmo/cx_virtual_elements=>virtual_element_not_known
                  element = <fs_calc_element>
                  entity  = iv_entity.
          ENDCASE.
        ENDLOOP.
      ENDMETHOD.
    ENDCLASS.
    

    备注

    IF_SADL_CAL_ELEMENT_READ 接口的方法以大写形式导入并导出其参数字符串。因此,CDS 实体和元素名称也必须大写,以便可以正确映射。

  3. 实施方法 calculate。

    使用此方法计算虚拟元素的值。除了计算所需的元素(通过方法 get_calculation_info 请求进行数据检索)外,参数it_original_data 还包含客户端请求的元素的检索值结果表。参数 it_requested_calc_elements 包含一个或多个虚拟元素。在更改参数 ct_calculated_data 中,必须提供虚拟元素的计算值。

    有关详细信息,请参阅 calculate 的方法描述。

    示例

    在我们的示例中,我们希望计算航班前剩余的天数或自航班起经过的天数,因此我们将 FLIGHTDATE 的值与今天的日期进行比较,以计算虚拟元素的值。

    可通过 cl_abap_context_info=>get_system_date( ) 检索系统日期。

    只要日期上下文明确,ABAP 就可以使用日期类型进行计算。因此,实际计算非常容易:我们只是从航班日期减去当天日期。然后,可以使用计算的航班天数填充返回参数。

        METHOD if_sadl_exit_calc_element_read~calculate.
        DATA(lv_today) = cl_abap_context_info=>get_system_date( ).
    
        DATA lt_original_data TYPE STANDARD TABLE OF /dmo/c_booking_proc_ve WITH DEFAULT KEY.
        lt_original_data = CORRESPONDING #( it_original_data ).
    
        LOOP AT lt_original_data ASSIGNING FIELD-SYMBOL(<fs_original_data>).
          <fs_original_data>-DaysToFlight =  <fs_original_data>-FlightDate - lv_today.
        ENDLOOP.
    
        ct_calculated_data = CORRESPONDING #(  lt_original_data ).
      ENDMETHOD.