托管方案:细化测试类结构
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为管理的航班参考场景开发测试类 › 管理的方案:细化测试类结构
现在您已创建基本测试类结构,可以通过定义提供所需测试配置的基本测试属性、测试关系、变量和固定设备方法来细化此结构。定义的测试类构成了测试方法的基础,将在接下来的章节中实施这些测试方法。
本主题涵盖测试类的特定结构,用于托管航班参考场景的行为实施。有关 RAP 测试类结构的常规信息,请参阅基本测试类结构。
测试类定义
测试类的定义部分包含基本元信息、参考变量以及固定设备和测试方法的声明。
分配测试属性
由于测试方法的大小相对较小,因此测试代码的执行时间不应超过 5 秒。因此,您可以使用 DURATION SHORT。根据相应的运行模式和运行时监控器,超过所选执行时间可能会影响测试结果。
由于您不会通过单元测试更改持久数据或系统设置,因此可以使用 RISK LEVEL HARMLESS。如果所选风险级别高于系统中允许的风险级别,则不会执行测试。
CLASS ltc_managed DEFINITION FINAL FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS.
指定测试关系
您将为业务对象 /DMO/I_Travel_M 开发单元测试。通过指定与此业务对象的测试关系,您可以通过业务对象的行为定义的上下文菜单直接运行单元测试。
"! @testing BDEF:/DMO/I_Travel_M
CLASS ltc_managed DEFINITION FINAL FOR TESTING
...
声明参考变量
为了调用要测试的方法,需要在 之前实例化其类。为此,请在专用部分中声明类 lhc_travel 的参考变量。
由于您将使用 CDS 测试双框架和 SQL 测试双框架的接口来模拟测试数据,因此还需要声明这些接口的参考变量。
PRIVATE SECTION.
CLASS-DATA: class_under_test TYPE REF TO lhc_travel,
cds_test_environment TYPE REF TO if_cds_test_environment,
sql_test_environment TYPE REF TO if_osql_test_environment.
声明固定设备和测试方法
除了声明测试方法外,还声明固定设备方法。固定设备方法用于设置和拆卸测试环境,为每个执行的测试生成唯一的测试行为。声明的测试方法可能与要测试的方法具有相同的名称。对于某些方法,您将开发多种测试方法,以确保测试稳定性和易于维护。
展开以下代码示例以查看源代码。
示例代码
CLASS-METHODS:
"! Instantiate class under test and setup test double frameworks
class_setup,
"! Destroy test environments and test doubles
class_teardown.
METHODS:
"! Reset test doubles
setup,
"! Reset transactional buffer
teardown,
"! Check instance with overall status 'Open'
validate_travel_status_open FOR TESTING,
"! Check instance with overall status 'Accepted'
validate_travel_status_acpt FOR TESTING,
"! Check instance with overall status 'Rejected'
validate_travel_status_rej FOR TESTING,
"! Check instance with invalid overall status
validate_travel_status_invalid FOR TESTING,
"! Check returned features for instance with overall status 'Open'
get_features_open FOR TESTING,
"! Check returned features for instance with overall status 'Accepted'
get_features_accepted FOR TESTING,
"! Check returned features for instance with overall status 'Rejected'
get_features_rejected FOR TESTING,
"! Check returned features for instance with invalid overall status
get_features_invalidstatus FOR TESTING,
"! Check returned features for instance with invalid key
get_features_invalidkey FOR TESTING,
"! Check instance with valid customer ID
validate_customer_valid FOR TESTING,
"! Check instance with invalid customer ID
validate_customer_invalid FOR TESTING,
"! Check instance with initial customer ID
validate_customer_initial FOR TESTING,
"! Check set_status_accepted action
set_status_accepted FOR TESTING.
有关特定测试设计的信息,请参阅:
测试类实施
本部分介绍固定设备方法的实施,这些固定设备方法指定测试方法使用的测试配置。
实施方法 class_setup
为了调用测试类 lhc_travel 的方法,需要在 之前实例化此类。附加项 FOR TESTING 支持实例化行为实施的处理器类。
测试方法包含通过 CDS 实体 Travel 访问实例数据的 EML 语句。为了让这些 EML 语句访问测试双数据库的数据而不是实际数据库表,现在需要使用 CDS 测试双层框架创建测试双重。指定 CDS 视图 /DMO/I_TRAVEL_M 以确保数据库表 /dmo/travel_m 翻倍。
测试方法 validate_customer 包含用于直接访问数据库的开放式 SQL 语句。为了使这些 SQL 语句访问测试双精度数据而不是实际数据库的数据,还需要使用 SQL 测试双层框架为数据库表 /DMO/CUSTOMER 创建测试双精度。
METHOD class_setup.
CREATE OBJECT class_under_test FOR TESTING.
cds_test_environment = cl_cds_test_environment=>create( i_for_entity = '/DMO/I_TRAVEL_M' ).
sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #( ( '/DMO/CUSTOMER' ) ) ).
ENDMETHOD.
实施方法 setup
为确保测试方法不受其他测试方法数据的影响,请在每次测试方法执行之前清除测试两倍的内容。
METHOD setup.
cds_test_environment->clear_doubles( ).
sql_test_environment->clear_doubles( ).
ENDMETHOD.
实施方法 teardown
为确保每次测试方法执行后为相关实体重置事务缓冲区,请在拆卸方法中使用 EML 语句 ROLLBACK ENTITIES。
METHOD teardown.
ROLLBACK ENTITIES.
ENDMETHOD.
实施方法 class_teardown
测试结束时,清除测试环境和创建的测试两倍。
METHOD class_teardown.
cds_test_environment->destroy( ).
sql_test_environment->destroy( ).
ENDMETHOD.
结果测试类
遵循上述步骤后,您的测试类如下所示,并准备好实施测试方法:
展开以下代码示例以查看测试类 ltc_managed 的源代码。
示例代码
"! @testing BDEF:/DMO/I_Travel_M
CLASS ltc_managed DEFINITION FINAL FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS.
PRIVATE SECTION.
CLASS-DATA: class_under_test TYPE REF TO lhc_travel,
cds_test_environment TYPE REF TO if_cds_test_environment,
sql_test_environment TYPE REF TO if_osql_test_environment.
CLASS-METHODS:
"! Instantiate class under test and setup test double frameworks
class_setup,
"! Destroy test environments and test doubles
class_teardown.
METHODS:
"! Reset test doubles
setup,
"! Reset transactional buffer
teardown,
"! Check instance with overall status 'Open'
validate_travel_status_open FOR TESTING,
"! Check instance with overall status 'Accepted'
validate_travel_status_acpt FOR TESTING,
"! Check instance with overall status 'Rejected'
validate_travel_status_rej FOR TESTING,
"! Check instance with invalid overall status
validate_travel_status_invalid FOR TESTING,
"! Check returned features for instance with overall status 'Open'
get_features_open FOR TESTING,
"! Check returned features for instance with overall status 'Accepted'
get_features_accepted FOR TESTING,
"! Check returned features for instance with overall status 'Rejected'
get_features_rejected FOR TESTING,
"! Check returned features for instance with invalid overall status
get_features_invalidstatus FOR TESTING,
"! Check returned features for instance with invalid key
get_features_invalidkey FOR TESTING,
"! Check instance with valid customer ID
validate_customer_valid FOR TESTING,
"! Check instance with invalid customer ID
validate_customer_invalid FOR TESTING,
"! Check instance with initial customer ID
validate_customer_initial FOR TESTING,
"! Check set_status_accepted action
set_status_accepted FOR TESTING.
ENDCLASS.
CLASS ltc_managed IMPLEMENTATION.
METHOD class_setup.
CREATE OBJECT class_under_test FOR TESTING.
cds_test_environment = cl_cds_test_environment=>create( i_for_entity = '/DMO/I_TRAVEL_M' ).
sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #( ( '/DMO/CUSTOMER' ) ) ).
ENDMETHOD.
METHOD setup.
cds_test_environment->clear_doubles( ).
sql_test_environment->clear_doubles( ).
ENDMETHOD.
METHOD teardown.
ROLLBACK ENTITIES.
ENDMETHOD.
METHOD class_teardown.
cds_test_environment->destroy( ).
sql_test_environment->destroy( ).
ENDMETHOD.
METHOD validate_travel_status_open.
ENDMETHOD.
METHOD validate_travel_status_acpt.
ENDMETHOD.
METHOD validate_travel_status_rej.
ENDMETHOD.
METHOD validate_travel_status_invalid.
ENDMETHOD.
METHOD get_features_open.
ENDMETHOD.
METHOD get_features_accepted.
ENDMETHOD.
METHOD get_features_rejected.
ENDMETHOD.
METHOD get_features_invalidstatus.
ENDMETHOD.
METHOD get_features_invalidkey.
ENDMETHOD.
METHOD validate_customer_valid.
ENDMETHOD.
METHOD validate_customer_invalid.
ENDMETHOD.
METHOD validate_customer_initial.
ENDMETHOD.
METHOD set_status_accepted.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译