测试操作方法 set_status_accepted
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为管理的航班参考场景开发测试类 › 托管方案:实施测试方法 › 测试操作方法 set_status_accepted
本主题显示操作方法 set_status_accepted 的可能单元测试。
本主题中的文档仅涉及相应的测试方法。有关测试类其他部分的信息,请参阅管理场景:细化测试类结构。
测试设计
要测试的方法可以分为两部分:第一部分对相应的实例执行 EML 修改操作。第二部分读取修改的实例,并将读取结果分配给操作的结果参数。与之前讨论的方法不同,方法 set_status_accepted 不区分不同的情况,例如现有整体状态。方法的两个部分在每个方法执行期间运行,因此整个方法可由单个测试方法涵盖。
测试方法 set_status_accepted
测试方法首先将具有不同总体状态的四个差旅实例添加到测试双精度中,两个具有有效状态,一个具有无效状态,另一个具有初始状态。
由于测试方法需要操作的内部表 result 以及 mapped、failed 和 reported 响应的结构作为更改参数,因此使用从差旅 CDS 实体及其行为定义派生的相应类型声明四个结构。
现在,调用要测试的方法。已插入到测试双精度中的实例的行程标识将作为导出参数、声明的表和结构作为更改参数提供。
要确定在更新总体状态字段的 modify 操作期间是否发生错误,该方法断言 failed 和 reported 结构为空。由于在操作实施中未填充 mapped 结构,因此指定类似的断言检查。
代码的以下部分检查是否已正确填充操作结果。根据行为定义,预期操作会为结果中已执行操作的每个实例返回一个差旅实例。为了能够比较预期操作结果与实际操作结果,需要两个内部表。表 exp 通过引用 result 表的数据类型进行声明,然后使用预期内容填充 - 四个包含模拟差旅标识和整体状态 A 的差旅实例。需要两次指定差旅标识:一次用于字段 travel_id 以标识源实例,一次用于字段 %param-travel_id 以标识目标实例。还使用操作结果的数据类型声明表 act。为确保 act 表仅获取同样包含在 exp 表中的字段的值,使用必填字段的映射规则通过 corresponding 运算符完成操作结果内容的分配。最后,该方法断言表 exp 和 act 的内容是相等的。
该方法的最后一部分检查实例本身是否已正确更新。为此,该方法从事务缓冲区读取模拟差旅实例的差旅标识和总体状态。然后将读取操作的结果分配到 act 表,从而覆盖操作结果的内容。最后,该方法断言表 exp 和 act 的内容是相等的。
展开以下代码示例以查看方法 set_status_accepted 的源代码。
示例代码
METHOD set_status_accepted.
" Fill in test data
DATA travel_mock_data TYPE STANDARD TABLE OF /DMO/TRAVEL_M.
travel_mock_data = VALUE #( ( travel_id = '42' overall_status = 'A' )
( travel_id = '43' overall_status = 'B' )
( travel_id = '44' overall_status = 'X' )
( travel_id = '45' overall_status = '' ) ).
cds_test_environment->insert_test_data( travel_mock_data ).
" Declare required table and structures
DATA result TYPE TABLE FOR ACTION RESULT /DMO/I_TRAVEL_M\\travel~accepttravel.
DATA mapped TYPE RESPONSE FOR MAPPED EARLY /DMO/I_TRAVEL_M.
DATA failed TYPE RESPONSE FOR FAILED EARLY /DMO/I_TRAVEL_M.
DATA reported TYPE RESPONSE FOR REPORTED EARLY /DMO/I_TRAVEL_M.
" Call the method to be tested
class_under_test->set_status_accepted(
EXPORTING
keys = CORRESPONDING #( travel_mock_data )
CHANGING
result = result
mapped = mapped
failed = failed
reported = reported
).
" Check for content in mapped, failed and reported
cl_abap_unit_assert=>assert_initial( msg = 'mapped' act = mapped ).
cl_abap_unit_assert=>assert_initial( msg = 'failed' act = failed ).
cl_abap_unit_assert=>assert_initial( msg = 'reported' act = reported ).
" Check action result for fields of interest: travel_id, %param-travel_id, %param-overall_status.
DATA exp LIKE result.
exp = VALUE #( ( travel_id = 42 %param-travel_id = '42' %param-overall_status = 'A' )
( travel_id = 43 %param-travel_id = '43' %param-overall_status = 'A' )
( travel_id = 44 %param-travel_id = '44' %param-overall_status = 'A' )
( travel_id = 45 %param-travel_id = '45' %param-overall_status = 'A' ) ).
DATA act LIKE result.
act = CORRESPONDING #( result MAPPING travel_id = travel_id
( %param = %param MAPPING travel_id = travel_id
overall_status = overall_status
EXCEPT * )
EXCEPT * ).
cl_abap_unit_assert=>assert_equals( msg = 'action result' exp = exp act = act ).
" Additionally check modified instances
READ ENTITY /DMO/I_TRAVEL_M
FIELDS ( travel_id overall_status ) WITH CORRESPONDING #( travel_mock_data )
RESULT DATA(read_result).
act = VALUE #( FOR t IN read_result ( travel_id = t-travel_id
%param-travel_id = t-travel_id
%param-overall_status = t-overall_status ) ).
cl_abap_unit_assert=>assert_equals( msg = 'read result' exp = exp act = act ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译