代理业务情景:实施测试方法
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为代理参考场景开发测试类 › 代理业务情景:实施测试方法
本部分开发的单元测试测试是否按方法 /DMO/AgencyReviewCreated 中的预期引发 RAP 业务事件 save_modified。此方法表示扩展节点 /DMO/ZZ_R_AGENCY_REVIEWTP 的附加保存实施。
测试设计
创建一个或多个审核实例后将引发事件 /DMO/AGENCYREVIEWCREATED。所选测试方法涵盖没有、一个或多个审核实例移交到附加保存出口的情况。
实施测试方法 save_md_no_review_created
首先,该方法使用实体 /DMO/I_AGENCYTP 的相应派生类型声明延迟报告的响应的结构。
接下来,该方法使用声明的报告结构作为更改参数来执行被测代码。没有为导入参数 create、update 和 delete 提供数据。
最后,该方法断言尚未针对实体 /DMO/AGENCYREVIEWCREATED 引发事件 /DMO/I_AGENCYTP。
METHOD save_md_no_review_created.
" Prepare
DATA reported TYPE RESPONSE FOR REPORTED LATE /dmo/i_agencytp.
" Execute
class_under_test->save_modified( EXPORTING create = VALUE #( )
update = VALUE #( )
delete = VALUE #( )
CHANGING reported = reported ).
" Verify
event_test_environment->get_event( entity_name = agency_entity event_name = agency_event )->verify( )->is_raised_times( 0 ).
ENDMETHOD.
实施测试方法 save_md_one_review_created
测试方法需要模拟数据库表中代理实例的数据,以便在引发事件时填充事件有效负载的字段 email address。因此,测试方法使用代理标识和电子邮件地址填充相应类型的内部表。然后,使用 CDS 测试双重框架将这些测试数据插入到数据库测试双精度中。
接下来,该方法声明了使用实体 /DMO/I_AGENCYTP 的相应派生类型将创建的审核实例导入到附加保存出口的结构。然后,方法使用审核实例的数据填充其表格组件 /DMO/ZZ_REVIEW。审核实例与代理实例具有相同的代理标识,该标识已预先插入到数据库测试双精度中。
在下一步中,该方法使用实体 /DMO/I_AGENCYTP 的相应派生类型声明延迟报告的响应的结构。
现在,该方法使用声明的 create 结构作为导入参数,使用 reported 结构作为更改参数来执行被测代码。
接下来,该方法断言事件 /DMO/AGENCYREVIEWCREATED 已针对实体 /DMO/I_AGENCYTP 引发一次。
最后, 方法检查事件的有效负载是否符合预期。
METHOD save_md_one_review_created.
" Prepare
DATA agency_mock_data TYPE STANDARD TABLE OF /dmo/agency.
agency_mock_data = VALUE #( ( agency_id = '1' email_address = 'test@test.example' ) ).
cds_test_environment->insert_test_data( agency_mock_data ).
DATA create TYPE REQUEST FOR CHANGE /dmo/i_agencytp.
create-/dmo/zz_review = VALUE #( ( agencyid = '1'
reviewid = '1'
rating = '1'
freetextcomment = 'Bad' ) ).
DATA reported TYPE RESPONSE FOR REPORTED LATE /dmo/i_agencytp.
" Execute
class_under_test->save_modified( EXPORTING create = create
update = VALUE #( )
delete = VALUE #( )
CHANGING reported = reported ).
" Verify
event_test_environment->get_event( entity_name = agency_entity event_name = agency_event )->verify( )->is_raised_times( 1 ).
DATA event_payload_act TYPE TABLE FOR EVENT /dmo/i_agencytp~/dmo/agencyreviewcreated.
event_payload_act = event_test_environment->get_event( entity_name = agency_entity event_name = agency_event )->get_payload( )->*.
DATA event_payload_exp TYPE TABLE FOR EVENT /dmo/i_agencytp~/dmo/agencyreviewcreated.
event_payload_exp = VALUE #( ( agencyid = '1'
reviewid = '1'
rating = '1'
freetextcomment = 'Bad'
emailaddress = 'test@test.example' ) ).
cl_abap_unit_assert=>assert_equals( act = event_payload_act exp = event_payload_exp ).
ENDMETHOD.
实施测试方法 save_md_multi_reviews_created
此测试方法的实施遵循与测试方法 save_md_one_review_created 类似的原则。但是,在此测试方法中,参考不同代理实例的三个审核实例将导入到附加保存方法中。尽管为多个机构创建了多个审核实例,但事件 /DMO/AGENCYREVIEWCREATED 预计仅引发一次。不同审核实例的数据反映在事件的有效负载中。
METHOD save_md_multi_reviews_created.
" Prepare
DATA agency_mock_data TYPE STANDARD TABLE OF /dmo/agency.
agency_mock_data = VALUE #( ( agency_id = '1' email_address = 'test@test.example' )
( agency_id = '2' email_address = 'test2@test.example' ) ).
cds_test_environment->insert_test_data( agency_mock_data ).
DATA create TYPE REQUEST FOR CHANGE /dmo/i_agencytp.
create-/dmo/zz_review = VALUE #( ( agencyid = '1'
reviewid = '1'
rating = '1'
freetextcomment = 'Bad' )
( agencyid = '1'
reviewid = '2'
rating = '4'
freetextcomment = 'Good' )
( agencyid = '2'
reviewid = '1'
rating = '2'
freetextcomment = 'Medium' ) ).
DATA reported TYPE RESPONSE FOR REPORTED LATE /dmo/i_agencytp.
" Execute
class_under_test->save_modified( EXPORTING create = create
update = VALUE #( )
delete = VALUE #( )
CHANGING reported = reported ).
" Verify
event_test_environment->get_event( entity_name = agency_entity event_name = agency_event )->verify( )->is_raised_times( 1 ).
DATA event_payload_act TYPE TABLE FOR EVENT /dmo/i_agencytp~/dmo/agencyreviewcreated.
event_payload_act = event_test_environment->get_event( entity_name = agency_entity event_name = agency_event )->get_payload( )->*.
DATA event_payload_exp TYPE TABLE FOR EVENT /dmo/i_agencytp~/dmo/agencyreviewcreated.
event_payload_exp = VALUE #( ( agencyid = '1'
reviewid = '1'
rating = '1'
freetextcomment = 'Bad'
emailaddress = 'test@test.example' )
( agencyid = '1'
reviewid = '2'
rating = '4'
freetextcomment = 'Good'
emailaddress = 'test@test.example' )
( agencyid = '2'
reviewid = '1'
rating = '2'
freetextcomment = 'Medium'
emailaddress = 'test2@test.example' ) ).
cl_abap_unit_assert=>assert_equals( act = event_payload_act exp = event_payload_exp ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 代理方案:细化测试类结构 · 集成测试 →