草稿场景:实施测试方法
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为草稿航班参考场景开发测试类 › 草稿场景:实施测试方法
本主题显示确定方法 setTravelNumber 的可能单元测试。
本主题中的文档仅涉及相应的测试方法。有关测试类其他部分的信息,请参阅草稿场景:创建测试类。
测试设计
要测试的方法可分为两部分:第一部分使用导入的密钥读取差旅实例,并从已具有差旅标识的读取结果表 travels 中移除这些差旅实例。这可确保确定的幂等性。如果执行此步骤后表 travels 为空,则终止该方法。如果表不为空,则方法的第二部分将计算新的差旅 ID 并将其分配给差旅实例。
第一个测试方法通过提供具有现有差旅 ID 的差旅实例来检查幂等性。第二种测试方法检查是否为没有差旅标识的实例正确计算了新的差旅标识。第三个测试方法检查前两个测试用例的组合。
测试方法 settravelnumber_idempotence
测试方法首先将具有差旅标识的差旅实例添加到 CDS 测试双精度。
由于被测方法将 reported 响应的结构作为更改参数,因此使用从差旅 CDS 实体及其行为定义派生的相应类型声明结构 reported。
现在,调用要测试的方法。已插入到测试双精度的 实例的行程 UUID 作为导出参数提供,声明的报告结构作为更改参数。
reported 结构可能包含更新操作失败的消息,因此该方法断言 reported 结构为初始值。
该方法现在检查实例是否仍具有其差旅标识。为此,首先从交易缓冲区读取差旅 UUID 和差旅标识。接下来,该方法执行断言检查:第一个断言读取结果表包含一行。此断言检查可确保正确的读取实例数,并用于防止转储,如果表 read_result 为空,则会在下一次断言检查期间发生转储。第二个检查断言差旅 ID 未更改。
展开以下代码示例以查看方法 settravelnumber_idempotence 的源代码。
示例代码
METHOD settravelnumber_idempotence.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/A_Travel_D.
travel_mock_data = VALUE #( ( travel_uuid = uuid1 travel_id = '1' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structure
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_Travel_D.
" Call the method to be tested
class_under_test->setTravelNumber(
EXPORTING
keys = VALUE #( ( TravelUUID = travel_mock_data[ 1 ]-travel_uuid ) )
CHANGING
reported = reported
).
" Check for content in reported
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
" Read instance data
READ ENTITY /DMO/I_Travel_D
FIELDS ( TravelID ) WITH VALUE #( ( TravelUUID = travel_mock_data[ 1 ]-travel_uuid ) )
RESULT DATA(read_result).
" Check number of returned instances in read_result
cl_abap_unit_assert=>assert_equals( msg = 'lines in read result' exp = 1 act = lines( read_result ) ).
" Check idempotence
cl_abap_unit_assert=>assert_equals( msg = 'idempotence' exp = '1' act = read_result[ 1 ]-TravelID ).
ENDMETHOD.
测试方法 settravelnumber_newtravelids
此测试方法涵盖针对尚不包含差旅标识的差旅实例执行确定的情况。由于测试双精度不包含具有差旅标识的其他差旅实例,该方法断言该实例的已计算差旅标识为 1 和 2。
展开以下代码示例以查看方法 settravelnumber_newtravelids 的源代码。
示例代码
METHOD settravelnumber_newtravelids.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/A_Travel_D.
travel_mock_data = VALUE #( ( travel_uuid = uuid1 )
( travel_uuid = uuid2 ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structure
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_Travel_D.
" Call the method to be tested
class_under_test->setTravelNumber(
EXPORTING
keys = VALUE #( FOR key IN travel_mock_data ( TravelUUID = key-travel_uuid ) )
CHANGING
reported = reported
).
" Check for content in reported
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
" Read and sort instance data
READ ENTITY /DMO/I_Travel_D
FIELDS ( TravelID ) WITH VALUE #( FOR key IN travel_mock_data ( TravelUUID = key-travel_uuid ) )
RESULT DATA(read_result).
SORT read_result BY travelid.
" Check number of returned instances in read_result
cl_abap_unit_assert=>assert_equals( msg = 'lines in read result' exp = 2 act = lines( read_result ) ).
" Check new travel ids
cl_abap_unit_assert=>assert_equals( msg = 'new travel id' exp = '1' act = read_result[ 1 ]-TravelID ).
cl_abap_unit_assert=>assert_equals( msg = 'new travel id' exp = '2' act = read_result[ 2 ]-TravelID ).
ENDMETHOD.
测试方法 settravelnumber_mixed
最新测试方法检查先前测试用例的组合:两个需要差旅标识的差旅实例和一个已具有差旅标识的差旅实例。为确保预期差旅标识属于正确的差旅实例,该方法还检查读取结果中的差旅 UUID。
展开以下代码示例以查看方法 settravelnumber_newtravel_mixed 的源代码。
示例代码
METHOD settravelnumber_newtravel_mixed.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/A_Travel_D.
travel_mock_data = VALUE #( ( travel_uuid = uuid1 )
( travel_uuid = uuid2 travel_id = '1' )
( travel_uuid = uuid3 ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structure
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_Travel_D.
" Call the method to be tested
class_under_test->setTravelNumber(
EXPORTING
keys = VALUE #( FOR key IN travel_mock_data ( TravelUUID = key-travel_uuid ) )
CHANGING
reported = reported
).
" Check for content in reported
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
" Read and sort instance data
READ ENTITY /DMO/I_Travel_D
FIELDS ( TravelID ) WITH VALUE #( FOR key IN travel_mock_data ( TravelUUID = key-travel_uuid ) )
RESULT DATA(read_result).
SORT read_result BY travelid.
" Check number of returned instances in read result
cl_abap_unit_assert=>assert_equals( msg = 'lines in read result' exp = 3 act = lines( read_result ) ).
" Check travel uuid of first instance
cl_abap_unit_assert=>assert_equals( msg = 'travel uuid' act = read_result[ 1 ]-TravelUUID exp = uuid2 ).
" Check idempotence
cl_abap_unit_assert=>assert_equals( msg = 'idempotence' act = read_result[ 1 ]-TravelID exp = '1' ).
" Check travel uuid of second instance
cl_abap_unit_assert=>assert_equals( msg = 'travel uuid' act = read_result[ 2 ]-TravelUUID exp = uuid1 ).
" Check new travel id
cl_abap_unit_assert=>assert_equals( msg = 'new travel id' act = read_result[ 2 ]-TravelID exp = '2' ).
" Check travel uuid of third instance
cl_abap_unit_assert=>assert_equals( msg = 'travel uuid' act = read_result[ 3 ]-TravelUUID exp = uuid3 ).
" Check new travel id
cl_abap_unit_assert=>assert_equals( msg = 'new travel id' act = read_result[ 3 ]-TravelID exp = '3' ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 草稿场景:创建测试类 · 为补充参考场景开发测试类 →