实施虚拟元素排序
ABAP RESTful 应用程序编程模型 › 开发 › 开发通用功能 › 在 CDS 映射视图中使用虚拟元素 › 建模虚拟元素 › 实施虚拟元素排序
对虚拟元素的排序在虚拟元素的排序转换中引用的 ABAP 类中实施。本主题介绍如何转换虚拟元素的排序条件。
上下文
由于虚拟元素不会保留在数据库中,因此无法将传入排序请求委托给数据库以获取请求的排序结果。排序必须在相关 ABAP 类中实施。
排序转换的类必须实施接口 IF_SADL_EXIT_SORT_TRANSFORM。此接口提供方法 map_element。它将虚拟元素上的排序替换为其他 CDS 元素。排序方向取自传入请求,但可以根据需要恢复。只要 OData 请求请求对响应进行排序,就会在数据检索之前调用此方法。
前提条件
虚拟元素根据建模虚拟元素的说明在 CDS 投影视图中建模。
虚拟元素使用引用现有 ABAP 类的注释
@ObjectModel.sort.transformedBy。
过程
将接口 IF_SADL_EXIT_SORT_TRANSFORM 添加到排序转换类的公共部分,然后为 map_element 添加方法实施。
示例
CLASS /dmo/cl_days_to_flight_sort DEFINITION PUBLIC FINAL CREATE PUBLIC . PUBLIC SECTION. INTERFACES if_sadl_exit_sort_transform. PROTECTED SECTION. PRIVATE SECTION. ENDCLASS. CLASS /dmo/cl_days_to_flight_sort IMPLEMENTATION. METHOD if_sadl_exit_sort_transform~map_element. " Implementation of the method goes here ENDMETHOD. ENDCLASS.
实施方法
map_element。使用此方法,可以将虚拟元素的排序条件转换为其他 CDS 元素的排序条件。
示例
传入排序条件的排序转换在方法 map_element 中定义。必须将虚拟元素上的传入排序请求转换为另一个 CDS 元素上的排序请求。
首先,我们检查实体是否为相关 CDS,以及排序元素是否为要排序的虚拟元素。如果不是这种情况,则会引发异常。然后,必须使用转换排序条件的常规 CDS 元素填充导出参数 et_sort_elements。
CLASS /dmo/cl_days_to_flight_sort IMPLEMENTATION.
METHOD if_sadl_exit_sort_transform~map_element.
IF iv_entity <> '/DMO/C_BOOKING_VE'.
RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
EXPORTING
textid = /dmo/cx_virtual_elements=>entity_not_known
entity = iv_entity.
ENDIF.
IF iv_element <> 'DAYSTOFLIGHT'.
RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
EXPORTING
textid = /dmo/cx_virtual_elements=>sort_element_not_expected
entity = iv_entity
element = iv_element.
ENDIF.
APPEND VALUE #( name = `FLIGHTDATE` reverse = abap_false ) TO et_sort_elements.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译