测试场景深度创建 + 确定

ABAP RESTful 应用程序编程模型 › 测试 › 集成测试 › EML 集成测试 › EML 测试:实施测试方法 › 测试场景深度创建 + 确定

此集成测试检查确定 calculateTotalPrice 是否返回包含预订和补充实例的已创建差旅实例的正确总价。

首先,测试方法填充开始日期和结束日期的变量。

接下来,该方法执行 EML 修改调用,以创建差旅和相应的预订和补充实例。为确保正确执行按关联创建和创建操作,为航班日期以及代理和客户标识提供有效数据。

现在,该方法执行 EML 读取调用以获取确定的计算结果 calculateTotalPrice。在此 EML 读取语句中,通过从先前 EML 创建语句的 mapped 响应中获取的行程标识来识别差旅实例。

该方法最终断言读取计算结果等于预期值。

展开以下代码示例以查看方法 deep_create_determination 的源代码。

示例代码

METHOD deep_create_determination.

    begin_date = cl_abap_context_info=>get_system_date( ) + 10.
    end_date   = cl_abap_context_info=>get_system_date( ) + 30.

    " Create a Travel, Booking and Supplement
    MODIFY ENTITIES OF /dmo/i_travel_m
      ENTITY travel
        CREATE FIELDS (    agency_id customer_id begin_date end_date description booking_fee currency_code overall_status ) WITH
        VALUE #( (         %cid = cid
                           agency_id      = agency_mock_data[ 1 ]-agency_id
                           customer_id    = customer_mock_data[ 1 ]-customer_id
                           begin_date     = begin_date
                           end_date       = end_date
                           description    = 'TestTravel 1'
                           booking_fee    = '10.5'
                           currency_code  = 'EUR'
                           overall_status = 'O' ) )
        CREATE BY \_booking FIELDS ( booking_date customer_id carrier_id connection_id flight_date flight_price currency_code
                                     booking_status )
        WITH VALUE #( ( %cid_ref = cid
                         %target = VALUE #( ( %cid           = cid_node
                                              booking_date   = begin_date
                                              customer_id    = customer_mock_data[ 1 ]-customer_id
                                              carrier_id     = '1'
                                              connection_id  = '1'
                                              flight_date    = begin_date
                                              flight_price   = '200'
                                              currency_code  = 'EUR'
                                              booking_status = 'N' ) )
         ) )
      ENTITY booking
          CREATE BY \_booksupplement FIELDS ( supplement_id price currency_code ) WITH
          VALUE #( (  %cid_ref = cid_node
                      %target = VALUE #( ( %cid          = cid_subnode
                                           supplement_id = '100'
                                           price         = '1000'
                                           currency_code = 'EUR' ) )
                       ) )
     MAPPED DATA(mapped_cba)
     FAILED DATA(failed_cba)
     REPORTED DATA(reported_cba).

    " Read determination result
    READ ENTITIES OF /dmo/i_travel_m
     ENTITY travel
       FIELDS ( total_price )
       WITH VALUE #( ( travel_id = mapped_cba-travel[ 1 ]-%tky ) )
       RESULT DATA(result)
       FAILED DATA(failed_read).

    " Determination calculation was successful
    cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( result ) ).
    cl_abap_unit_assert=>assert_equals( act = result[ 1 ]-total_price exp = '1210.50'  ).

  ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 测试场景创建 + 验证 · 测试场景创建 + 功能控制 + 操作 →