测试验证方法 validate_customer

ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为管理的航班参考场景开发测试类 › 托管方案:实施测试方法 › 测试验证方法 validate_customer

本主题显示验证方法 validate_customer 的可能单元测试。

本主题中的文档仅涉及相应的测试方法。有关测试类其他部分的信息,请参阅管理场景:细化测试类结构。

测试设计

测试类包含三种测试方法,它们反映了测试方法涵盖的不同情况。第一个测试方法涵盖有效客户标识的情况,第二个包含无效客户标识的情况,而第三个测试方法涵盖没有为差旅实例提供客户标识的情况。

将测试代码细分为单独的测试方法有助于测试维护。例如,如果为具有初始客户标识的差旅实例实施专用处理,则只需调整相应的测试方法,所有其他测试方法都可以原样保留。

测试方法 validate_customer_valid

测试方法首先将客户标识为 1 的行程实例添加到 CDS 测试双精度。

接着,该方法会将客户标识为 1 的客户数据集添加到 SQL 测试双精度值。

由于被测方法希望将 failed 和 reported 响应的结构作为更改参数,因此将使用从差旅 CDS 实体及其行为定义派生的相应类型声明三个结构。

现在,调用要测试的方法。已插入到测试双精度的 实例的行程标识作为导出参数提供,声明的失败和已报告结构作为更改参数提供。

最后,使用断言检查评估测试方法返回的失败结构和报告结构。由于已验证差旅实例的客户标识包含在双倍客户表中,因此失败和已报告的结构预期为空。

展开以下代码示例以查看测试方法 validate_customer_valid 的源代码。

示例代码

METHOD validate_customer_valid.

    " Fill in test data for entity travel
    DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
    travel_mock_data = VALUE #( ( travel_id = '43' customer_id = '1' ) ).
    cds_test_environment->insert_test_data( travel_mock_data ).

    " Fill in test data for customer table
    DATA customer_mock_data TYPE STANDARD TABLE OF /DMO/CUSTOMER.
    customer_mock_data = VALUE #(  (  customer_id = '1' ) ).
    sql_test_environment->insert_test_data( customer_mock_data ).

    " Declare required structures
    DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
    DATA reported TYPE RESPONSE FOR REPORTED LATE  /DMO/I_TRAVEL_M.

    " Call the method to be tested
    class_under_test->validate_customer(
      EXPORTING
        keys               = CORRESPONDING #(  travel_mock_data )
      CHANGING
        failed             = failed
        reported           = reported
    ).

    " Check for content in failed and reported
    cl_abap_unit_assert=>assert_initial( msg = 'failed' act = failed ).
    cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).

ENDMETHOD.

测试方法 validate_customer_invalid

此测试方法涵盖差旅实例的客户标识未包含在客户表中的情况,因此差旅实例被视为无效。要实现此情况,该方法将包含客户标识的差旅实例添加到 CDS 测试双精度,但不会向 SQL 测试双精度值添加测试数据。

该方法断言差旅实体的 failed 和 reported 表各仅包含一行。这样可以防止转储,当尝试访问表中不可用的行时,将在后续断言检查期间发生转储。后续检查断言失败且报告的差旅标识等于为 CDS 测试双重提供的标识。对于报告的结构,该方法还断言在 %element 组件中标记了正确的元素,并且它包含对现有消息对象的引用。

展开以下代码示例以查看测试方法 validate_customer_invalid 的源代码。

示例代码

METHOD validate_customer_invalid.

    " Fill in test data for entity travel
    DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
    travel_mock_data = VALUE #( ( travel_id = '43' customer_id = '1' ) ).
    cds_test_environment->insert_test_data( travel_mock_data ).

    " Declare required structures
    DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
    DATA reported TYPE RESPONSE FOR REPORTED LATE  /DMO/I_TRAVEL_M.

    " Call the method to be tested
    class_under_test->validate_customer(
      EXPORTING
        keys               = CORRESPONDING #(  travel_mock_data )
      CHANGING
        failed             = failed
        reported           = reported
    ).

    " Check number of returned instances in failed-travel
    cl_abap_unit_assert=>assert_equals( msg = 'lines in failed-travel' act = lines( failed-travel ) exp = 1 ).

    " Check travel id in failed-travel
    cl_abap_unit_assert=>assert_equals( msg = 'travel id in failed-travel' act = failed-travel[ 1 ]-travel_id exp = '43' ).

    " Check number of returned instances in reported-travel
    cl_abap_unit_assert=>assert_equals( msg = 'lines in reported-travel' act = lines( reported-travel ) exp = 1 ).

    " Check travel id in reported-travel
    cl_abap_unit_assert=>assert_equals( msg = 'travel id in reported-travel' act = reported-travel[ 1 ]-travel_id  exp = '43' ).

    " Check marked field in reported-travel
    cl_abap_unit_assert=>assert_equals( msg = 'field customer id in reported-travel' act = reported-travel[ 1 ]-%element-customer_id  exp = if_abap_behv=>mk-on ).

    " Check message reference in reported-travel
    cl_abap_unit_assert=>assert_bound(  msg = 'message reference in reported-travel' act = reported-travel[ 1 ]-%msg ).

ENDMETHOD.

测试方法 validate_customer_initial

此测试方法涵盖没有为差旅实例提供客户标识的情况,因此验证会将差旅实例视为无效。要实现此情况,该方法将不包含客户标识的差旅实例添加到 CDS 测试双精度。不需要插入 SQL 测试双倍的测试数据。

该方法断言差旅实体的 failed 和 reported 表各仅包含一行。这样可以防止转储,当尝试访问表中不可用的行时,将在后续断言检查期间发生转储。后续检查断言失败且报告的差旅标识等于为 CDS 测试双重提供的标识。对于报告的结构,该方法还断言在 %element 组件中标记了正确的元素,并且它包含对现有消息对象的引用。

展开以下代码示例以查看测试方法 validate_customer_initial 的源代码。

示例代码

METHOD validate_customer_initial.

    " Fill in test data for entity travel
    DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
    travel_mock_data = VALUE #( ( travel_id = '43' customer_id = '' ) ).
    cds_test_environment->insert_test_data( travel_mock_data ).

    " Declare required structures
    DATA failed TYPE RESPONSE FOR FAILED LATE /DMO/I_TRAVEL_M.
    DATA reported TYPE RESPONSE FOR REPORTED LATE  /DMO/I_TRAVEL_M.

    " Call the method to be tested
    class_under_test->validate_customer(
      EXPORTING
        keys               = CORRESPONDING #(  travel_mock_data )
      CHANGING
        failed             = failed
        reported           = reported
    ).

    " Check number of returned instances in failed-travel
    cl_abap_unit_assert=>assert_equals( msg = 'lines in failed-travel' act = lines( failed-travel ) exp = 1 ).

    " Check travel id in failed-travel
    cl_abap_unit_assert=>assert_equals( msg = 'travel id in failed-travel' act = failed-travel[ 1 ]-travel_id exp = '43' ).

    " Check number of returned instances in reported-travel
    cl_abap_unit_assert=>assert_equals( msg = 'lines in reported-travel' act = lines( reported-travel ) exp = 1 ).

    " Check travel id in reported-travel
    cl_abap_unit_assert=>assert_equals( msg = 'travel id in reported-travel' act = reported-travel[ 1 ]-travel_id  exp = '43' ).

    " Check marked field in reported-travel
    cl_abap_unit_assert=>assert_equals( msg = 'field customer id in reported-travel' act = reported-travel[ 1 ]-%element-customer_id  exp = if_abap_behv=>mk-on ).

    " Check message reference in reported-travel
    cl_abap_unit_assert=>assert_bound(  msg = 'message reference in reported-travel' act = reported-travel[ 1 ]-%msg ).

ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 测试功能控制方法 get_features · 测试操作方法 set_status_accepted →