测试验证方法 validate_travel_status
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为管理的航班参考场景开发测试类 › 托管方案:实施测试方法 › 测试验证方法 validate_travel_status
本主题显示验证方法 validate_travel_status 的可能单元测试。
本主题中的文档仅涉及相应的测试方法。有关测试类其他部分的信息,请参阅管理场景:细化测试类结构。
测试设计
测试包含四种测试方法,反映测试方法涵盖的不同情况。前三种方法是指差旅实例包含有效总体状态值(已接受、已拒绝和**未处理)的情况。第四个测试方法涵盖差旅实例包含总体状态值(与上述值不同)的情况。此类值被验证视为无效。
将测试代码细分为单独的测试方法有助于测试维护。例如,如果无效总体状态的实施发生更改,则只需调整相应的测试方法,所有其他测试方法都可以保持不变。
测试方法 validate_travel_status_open
测试方法首先为测试双精度添加总体状态值为 O(表示“未清”)的行程实例。
由于被测方法要求将 failed 和 reported 响应的结构作为更改参数,因此将使用从差旅 CDS 实体及其行为定义派生的相应类型声明两个结构。
现在,调用要测试的方法。已插入到测试双精度的 实例的行程标识作为导出参数提供,声明的失败和已报告结构作为更改参数提供。
最后,使用断言检查评估测试方法返回的失败结构和报告结构。由于验证接受总体状态字段的值,因此失败和已报告结构预期为空。
展开以下代码示例以查看方法 validate_travel_status_open 的源代码。
示例代码
METHOD validate_travel_status_open.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '52' overall_status = 'O' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structures
DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_TRAVEL_M.
" Call method to be tested
class_under_test->validate_travel_status(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
CHANGING
failed = failed
reported = reported
).
" Check for content in failed and reported
cl_abap_unit_assert=>assert_initial( msg = 'failed' act = failed ).
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
ENDMETHOD.
测试方法 validate_travel_status_acpt
此测试方法遵循与整体状态*“未处理*”的测试方法相同的方法,但这次使用整体状态“已接受”,这也有效。
展开以下代码示例以查看方法 validate_travel_status_acpt 的源代码。
示例代码
METHOD validate_travel_status_acpt.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '52' overall_status = 'A' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structures
DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_TRAVEL_M.
" Call method to be tested
class_under_test->validate_travel_status(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
CHANGING
failed = failed
reported = reported
).
" Check for content in failed and reported
cl_abap_unit_assert=>assert_initial( msg = 'failed' act = failed ).
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
ENDMETHOD.
测试方法 validate_travel_status_rej
此测试方法遵循与整体状态*“未处理*”的测试方法相同的方法,但这次使用整体状态“已拒绝”,这同样有效。
展开以下代码示例以查看方法 validate_travel_status_rej 的源代码。
示例代码
METHOD validate_travel_status_rej.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '52' overall_status = 'X' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structures
DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_TRAVEL_M.
" Call method to be tested
class_under_test->validate_travel_status(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
CHANGING
failed = failed
reported = reported
).
" Check for content in failed and reported
cl_abap_unit_assert=>assert_initial( msg = 'failed' act = failed ).
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
ENDMETHOD.
测试方法 validate_travel_status_invalid
此测试方法遵循与预期值的测试方法相同的方法,但这次将整体状态设置为与验证预期值不同的值。
该方法断言 failed 和 reported 结构在其差旅表中仅包含一行。这样可以防止转储,当尝试访问表中不可用的行时,将在后续断言检查期间发生转储。后续检查断言失败且报告的差旅标识等于为 CDS 测试双重提供的标识。对于报告的结构,该方法还断言在 %element 组件中标记了正确的元素,并且其中包含有效的消息参考。
展开以下代码示例以查看方法 validate_travel_status_invalid 的源代码。
示例代码
METHOD validate_travel_status_invalid.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '52' overall_status = 'T' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required structures
DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED LATE /DMO/I_TRAVEL_M.
" Call method to be tested
class_under_test->validate_travel_status(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
CHANGING
failed = failed
reported = reported
).
" Check number of returned instances in failed-travel
cl_abap_unit_assert=>assert_equals( act = lines( failed-travel ) exp = 1 msg = 'lines in failed-travel' ).
" Check travel id in failed-travel
cl_abap_unit_assert=>assert_equals( act = failed-travel[ 1 ]-travel_id exp = '52' msg = 'travel id in failed-travel' ).
" Check number of returned instances in reported-travel
cl_abap_unit_assert=>assert_equals( act = lines( reported-travel ) exp = 1 msg = 'lines in reported-travel' ).
" Check travel id in reported-travel
cl_abap_unit_assert=>assert_equals( act = reported-travel[ 1 ]-travel_id exp = '52' msg = 'travel id in reported-travel' ).
" Check marked field in reported-travel
cl_abap_unit_assert=>assert_equals( act = reported-travel[ 1 ]-%element-overall_status exp = if_abap_behv=>mk-on msg = 'field overall status in reported-travel' ).
" Check message reference in reported-travel
cl_abap_unit_assert=>assert_bound( act = reported-travel[ 1 ]-%msg msg = 'message reference in reported-travel' ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译