代理方案:细化测试类结构

ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为代理参考场景开发测试类 › 代理方案:细化测试类结构

现在您已创建基本测试类结构,可以通过定义提供所需测试配置的基本测试属性、测试关系、变量和固定设备方法来细化此结构。定义的测试类构成了测试方法的基础,将在下一章中实施这些测试方法。

测试类定义

测试类的定义部分包含基本元信息、参考变量和所用方法的声明。

分配测试属性

由于测试方法的大小相对较小,因此测试代码的执行时间不应超过 5 秒。因此,您可以使用 DURATION SHORT。根据相应的运行模式和运行时监控器,超过所选执行时间可能会影响测试结果。

由于您不会通过单元测试更改持久数据或系统设置,因此可以使用 RISK LEVEL HARMLESS。如果所选风险级别高于系统中允许的风险级别,则不会执行测试。

CLASS ltcl_sc_r_agency DEFINITION FINAL FOR TESTING
  DURATION SHORT
  RISK LEVEL HARMLESS.

指定测试关系

您将为 BDEF /DMO/ZZ_X_REVIEW_R_AGENCYTP 中定义的节点扩展开发单元测试。通过指定与此 BDEF 的测试关系,您可以通过节点扩展的行为定义的上下文菜单直接运行单元测试。

"! @testing BDEF:/DMO/ZZ_X_REVIEW_R_AGENCYTP
CLASS ltcl_sc_r_agency DEFINITION FINAL FOR TESTING
...

声明常量和类属性

为 RAP 业务事件的名称和预期引发事件的实体定义常量。

在专用部分中为被测代码定义参考变量。

由于您将使用 CDS 测试双框架和事件测试双重框架,因此还需要声明其相应接口的参考变量。

PRIVATE SECTION.
    CONSTANTS agency_event  TYPE c length 30 VALUE '/DMO/AGENCYREVIEWCREATED'.
    CONSTANTS agency_entity TYPE abp_entity_name VALUE '/DMO/I_AGENCYTP'.
    CLASS-DATA:
      class_under_test       TYPE REF TO lsc_r_agency,
      cds_test_environment   TYPE REF TO if_cds_test_environment,
      event_test_environment TYPE REF TO if_rap_event_test_environment.

声明固定设备和测试方法

除测试方法 save_md_no_review_created、save_md_one_review_created 和 save_md_multi_reviews_created 的声明外,还声明固定设备方法。固定设备方法用于设置和拆卸测试环境,为每个执行的测试生成唯一的测试行为。

展开以下代码示例以查看源代码。

示例代码

CLASS-METHODS:
  class_setup,
  class_teardown.

METHODS:
  setup,
  teardown.

METHODS:
  save_md_no_review_created FOR TESTING,
  save_md_one_review_created FOR TESTING,
  save_md_multi_reviews_created FOR TESTING.

有关测试方法和所选测试方法实施的信息,请参阅 代理业务情景:实施测试方法 。

测试类实施

本部分介绍固定设备方法的实施,这些固定设备方法指定测试方法使用的测试配置。

实施方法 class_setup

首先,使用参考变量 class_under_test 实例化要测试的行为实现类。

接下来,创建 CDS 测试双框架环境以隔离数据库相关性:提供被测试代码中 EML 读取语句寻址的实体的名称,并确保位于相关性树中此实体下方的数据库表翻倍。

最后,准备 RAP 事件测试双框架环境的配置:提供事件的名称以及预期引发事件的实体的名称,作为 create 方法的导入参数。由于要测试的事件在节点扩展的行为实施中引发,因此需要指定 RAP BO 接口的实体名称。

METHOD class_setup.
    CREATE OBJECT class_under_test FOR TESTING.
    sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #( ( '/DMO/ZZ_AGN_REVA' ) ) ).
    cds_test_environment = cl_cds_test_environment=>create( i_for_entity               = agency_entity
                                                            i_select_base_dependencies = abap_true ).
    event_test_environment = cl_rap_event_test_environment=>create( VALUE #( ( entity_name = agency_entity event_name = agency_event ) ) ).
ENDMETHOD.

实施方法 setup

在每次执行测试方法之前清除 CDS 和事件测试两倍。

METHOD setup.
    cds_test_environment->clear_doubles(  ).
    event_test_environment->clear(  ).
  ENDMETHOD.

实施方法 teardown

清除事务缓冲区。

METHOD teardown.
    ROLLBACK ENTITIES.
ENDMETHOD.

实施方法 class_teardown

拆卸环境并测试 CDS 和事件测试双重框架的两倍。

METHOD class_teardown.
    cds_test_environment->destroy(  ).
    event_test_environment->destroy(  ).
ENDMETHOD.

结果测试类

遵循上述步骤后,您的测试类如下所示,并准备好实施测试方法:

展开以下代码示例以查看测试类 ltcl_sc_r_agency 的源代码。

示例代码

"! @testing BDEF:/DMO/ZZ_X_REVIEW_R_AGENCYTP
CLASS ltcl_sc_r_agency DEFINITION FINAL FOR TESTING
  DURATION SHORT
  RISK LEVEL HARMLESS.

  PRIVATE SECTION.
    CLASS-DATA:
      CONSTANTS agency_event  TYPE c length 30 VALUE '/DMO/AGENCYREVIEWCREATED'.
      CONSTANTS agency_entity TYPE abp_entity_name VALUE '/DMO/I_AGENCYTP'.
      class_under_test     TYPE REF TO lsc_r_agency,
      cds_test_environment   TYPE REF TO if_cds_test_environment,
      event_test_environment TYPE REF TO if_rap_event_test_environment.

    CLASS-METHODS:
      class_setup,
      class_teardown.

    METHODS:
      setup,
      teardown.

    METHODS:
      save_md_no_review_created FOR TESTING,
      save_md_one_review_created FOR TESTING,
      save_md_multi_reviews_created FOR TESTING.
ENDCLASS.

CLASS ltcl_sc_r_agency IMPLEMENTATION.

  METHOD class_setup.
    CREATE OBJECT class_under_test FOR TESTING.
    sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #( ( '/DMO/ZZ_AGN_REVA' ) ) ).
    cds_test_environment = cl_cds_test_environment=>create( i_for_entity               = agency_entity
                                                            i_select_base_dependencies = abap_true ).
    event_test_environment = cl_rap_event_test_environment=>create( VALUE #( ( entity_name = agency_entity event_name = agency_event ) ) ).
  ENDMETHOD.

  METHOD setup.
    cds_test_environment->clear_doubles(  ).
    event_test_environment->clear(  ).
  ENDMETHOD.

  METHOD teardown.
    ROLLBACK ENTITIES.
  ENDMETHOD.

  METHOD class_teardown.
    cds_test_environment->destroy(  ).
    event_test_environment->destroy(  ).
  ENDMETHOD.

  METHOD save_md_no_review_created.
  ENDMETHOD.

  METHOD save_md_one_review_created.
  ENDMETHOD.

  METHOD save_md_multi_reviews_created.
  ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 代理场景:提供对已测试方法的访问权限 · 代理业务情景:实施测试方法 →