扩展 CDS 视图

ABAP RESTful 应用程序编程模型 › 扩展 › RAP 扩展 › 开发 RAP 扩展 › 开发数据模型扩展 › 扩展 CDS 视图

本章将指导您完成使用您在上一步添加到数据库表中的字段扩展参考业务对象的 CDS 数据模型的必要步骤。

前提条件

  • 您已按启用 CDS 视图章节中所述启用 CDS 数据模型的可扩展性。

  • 您已按扩展数据库表章节中所述,将字段 /dmo/zzsloganzag 添加到活动数据库表和草稿数据库表。

所需扩展步骤

为了使新字段在 CDS 数据模型中可用,首先需要为扩展 include 视图 /DMO/E_Agency 创建 CDS 视图扩展,并将字段添加到此视图。您可以通过扩展 include 视图中定义的数据源别名访问数据库表中的新字段。

接下来,为 CDS 视图 /DMO/R_AGENCYTP 创建 CDS 视图扩展,并使用与扩展 include 视图 的关联将新字段添加到 CDS 视图 /DMO/R_AGENCYTP。

在最后一步中,使新字段在 CDS 映射视图 /DMO/C_AGENCYTP、界面视图 /DMO/I_AGENCYTP 和草稿查询视图 /DMO/R_AGENCYDRAFT 中也可用。使用在扩展 CDS 视图中分别定义的数据源别名访问字段。

由于新字段在数据库和 CDS 级别具有相同的名称,因此不需要映射扩展。

过程

  1. 为扩展 include 视图 /DMO/E_AGENCY 创建名为 /DMO/ZZ_X_SLOGAN_E_AGENCY 的 CDS 扩展视图,并在字段列表中添加新字段。由于已使用新字段扩展数据库表 /DMO/AGENCY,因此可以在路径表达式中使用扩展 include 视图中定义的数据源别名 Agency 来访问字段。

    extend view entity /DMO/E_Agency with
    {
      Agency./dmo/zzsloganzag as /DMO/ZZSloganZAG
    }
    

    备注

    不应在基础层执行从小写更改为大写(反之亦然)以外的别名。在接口层或业务对象的投影层上可以使用别名。

    备注

    扩展元素的名称必须以相关包使用的命名空间前缀开头。由于命名空间 /DMO/ 用于传送整个代理参考场景,因此前缀 /DMO/ 也用于此示例中的扩展元素。在生产环境中,扩展元素的命名空间前缀与原始业务对象的命名空间不同。这由 /DMO/ 命名空间后的附加项 ZZ 指示。

  2. 为 CDS 视图 /DMO/ZZ_X_SLOGAN_R_AGENCY 创建名为 /DMO/R_AGENCYTP 的 CDS 扩展视图,并在字段列表中添加新字段。要访问该字段,请在路径表达式中使用与扩展 include 视图 /DMO/E_AGENCY 的关联 _Extension。

    extend view entity /DMO/R_AgencyTP with
    {
      _Extension./DMO/ZZSloganZAG
    }
    
  3. 为 CDS 映射视图 /DMO/ZZ_X_SLOGAN_C_AGENCY 创建名为 /DMO/C_AGENCYTP 的 CDS 扩展视图,并在字段列表中添加新字段。要访问字段,请在路径表达式中使用 CDS 投影视图中定义的数据源别名 Agency。该字段在 CDS 视图 /DMO/R_AGENCYTP 中可用,因为您已在上一步中对其进行扩展。为缺省搜索元素和字段的模糊性阈值添加 UI 注释以及搜索注释。

    extend view entity /DMO/C_AgencyTP with
    {
      @UI: {
        lineItem:   [ { position: 25, importance: #HIGH },
                      { position: 10, type: #FOR_ACTION, dataAction: '/DMO/createFromTemplate', label: 'Create from Template' } ],
        fieldGroup: [ { position: 25, qualifier: 'General_FG' } ],
        identification: [ { position: 10, type: #FOR_ACTION, dataAction: '/DMO/createFromTemplate', label: 'Create from Template' } ]
      }
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      Agency./DMO/ZZSloganZAG
    }
    
  4. 为 CDS 接口映射视图 /DMO/ZZ_X_SLOGAN_I_AGENCY 创建名为 /DMO/I_AGENCYTP 的 CDS 扩展视图,并在字段列表中添加新字段 。要访问字段,请在路径表达式中使用接口映射视图中定义的数据源别名 Agency。该字段在 CDS 视图 /DMO/R_AGENCYTP 中可用,因为您已在上一步中对其进行扩展。

    extend view entity /DMO/I_AgencyTP with
    {
      Agency./DMO/ZZSloganZAG
    }
    
  5. 为草稿查询视图 /DMO/ZZ_X_SLOGAN_R_AGENCYDRAFT 创建名为 /DMO/R_AGENCYDRAFT 的 CDS 扩展视图,并在字段列表中添加新字段。由于已使用新字段扩展数据库表 /DMO/AGENCY_D,因此可以在路径表达式中使用草稿查询视图中定义的数据源别名 Agency 来访问字段。

    extend view entity /DMO/R_AgencyDraft with
    {
      Agency./dmo/zzsloganzag as /DMO/ZZSloganZAG
    }
    

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 扩展数据库表 · 开发行为扩展 →