草稿场景:创建测试类

ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为草稿航班参考场景开发测试类 › 草稿场景:创建测试类

在此步骤中,您将创建测试类,作为要开发的测试方法的基础。

要创建测试类,请执行以下操作:

  1. 启动 ABAP 开发工具。

  2. 在 ABAP 项目(或 ABAP 云项目)中,选择行为实施 /DMO/BP_TRAVEL_D。

  3. 在测试类标签中,单击创建测试类按钮,键入“测试”一词并使用代码完整化插入测试类模板。

  4. 将类命名为 ltc_draft 并移除虚拟方法 first_test 的声明和实施。

  5. 激活更改。

  6. 添加创建的测试类作为本地处理器类 lhc_travel 的友元,以便能够访问其私有方法。按照 被管理场景:提供对已测试方法的访问权限 中所述进行操作。

  7. 按照 被管理场景:细化测试类结构 中所述细化测试类结构。除上述链接的说明外,还要考虑测试类的以下方面:

    • 测试方法

      声明测试方法 setTravelNumber_idempotence、setTravelNumber_newTravelID 和 settravelnumber_mixed,并使用提供的快速修复在类的实现部分插入签名。有关测试设计的信息,请参阅草稿场景:实施测试方法。

    • UUID 常量

      声明用作测试数据的差旅 UUID 的四个常量。

    • CDS 测试双框架

      您需要 CDS 测试双重框架来使测试方法的 EML 调用通过 CDS 视图 /DMO/I_TRAVEL_D 访问双重数据库相关性。提供此 CDS 视图名称作为 cl_cds_test_environment 类的 create 方法的导入参数。

    • 开放式 SQL 调用的双重重定向

      测试方法包含直接访问数据库表 /dmo/a_travel_d 的开放式 SQL 调用。要使此开放式 SQL 调用访问测试双精度而不是实际数据库表,请在创建 CDS 测试环境和测试双精度表后调用类设置中的方法 enable_double_redirection。

遵循上述步骤后,您的测试类如下所示,并准备好实施测试方法:

展开以下代码示例以查看测试类 ltc_draft 的源代码。

示例代码

"! @testing BDEF:/DMO/I_TRAVEL_D
CLASS ltc_draft DEFINITION FINAL FOR TESTING
  DURATION SHORT
  RISK LEVEL HARMLESS.
  PRIVATE SECTION.

    CLASS-DATA: class_under_test     TYPE REF TO lhc_travel,
                cds_test_environment TYPE REF TO if_cds_test_environment.

    CONSTANTS: uuid1 TYPE sysuuid_x16 VALUE '66657221A8E4645C17002DF03754A1',
               uuid2 TYPE sysuuid_x16 VALUE '66657221A8E4645C17002DF03754A2',
               uuid3 TYPE sysuuid_x16 VALUE '66657221A8E4645C17002DF03754A3',
               uuid4 TYPE sysuuid_x16 VALUE '66657221A8E4645C17002DF03754A4'.

    CLASS-METHODS:
    "! Instantiate class under test and set up CDS Test Double Framework
    class_setup,

    "! Destroy test environment and test double
    class_teardown.

    METHODS:
    "! Reset test double
    setup,

    "! Reset transactional buffer
    teardown,

    "! Check instance with already existing travel id
    setTravelNumber_idempotence  FOR TESTING,

    "! Check instances with new travel ids
    settravelnumber_newtravelids FOR TESTING,

    "! Check instances with and without travel ids
    settravelnumber_mixed        FOR TESTING.

ENDCLASS.

CLASS ltc_draft IMPLEMENTATION.

METHOD class_setup.
    CREATE OBJECT class_under_test FOR TESTING.
    cds_test_environment = cl_cds_test_environment=>create( i_for_entity = '/DMO/I_TRAVEL_D' ).
    cds_test_environment->enable_double_redirection(  ).
ENDMETHOD.

METHOD setup.
    cds_test_environment->clear_doubles( ).
ENDMETHOD.

METHOD teardown.
    ROLLBACK ENTITIES.
ENDMETHOD.

METHOD class_teardown.
    cds_test_environment->destroy( ).
ENDMETHOD.

METHOD setTravelNumber_idempotence.
ENDMETHOD.

METHOD settravelnumber_newtravelids.
ENDMETHOD.

METHOD settravelnumber_mixed.
ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 为草稿航班参考场景开发测试类 · 草稿场景:实施测试方法 →