测试方法 supplement_create_text_update
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为补充参考场景开发测试类 › 补充场景:实施测试方法 › 测试方法 supplement_create_text_update
此测试方法涵盖对补充实体的创建操作(具有补充描述字段的字段设置)的请求情况,并在同一修改请求中执行对补充描述字段的更新。这将导致在基础层使用相应的更新描述字段创建补充和补充文本实例。
在第一步中,该方法触发包括投影层上的创建和更新操作的 EML MODIFY 请求。这两个操作都涉及补充描述字段。该方法确保通过断言响应结构来执行这两个操作。
在第二步中,该方法读取并检查基础层上补充实例和补充文本实例的结果实例数据。由于增强方法需要使用通过关联创建操作添加补充文本实例,因此通过关联读取此实例的数据。
METHOD supplement_create_text_update.
" Preparation
DATA:
c_create TYPE STRUCTURE FOR CREATE /dmo/c_supplement\\supplement,
c_update TYPE STRUCTURE FOR UPDATE /dmo/c_supplement\\supplement,
c_supplement_act TYPE STRUCTURE FOR UPDATE /dmo/c_supplement\\supplement,
c_supplement_exp TYPE STRUCTURE FOR UPDATE /dmo/c_supplement\\supplement,
i_supplement_act TYPE STRUCTURE FOR UPDATE /dmo/i_supplement\\supplement,
i_supplement_exp TYPE STRUCTURE FOR UPDATE /dmo/i_supplement\\supplement,
i_supplement_text_act TYPE STRUCTURE FOR UPDATE /dmo/i_supplement\\supplementtext.
c_create = VALUE #(
%cid = 'TESTCID'
%is_draft = if_abap_behv=>mk-on
supplementcategory = 'XX'
supplementdescription = 'Test Create'
price = '42'
currencycode = 'EUR'
).
c_update = VALUE #(
%cid_ref = c_create-%cid
%is_draft = c_create-%is_draft
supplementdescription = 'Test Update'
price = '123'
currencycode = 'USD'
).
" Test
MODIFY ENTITIES OF /dmo/c_supplement
ENTITY supplement
CREATE
FIELDS ( supplementcategory supplementdescription price currencycode )
WITH VALUE #( ( c_create ) )
UPDATE
FIELDS ( supplementdescription price currencycode )
WITH VALUE #( ( c_update ) )
MAPPED mapped
FAILED failed
REPORTED reported.
" Verification
cl_abap_unit_assert=>assert_initial( failed ).
cl_abap_unit_assert=>assert_initial( reported ).
cl_abap_unit_assert=>assert_not_initial( mapped-supplement ).
READ ENTITIES OF /dmo/i_supplement
ENTITY supplement
FIELDS ( supplementcategory price currencycode )
WITH CORRESPONDING #( mapped-supplement )
RESULT DATA(i_supplements)
ENTITY supplement
BY \_supplementtext
FIELDS ( description )
WITH CORRESPONDING #( mapped-supplement )
RESULT DATA(i_supplement_texts)
FAILED i_failed
REPORTED i_reported.
cl_abap_unit_assert=>assert_initial( i_failed ).
cl_abap_unit_assert=>assert_initial( i_reported ).
" Supplement
cl_abap_unit_assert=>assert_not_initial( i_supplements ).
cl_abap_unit_assert=>assert_equals( exp = 1
act = lines( i_supplements ) ).
i_supplement_act = CORRESPONDING #( i_supplements[ 1 ] EXCEPT %key ).
i_supplement_exp = CORRESPONDING #( c_update EXCEPT %cid_ref %key supplementcategory ).
i_supplement_exp-supplementcategory = c_create-supplementcategory.
cl_abap_unit_assert=>assert_equals( exp = i_supplement_exp
act = i_supplement_act ).
" Supplement Text
cl_abap_unit_assert=>assert_not_initial( i_supplement_texts ).
cl_abap_unit_assert=>assert_equals( exp = 1
act = lines( i_supplement_texts ) ).
i_supplement_text_act = CORRESPONDING #( i_supplement_texts[ 1 ] EXCEPT supplementid ).
cl_abap_unit_assert=>assert_equals( exp = sy-langu
act = i_supplement_text_act-languagecode ).
cl_abap_unit_assert=>assert_equals( exp = c_update-supplementdescription
act = i_supplement_text_act-description ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 测试方法 supplement_create · 测试方法 supplement_update_text_create →