测试方法 supplement_update_text_create

ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为补充参考场景开发测试类 › 补充场景:实施测试方法 › 测试方法 supplement_update_text_create

此测试涵盖请求更新补充实例的情况。要更新的实例不包含字段补充描述的值。此值仅由更新请求设置。

在第一步中,方法通过执行 MODIFY 创建请求准备补充实例。创建请求在基础层执行,其中补充描述字段不是补充实体的一部分。

实际测试由映射层上的 MODIFY 更新请求执行,该请求设置补充描述字段和补充实体的其他字段的值。由于增强方法需要使用通过关联创建操作添加补充文本实例,因此通过关联读取来读取此实例的数据,并在之后分别进行检查。

METHOD supplement_update_text_create.
    " Preparation
    DATA:
      i_create TYPE STRUCTURE FOR CREATE /dmo/i_supplement\\supplement.

    i_create = VALUE #(
        %is_draft          = if_abap_behv=>mk-on
        supplementcategory = 'XX'
        price              = '10'
        currencycode       = 'USD'
      ).
    MODIFY ENTITIES OF /dmo/i_supplement
      ENTITY supplement
        CREATE
          AUTO FILL CID
          FIELDS ( supplementcategory price currencycode )
          WITH VALUE #( ( i_create ) )
      MAPPED    i_mapped
      FAILED    i_failed
      REPORTED  i_reported.

    cl_abap_unit_assert=>assert_initial( i_failed ).
    cl_abap_unit_assert=>assert_initial( i_reported ).
    cl_abap_unit_assert=>assert_initial( i_mapped-supplementtext ).

    cl_abap_unit_assert=>assert_not_initial( i_mapped-supplement ).
    cl_abap_unit_assert=>assert_equals( exp = 1
                                        act = lines( i_mapped-supplement ) ).

    DATA(supplementid_to_test) = VALUE #( i_mapped-supplement[ 1 ]-supplementid ).

    " Test
    DATA:
      c_update TYPE STRUCTURE FOR UPDATE /dmo/c_supplement\\supplement,
      i_update TYPE STRUCTURE FOR UPDATE /dmo/i_supplement\\supplement.

    c_update = VALUE #(
                   %is_draft             = if_abap_behv=>mk-on
                   supplementid          = supplementid_to_test
                   supplementdescription = 'Test'
                   price                 = '42'
                   currencycode          = 'EUR'
                 ).

    MODIFY ENTITIES OF /dmo/c_supplement
      ENTITY supplement
        UPDATE
          FIELDS ( supplementdescription price currencycode )
          WITH VALUE #( ( c_update ) )
      MAPPED    mapped
      FAILED    failed
      REPORTED  reported.

    " Verification
    cl_abap_unit_assert=>assert_initial( failed ).
    cl_abap_unit_assert=>assert_initial( reported ).
    cl_abap_unit_assert=>assert_initial( mapped ).

    READ ENTITIES OF /dmo/i_supplement
      ENTITY supplement
        FIELDS ( supplementcategory price currencycode )
        WITH CORRESPONDING #( i_mapped-supplement )
        RESULT DATA(supplements)
      ENTITY supplement
        BY \_supplementtext
        FIELDS ( description )
        WITH CORRESPONDING #( i_mapped-supplement )
        RESULT DATA(supplement_texts)
      FAILED    i_failed
      REPORTED  i_reported.

    cl_abap_unit_assert=>assert_initial( i_failed ).
    cl_abap_unit_assert=>assert_initial( i_reported ).

    " Supplement
    cl_abap_unit_assert=>assert_not_initial( supplements ).
    cl_abap_unit_assert=>assert_equals( exp = 1
                                        act = lines( supplements ) ).

    i_update = CORRESPONDING #( c_update ).
    i_update-supplementcategory = i_create-supplementcategory.
    cl_abap_unit_assert=>assert_equals( exp = i_update-%data
                                        act = supplements[ 1 ]-%data ).
    cl_abap_unit_assert=>assert_equals( exp = i_update-%is_draft
                                        act = supplements[ 1 ]-%is_draft ).

    " Supplement Text
    cl_abap_unit_assert=>assert_not_initial( supplement_texts ).
    cl_abap_unit_assert=>assert_equals( exp = 1
                                        act = lines( supplement_texts ) ).
    DATA(act_i_cba) = supplement_texts[ 1 ].
    cl_abap_unit_assert=>assert_equals( exp = sy-langu
                                        act = act_i_cba-languagecode ).
    cl_abap_unit_assert=>assert_equals( exp = c_update-supplementdescription
                                        act = act_i_cba-description ).
  ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 测试方法 supplement_create_text_update · 测试方法 supplement_update_text_update →