测试功能控制方法 get_features
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为管理的航班参考场景开发测试类 › 托管方案:实施测试方法 › 测试功能控制方法 get_features
本主题显示功能控制方法 get_features 的可能的单元测试。
本主题中的文档仅涉及相应的测试方法。有关测试类其他部分的信息,请参阅管理场景:细化测试类结构。
测试设计
测试包含五种测试方法,反映了测试方法涵盖的不同情况。每个总体状态值都有一个测试方法,即验证时认为该方法有效 validate_travel_status。第四个测试方法涵盖无效总体状态值的情况。第五个涉及测试方法处理具有无效差旅标识的差旅实例的情况。
将测试代码细分为单独的测试方法有助于测试维护。例如,如果在测试方法中实施整体状态待处理的专用处理,则只需调整相应的测试方法,所有其他测试方法都可以保持不变。
测试方法 get_features_open
测试方法首先向测试双精度添加值为 O(表示“打开”)的行程实例。
由于被测方法预期将 result、failed 和 reported 响应的结构作为更改参数,因此将使用从差旅 CDS 实体及其行为定义派生的相应类型声明三个结构。
现在,调用要测试的方法。实例的行程标识(已插入到测试双精度中)以及要检查的功能作为导出参数提供。声明的结果、失败和报告结构作为更改参数提供。
代码的最后一部分检查是否已使用预期的功能控制信息填充结果。为了能够将预期结果与实际结果进行比较,可通过引用 expected 表的数据类型来声明内部表 result。然后,使用预期内容填充声明表 - 包含模拟差旅标识和操作 acceptTravel 和 enabled 以及关联 rejectTravel 的预期操作控制常量 _Booking 的行程实例。
展开以下代码示例以查看测试方法 get_features_open 的源代码。
示例代码
METHOD get_features_open.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '43' overall_status = 'O' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required table and structures
DATA result TYPE TABLE FOR INSTANCE FEATURES RESULT /DMO/I_TRAVEL_M\\travel.
DATA failed TYPE RESPONSE FOR FAILED EARLY /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED EARLY /DMO/I_TRAVEL_M.
" Call the method to be tested
class_under_test->get_features(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
requested_features = VALUE #( %action-accepttravel = if_abap_behv=>mk-on
%action-rejectTravel = if_abap_behv=>mk-on
%assoc-_Booking = if_abap_behv=>mk-on )
CHANGING
result = result
failed = failed
reported = reported
).
" Check result
DATA expected LIKE result.
expected = VALUE #( ( travel_id = '43'
%action-accepttravel = if_abap_behv=>fc-o-enabled
%action-rejectTravel = if_abap_behv=>fc-o-enabled
%assoc-_Booking = if_abap_behv=>fc-o-enabled ) ).
cl_abap_unit_assert=>assert_equals( msg = 'result' exp = expected act = result ).
ENDMETHOD.
测试方法 get_features_accepted
此测试方法遵循与整体状态 未处理 的测试方法相同的方法,但这次使用整体状态 已接受 。在这种情况下,预期将禁用操作 accepttravel,而需要启用操作 rejecttravel 和关联 _Booking。
展开以下代码示例以查看测试方法 get_features_accepted 的源代码。
示例代码
METHOD get_features_accepted.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '43' overall_status = 'A' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required table and structures
DATA result TYPE TABLE FOR INSTANCE FEATURES RESULT /DMO/I_TRAVEL_M\\travel.
DATA failed TYPE RESPONSE FOR FAILED EARLY /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED EARLY /DMO/I_TRAVEL_M.
" Call the method to be tested
class_under_test->get_features(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
requested_features = VALUE #( %action-accepttravel = if_abap_behv=>mk-on
%action-rejectTravel = if_abap_behv=>mk-on
%assoc-_Booking = if_abap_behv=>mk-on )
CHANGING
result = result
failed = failed
reported = reported
).
" Check result
DATA expected LIKE result.
expected = VALUE #( ( travel_id = '43'
%action-accepttravel = if_abap_behv=>fc-o-disabled
%action-rejectTravel = if_abap_behv=>fc-o-enabled
%assoc-_Booking = if_abap_behv=>fc-o-enabled ) ).
cl_abap_unit_assert=>assert_equals( msg = 'result' exp = expected act = result ).
ENDMETHOD.
测试方法 get_features_rejected
此测试方法遵循与之前涵盖的总体状态的测试方法相同的方法,但这次使用整体状态已拒绝。在这种情况下,预期启用操作 accepttravel,而操作 rejecttravel 和关联 _Booking 预期将被禁用。
展开以下代码示例以查看测试方法 get_features_rejected 的源代码。
示例代码
METHOD get_features_rejected.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '43' overall_status = 'X' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required table and structures
DATA result TYPE TABLE FOR INSTANCE FEATURES RESULT /DMO/I_TRAVEL_M\\travel.
DATA failed TYPE RESPONSE FOR FAILED EARLY /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED EARLY /DMO/I_TRAVEL_M.
" Call method to be tested
class_under_test->get_features(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
requested_features = VALUE #( %action-accepttravel = if_abap_behv=>mk-on
%action-rejectTravel = if_abap_behv=>mk-on
%assoc-_Booking = if_abap_behv=>mk-on )
CHANGING
result = result
failed = failed
reported = reported
).
" Check result
DATA expected LIKE result.
expected = VALUE #( ( travel_id = '43'
%action-accepttravel = if_abap_behv=>fc-o-enabled
%action-rejectTravel = if_abap_behv=>fc-o-disabled
%assoc-_Booking = if_abap_behv=>fc-o-disabled ) ).
cl_abap_unit_assert=>assert_equals( msg = 'result' exp = expected act = result ).
ENDMETHOD.
测试方法 get_features_invalidstatus
此测试方法遵循与之前涵盖的总体状态的测试方法相同的方法,但这次使用无效的总体状态值。在这种情况下,需要启用操作和关联。
展开以下代码示例以查看测试方法 get_features_invalidstatus 的源代码。
示例代码
METHOD get_features_invalidstatus.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '43' overall_status = 'T' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required table and structures
DATA result TYPE TABLE FOR INSTANCE FEATURES RESULT /DMO/I_TRAVEL_M\\travel.
DATA failed TYPE RESPONSE FOR FAILED EARLY /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED EARLY /DMO/I_TRAVEL_M.
" Call the method to be tested
class_under_test->get_features(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
requested_features = VALUE #( %action-accepttravel = if_abap_behv=>mk-on
%action-rejectTravel = if_abap_behv=>mk-on
%assoc-_Booking = if_abap_behv=>mk-on )
CHANGING
result = result
failed = failed
reported = reported
).
" Check result
DATA expected LIKE result.
expected = VALUE #( ( travel_id = '43'
%action-accepttravel = if_abap_behv=>fc-o-enabled
%action-rejectTravel = if_abap_behv=>fc-o-enabled
%assoc-_Booking = if_abap_behv=>fc-o-enabled ) ).
cl_abap_unit_assert=>assert_equals( msg = 'result' exp = expected act = result ).
ENDMETHOD.
测试方法 get_features_invalidkey
此测试方法使用差旅标识调用测试方法,该方法在测试双重中不可用。因此,预期测试方法将返回一个失败的差旅实例,其中包含方法调用期间提供的差旅标识,失败原因为 NOT_FOUND。第一个 assert 检查可防止转储,在尝试访问表中不可用的行时,将在以下 assert 检查期间发生转储。
展开以下代码示例以查看测试方法 get_features_invalidkey 的源代码。
示例代码
METHOD get_features_invalidkey.
" Declare required table and structures
DATA result TYPE TABLE FOR INSTANCE FEATURES RESULT /DMO/I_TRAVEL_M\\travel.
DATA failed TYPE RESPONSE FOR FAILED EARLY /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED EARLY /DMO/I_TRAVEL_M.
" Call the method to be tested with invalid/not existing key
class_under_test->get_features(
EXPORTING
keys = VALUE #( ( travel_id = '43' ) )
requested_features = VALUE #( %action-accepttravel = if_abap_behv=>mk-on
%action-rejectTravel = if_abap_behv=>mk-on
%assoc-_Booking = if_abap_behv=>mk-on )
CHANGING
result = result
failed = failed
reported = reported
).
" Check number of returned instances in failed-travel
cl_abap_unit_assert=>assert_equals( msg = 'lines in failed-travel' act = lines( failed-travel ) exp = 1 ).
" Check travel id in failed-travel
cl_abap_unit_assert=>assert_equals( msg = 'travel id in failed-travel' act = failed-travel[ 1 ]-travel_id exp = '43' ).
" Check fail-cause in failed-travel
cl_abap_unit_assert=>assert_equals( msg = 'fail-cause in failed-travel' act = failed-travel[ 1 ]-%fail-cause exp = if_abap_behv=>cause-not_found ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 测试验证方法 validate_travel_status · 测试验证方法 validate_customer →