测试场景创建 + 功能控制 + 操作
ABAP RESTful 应用程序编程模型 › 测试 › 集成测试 › EML 集成测试 › EML 测试:实施测试方法 › 测试场景创建 + 功能控制 + 操作
此集成测试检查实例功能控制实施 get_features 是否阻止对创建的差旅实例执行的操作 acceptTravel。
测试方法 create_action_fc_negative
首先,测试方法填充开始日期和结束日期的变量。
该方法现在使用准备的日期变量以及准备的代理和客户标识对业务对象执行 EML 修改创建调用。由于该方法测试阻止执行操作 acceptTravel 的情况,因此提供整体状态 A。
创建操作应正确运行。因此,该方法断言来自 EML 创建语句的 mapped 响应包含预期内容和差旅标识,并且 failed 和 reported 响应为空。
现在,该方法会触发对已创建差旅实例的操作 acceptTravel。在此 EML 修改声明中,通过从先前 EML 创建语句的 mapped 响应中获取的差旅标识来标识差旅实例。
根据 get_features 方法的逻辑,针对总体状态为 A 的差旅实例禁用操作 acceptTravel。因此,该方法断言操作的 failed 响应包含差旅标识,并分别标记操作 acceptTravel。
操作预计不会返回任何消息,因此该方法断言 reported 响应为空。
展开以下代码示例以查看方法 create_action_fc_negative 的源代码。
示例代码
METHOD create_action_fc_negative.
begin_date = cl_abap_context_info=>get_system_date( ) + 10.
end_date = cl_abap_context_info=>get_system_date( ) + 30.
" Create a travel
MODIFY ENTITIES OF /dmo/i_travel_m
ENTITY travel
CREATE FIELDS ( agency_id customer_id begin_date end_date description booking_fee currency_code overall_status ) WITH
VALUE #( ( %cid = cid
agency_id = agency_mock_data[ 1 ]-agency_id
customer_id = customer_mock_data[ 1 ]-customer_id
begin_date = begin_date
end_date = end_date
description = 'TestTravel 1'
booking_fee = '10.5'
currency_code = 'EUR'
overall_status = 'A' ) )
MAPPED DATA(mapped_create)
FAILED DATA(failed_create)
REPORTED DATA(reported_create).
" Travel was created successfully
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( mapped_create-travel ) ).
DATA(key_of_new_travel) = mapped_create-travel[ 1 ].
cl_abap_unit_assert=>assert_equals( exp = cid act = key_of_new_travel-%cid ).
cl_abap_unit_assert=>assert_not_initial( act = key_of_new_travel-travel_id ).
cl_abap_unit_assert=>assert_initial( failed_create ).
cl_abap_unit_assert=>assert_initial( reported_create ).
" Execute action
MODIFY ENTITIES OF /dmo/i_travel_m
ENTITY travel
EXECUTE acceptTravel FROM VALUE #( ( travel_id = mapped_create-travel[ 1 ]-%tky ) )
FAILED DATA(failed_action)
REPORTED DATA(reported_action).
" Action failed as overall status is already accepted
cl_abap_unit_assert=>assert_equals( act = lines( failed_action-travel ) exp = 1 ).
cl_abap_unit_assert=>assert_not_initial( act = failed_action-travel[ 1 ]-travel_id ).
cl_abap_unit_assert=>assert_equals( exp = if_abap_behv=>mk-on act = failed_action-travel[ 1 ]-%action-accepttravel ).
cl_abap_unit_assert=>assert_initial( reported_action ).
ENDMETHOD.
测试方法 create_action_fc_positive
第二个测试方法测试使用者创建总体状态为 X 的行程实例的情况。在这种情况下,可以成功执行该操作。
展开以下代码示例以查看方法 create_action_fc_positive 的源代码。
示例代码
METHOD create_action_fc_positive.
begin_date = cl_abap_context_info=>get_system_date( ) + 10.
end_date = cl_abap_context_info=>get_system_date( ) + 30.
" Create a Travel
MODIFY ENTITIES OF /dmo/i_travel_m
ENTITY travel
CREATE FIELDS ( agency_id customer_id begin_date end_date description booking_fee currency_code overall_status ) WITH
VALUE #( ( %cid = cid
agency_id = agency_mock_data[ 1 ]-agency_id
customer_id = customer_mock_data[ 1 ]-customer_id
begin_date = begin_date
end_date = end_date
description = 'TestTravel 1'
booking_fee = '10.5'
currency_code = 'EUR'
overall_status = 'X' ) )
MAPPED DATA(mapped_create)
FAILED DATA(failed_create)
REPORTED DATA(reported_create).
" Travel was created successfully
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( mapped_create-travel ) ).
DATA(key_of_new_travel) = mapped_create-travel[ 1 ].
cl_abap_unit_assert=>assert_equals( exp = cid act = key_of_new_travel-%cid ).
cl_abap_unit_assert=>assert_not_initial( act = key_of_new_travel-travel_id ).
cl_abap_unit_assert=>assert_initial( failed_create ).
cl_abap_unit_assert=>assert_initial( reported_create ).
" Execute action
MODIFY ENTITIES OF /dmo/i_travel_m
ENTITY travel
EXECUTE acceptTravel FROM VALUE #( ( travel_id = mapped_create-travel[ 1 ]-%tky ) )
FAILED DATA(failed_action)
REPORTED DATA(reported_action).
" Read action result
READ ENTITIES OF /dmo/i_travel_m
ENTITY travel
FIELDS ( overall_status )
WITH VALUE #( ( travel_id = mapped_create-travel[ 1 ]-%tky ) )
RESULT DATA(result)
FAILED DATA(failed_read).
" Read was executed successfully
cl_abap_unit_assert=>assert_initial( failed_read ).
" Action was executed successfully
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( result ) ).
cl_abap_unit_assert=>assert_equals( act = result[ 1 ]-overall_status exp = 'A' ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译