实施虚拟元素过滤

ABAP RESTful 应用程序编程模型 › 开发 › 开发通用功能 › 在 CDS 映射视图中使用虚拟元素 › 建模虚拟元素 › 实施虚拟元素过滤

虚拟元素的过滤在虚拟元素的过滤器注释中引用的 ABAP 类中实施。本主题介绍如何转换虚拟元素的过滤器。

上下文

由于虚拟元素不会保留在数据库中,因此无法将传入过滤器请求委托给数据库以获取请求的过滤结果。虚拟元素的过滤器必须在相关 ABAP 类中实施。对于每个过滤器运算符,必须将过滤转换为计算虚拟元素所依据的元素的过滤器。

筛选转换的类必须实施接口 IF_SADL_EXIT_FILTER_TRANSFORM。此接口提供方法 map_atom。只要 OData 请求过滤虚拟元素,就会在数据检索之前调用此方法。接口 为以下过滤器运算符提供常量:

  • 等于

  • 小于

  • 大于

  • 为空

  • 覆盖模式。

前提条件

  • 虚拟元素在 CDS 投影视图中建模,如建模虚拟元素中所述。

  • 虚拟元素使用引用现有 ABAP 类的注释 @ObjectModel.filter.transformedBy。

过程

  1. 将接口 IF_SADL_EXIT_FILTER_TRANSFORM 添加到筛选器转换类的公共部分,然后为 map_atom 添加方法实施。

    示例

    CLASS /dmo/cl_days_to_flight_filter DEFINITION
    							PUBLIC
    							FINAL
    							CREATE PUBLIC .
    
    							PUBLIC SECTION.
    
    							INTERFACES if_sadl_exit_filter_transform.
    							PROTECTED SECTION.
    							PRIVATE SECTION.
    							ENDCLASS.
    
    							CLASS /dmo/cl_days_to_flight_filter IMPLEMENTATION.
    							METHOD if_sadl_exit_filter_transform~map_atom.
    
    							ENDMETHOD.
    
    							ENDCLASS.
    
  2. 实施方法 map_atom。

    使用此方法,您必须将虚拟元素的过滤器转换为可应用于 CDS 实体其他元素的过滤器。对于每个可能的过滤器运算符,定义仅使用常规 CDS 元素的过滤条件。使用方法 map_atom 替代过滤条件不得包含虚拟元素。

    简单条件工厂提供了创建此类筛选条件的选项。有关条件工厂中使用的接口的详细信息,请参阅使用简单条件工厂创建条件。

    示例

    传入过滤器条件的过滤器转换在方法 map_atom 中定义。OData 条件包含虚拟元素上的过滤器 URI 选项,因此在此示例中为 DAYSTOFLIGHT。此过滤器必须转换为可应用于常规 CDS 元素的过滤器 FlightDate。

    首先,我们检查实体是否为相关 CDS,以及过滤器元素是否为要过滤的虚拟元素。如果不是这种情况,则会引发异常。

    要创建过滤工厂,请调用类 create_simple_cond_factory 的公共方法 CL_SADL_COND_PROV_PUB。然后为筛选器转换的参考元素创建条件元素。在此示例中,参考元素为 FlightDate。要获取 FlightDate 的过滤条件,您需要将传入过滤器值添加到系统日期。在 lv_date 中使用此日期值,您可以比较所有过滤器运算符的 FlightDate。

    备注

    ABAP 可以在明确值为日期类型的上下文中处理使用日期格式的计算。

    CLASS /dmo/cl_days_to_flight_filter IMPLEMENTATION.
    									METHOD if_sadl_exit_filter_transform~map_atom.
    									IF iv_entity <> '/DMO/C_BOOKING_VE'.
    									RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
    									EXPORTING
    									textid  = /dmo/cx_virtual_elements=>entity_not_known
    									element = iv_entity.
    									ENDIF.
    
    									IF iv_element <> 'DAYSTOFLIGHT'.
    									RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
    									EXPORTING
    									textid   = /dmo/cx_virtual_elements=>filter_element_not_expected
    									entity   = iv_entity
    									element  = iv_element.
    									ENDIF.
    
    									DATA(lo_cfac) = cl_sadl_cond_prov_factory_pub=>create_simple_cond_factory( ).
    									DATA(flightdate) = lo_cfac->element( 'FLIGHTDATE' ).
    									DATA(lv_date) = cl_abap_context_info=>get_system_date( ).
    
    									lv_date += iv_value.
    
    									CASE iv_operator.
    
    									WHEN if_sadl_exit_filter_transform~co_operator-equals        .
    									ro_condition = flightdate->equals( lv_date ).
    
    									WHEN if_sadl_exit_filter_transform~co_operator-less_than     .
    									ro_condition = flightdate->less_than( lv_date  ).
    
    									WHEN if_sadl_exit_filter_transform~co_operator-greater_than  .
    									ro_condition = flightdate->greater_than( lv_date  ).
    
    									WHEN if_sadl_exit_filter_transform~co_operator-is_null       .
    									ro_condition = flightdate->is_null( ).
    
    									WHEN OTHERS.
    									"Operator not expected
    									RAISE EXCEPTION TYPE /dmo/cx_virtual_elements
    									EXPORTING
    									textid   = /dmo/cx_virtual_elements=>filter_operator_not_allowed
    									entity   = iv_entity
    									element  = iv_element
    									operator = iv_operator.
    									ENDCASE.
    									ENDMETHOD.
    
    									ENDCLASS.